*label scene_introduction
*if katie_subplot_scene = 1
    Katie didn't fight with raw power or speed; she applied precise techniques to create debilitating pain. She's invited you to her lab with the promise of helping you control your subjective experience of pain. Her systematic understanding of the nervous system could be useful during fights, although you're unsure what form her instruction will take. You palm your elbow, remembering the control she demonstrated.
    *if (katie_almost_lapsed)

        If you don't respond to her invitation soon, she will likely assume you're not interested.
*elseif katie_subplot_scene = 2
    Katie mentioned she would teach you a set of exercises designed to stop your nervous system from "overreacting." This time she's bringing tools that she crafted herself. She didn't elaborate. Nobody else is doing what she's doing, she said, which doesn't surprise you.
    *if (katie_almost_lapsed)

        Katie can't wait forever. If you don't meet her now, she'll keep on experimenting without you.
*elseif katie_subplot_scene = 3
    "I want to practise being around other people. Can you help me?" she writes. Katie's message — unfiltered, almost plaintive — matches what you've seen during your sessions together. It might be an unstructured chat, or a meticulously planned interaction. She didn't offer to teach you anything.
    *if (katie_almost_lapsed)

        Given what you know of Katie, waiting weeks before responding would feel like rejection to her.
*elseif katie_subplot_scene = 4
    *if katie_plot_timer = 0
        Katie's last message: the university is pushing back on her research. She's facing yet another review, and she's worried they will keep her in limbo indefinitely. The pressure's building. You're not sure how it resolves.
        *if (katie_almost_lapsed)

            You have a busy schedule, but Katie sounds like she's under serious pressure. Much longer and she will assume she's on her own.
    *else
        Katie hasn't replied to your messages. The last one she sent was a voice message at 2:56am. Lab noise, rustling, a stack of books toppling. Then her whisper: "Some issues with my research. University committee... questions about ethics. Will explain later. Don't come by."
        *if highest_trait = "analysis"
            You check the audio metadata. Sent from her campus lab Wi-Fi, no edits. She didn't rehearse this one.
        *elseif highest_trait = "empathy"
            You replay the memo. A tension, even panic, is creeping in.
        *elseif highest_trait = "composure"
            You don't follow up again. If she needs help, she'll ask.
        *else
            *bug Invalid highest_trait
*elseif katie_subplot_scene = 5
    *if katie_plot_timer = 0
        Katie's supervisor helped her get a modified fork approved for shorter trials. You've spent several sessions on the revised protocol. Her pre-submission review is coming up — her supervisor, two other professors from the kinesiology department, and you. You'd be the demonstration subject.
        *if (katie_almost_lapsed)

            Katie's thesis review is time sensitive. If you don't make time for it, she'll handle it alone, and that will be the end of your involvement.
    *else
        Katie's in a frenzy, rewriting entire sections, replacing figures, revising arguments. She messages you occasionally to bounce ideas, but she's too absorbed in her work to meet. She won't be free until she's finished.
*elseif katie_subplot_scene = 6
    *if katie_plot_timer = 0
        Katie asked if you were free to meet her after her thesis defence. You won't be allowed to attend in person, but meeting her afterwards makes sense.
        *if (katie_almost_lapsed)

            Katie wants to share this moment with you. If you leave her hanging, she'll take it as a no.
    *else
        Katie said she needed a few weeks to refine her thesis defence. She promised to meet you once it's over. The rest is in her hands now.
*elseif katie_subplot_scene = 7
    Katie's working on revisions to her thesis. She's fairly busy, but she makes time to see you often.
*else
    *bug Katie subplot scene not found
*return

*comment katie_friendship from katie_fight: 0-1
*label scene_choice
*if katie_subplot_scene = 1
    *comment earliest: chapter 3, first fortnight
    *comment katie_friendship from this chapter: 2-3 for accept, 0-1 for reject
    *comment cumulative katie_friendship after this chapter: 3-4
    *gosub event_1
    *set stat_mental %+2
    *set unlocked_katie_training true
*elseif katie_subplot_scene = 2
    *comment earliest: chapter 3, second fortnight
    *comment katie_friendship from this chapter: 1-2
    *comment cumulative katie_friendship after this chapter: 4-6
    *gosub event_2
    *set boxing_insights_unspent +1
*elseif katie_subplot_scene = 3
    *comment earliest: chapter 4, first fortnight
    *comment katie_friendship from this chapter: 1-4
    *comment cumulative katie_friendship after this chapter: 5-10
    *gosub event_3
    *set stat_mental %+4
    *set stat_energy +5
    *gosub_scene utils clamp_energy
    *set katie_plot_timer 2
*elseif katie_subplot_scene = 4
    *comment earliest: chapter 5, first fortnight
    *comment katie_friendship from this chapter: 0-5
    *comment cumulative katie_friendship after this chapter: 5-15
    *comment katie_romance from this chapter: 0-1
    *comment cumulative katie_romance after this chapter: 0-1
    *gosub event_4
    *set stat_mental %+5
    *set katie_plot_timer 2
*elseif katie_subplot_scene = 5
    *comment earliest: chapter 6, first fortnight
    *comment katie_friendship from afterhours: 2-6
    *comment katie_friendship from this chapter: 3-4
    *comment cumulative katie_friendship after this chapter (excl. afterhours): 8-19
    *comment katie_romance from afterhours: 0-2
    *comment katie_romance from this chapter: 0-4
    *comment cumulative katie_romance after this chapter (excl. afterhours): 0-5
    *gosub event_5
    *set stat_power %+5
    *set stat_toughness %+3
    *set katie_plot_timer 2
*elseif katie_subplot_scene = 6
    *comment earliest: chapter 7, first fortnight
    *comment katie_friendship from afterhours: 2-6
    *comment katie_friendship from this chapter: 3-6
    *comment cumulative katie_friendship after this chapter (excl. afterhours): 11-25
    *comment katie_romance from afterhours: 0-2
    *comment katie_romance from this chapter: 0-2
    *comment cumulative katie_romance after this chapter (excl. afterhours): 0-7
    *gosub event_6
    *set stat_power %+4
    *set stat_technique %+4
    *set stat_toughness %+3
    *set stat_energy +5
    *gosub_scene utils clamp_energy
    *set katie_plot_timer 10000
*else
    *bug Katie subplot scene not found
*return

*label event_1
The kinesiology wing is mostly dark and smells faintly of disinfectant, with a sharp wedge of light spilling from beneath the door at the end of the corridor as you approach quietly, not wanting to disturb the silence. A brushed metal nameplate next to the door announces:

LAB 3B-19
*line_break
Applied Kinesiology

You flex your elbow. No pain. You try your wrists, shoulders, waist, knees, ankles, cataloguing the responses. All fine. No memory in the joints; just in the nerves.

You knock.

From inside, the sound of a falling stack of paper, then a voice. "You're early! Or on time. Hold on!"

The door swings inwards, a little too fast.

*page_break
Anatomy charts. Plastic joint models. Nerve diagrams. A skeleton in the corner wearing a party hat and a name tag: SKELETOR - TEACHING ASSISTANT. A desk piled high with papers and folders.

Skeletor grins at you. So does Katie.

She's wearing bright teal leggings and a T-shirt that says "PAIN: IT'S ALL IN THE MIND." Near the hem, a tiny print-on-demand logo. She heaves a duffel bag onto the lab table. It lands with a thud and several quiet clacks. Doesn't sound like any gym gear you know of.

"Hi! You came!" She beams at you. "Usually people never show up."

*choice
    #Just nod. Better to see the full picture before deciding how to handle this.
        *gosub_scene utils increase_composure
        She greeted you lightly, but then followed with a weighty admission. You nod briefly. See how things develop first, before committing to a position.
    #Consider her words. It didn't sound like she was telling a joke.
        *gosub_scene utils increase_empathy
        The words take the form of a joke, but there's no lightness in her voice, no smile in her eyes. Just something to float into the air.

        You nod, just once. More is unnecessary.
    #Consider what the absences mean for her work.
        *gosub_scene utils increase_analysis
        If people aren't showing up, does it mean she hasn't tested any of this?

        Something to find out during the session.

Katie registers your slight nod. She swallows. One hand tugs at her ponytail, fingers circling the elastic again and again.

"Okay. You're steady. That's good. Let's get to it then."

She points to a waist-high padded exam table in the centre of the room. The pleather upholstery is cracked in places, mended with a patchwork of clear, duct, and metallic tape. "Lie down here," she says. Katie rummages through her duffel bag and extracts a short wooden rod that looks like a dowel or pestle.

"We'll establish your baseline response to stimulus before we start the real work," she says, then adds with bright formality, "${first_name} ${last_name}."

"Most people think all nerves respond the same way. But that's too simplified." Her smile returns. "Your body already knows this. Your brain just hasn't realised it yet." She gestures you towards the exam table.

*if highest_trait = "analysis"
    "I see. So the response is different for everyone. Individualised mapping."

    "Exactly. Every signal is a unique conversation." She smiles at you, lines below her eyes creasing.

*elseif highest_trait = "composure"
    "All right. Just tell me where you want the arm."

    "You make a good subject," she says, quieter now. "Steady and controlled. That helps more than most people realise."

*elseif highest_trait = "empathy"
    "Katie, that sounds rehearsed."

    Her shoulders sag as she lets out a soft sigh. Then she shrugs. "Yeah." A pause. "Most people pretend they don't realise it."

    She doesn't elaborate. You don't push.

*else
    *bug Invalid trait

You slide onto the table, sinking into the creased leather. Katie holds the wooden dowel in her hand like a baton. It's hand-carved, with dark notches and chipped edges, and one end is pointed. She smiles at you, her intensity softening.

"Okay," she says gently, almost to herself. "Just above the elbow, first."

You don't feel it right away. Then the nerve fires. A clean, precise pain. Some part of you watches your hand twitch. It doesn't feel connected.

*choice
    #Stay still. Let it pass.
        *gosub_scene utils increase_composure
        The pain crests, then vanishes. You don't even need to breathe deep. Nothing needs adjusting.

    #Focus on her technique instead of the pain.
        *gosub_scene utils increase_analysis
        She wasn't jabbing your elbow randomly. Her eyes tracked the joint line, first your wrist, then your elbow. The notches on the rod are for calibration.

    #Track her face instead of the pain.
        *gosub_scene utils increase_empathy
        The pain cuts clean and then fades. You keep your arm steady and watch her.

        Her smile holds, but there's no crease around her eyes. You don't say anything.

Your hand relaxes again. Perfectly functional. Katie rotates your wrist gently, presses a spot below the elbow, and nods to herself.

"Okay, here is where it gets interesting," she says. "You can change how you receive pain signals. Right now, when they activate, your nerves send a flood of pain signals to your brain, and their arrival overrides everything else. That's why you freeze up and scream." 

She talks faster. "This time when I press, don't think about the pain. Look into my eyes. It creates an alternative focus for your brain, providing a large amount of neural distraction."

Katie takes a deep breath, sucking in air through her teeth. "Okay, okay. Eye contact, then pressure. Keep the gaze." Then she makes eye contact with you. When she has your gaze, she presses the dowel into the spot below your elbow again.

A dull throb.

She withdraws the dowel, and the pain fades. Katie scans your elbow, the veins on your neck, your autonomic responses.

*if highest_trait = "analysis"
    Interesting concept. Pain as a signal, not as a fact. Counter-intuitive, but there could be something to it.
*elseif highest_trait = "composure"
    You compare this with the previous elbow signal. Identical. But only the first one felt threatening.
*elseif highest_trait = "empathy"
    You see that she collected herself before proceeding. You feel her intense concentration. She [i]needs[/i] to do this right.
*else
    *bug Invalid trait

"Good attenuation." She hands you the rod and points at her own elbow. "With practice, you can redirect a lot of your attention. Here, press like I did and watch my reaction." She looks at you for a second, then closes her eyes.

*choice
    #Copy her technique and watch her response.
        *gosub_scene utils increase_analysis
        You press at the crook of her elbow, mirroring her earlier grip and angle. Her skin is warm. The resistance is subtle, the nerves yielding to the rod.

        Her body shifts. She exhales softly through her nose. Then her relaxed smile returns.

        You consider her responses. Barely any physical reaction. Only tiny hints that she felt anything at all.

    #Study her face as well as her reaction.
        *gosub_scene utils increase_empathy
        You press gently into the crook of her elbow, minding the pressure. Her skin is warm. You watch how she flows with it. How she absorbs it, without pushing back.

        She exhales, quietly, evenly. Trust, maybe. Or habit.

    #Follow her instructions carefully.
        *gosub_scene utils increase_composure
        You press at the crook of her elbow, just like she showed you. Clean, steady pressure.

        Katie exhales through her nose. Relaxed. Her shoulders stay level. A modest smile.

        "Good pacing," she says. "You didn't rush it."

After a few more exercises, Katie's chatter returns. "Okay, that's a good baseline! Your proprioceptive feedback is surprisingly consistent. I think that's all for today, let me just make sure I didn't forget anything."

She scoots over to the desk and rifles through the untidy stack of papers. As she shuffles the papers, you notice a manuscript float to the top, thicker than the others. "REJECTED" is stamped on the front, obscuring the title. Katie sees it too, and snatches it, sliding it to the bottom of the paper pile. She glances back, notices you watching, and her shoulders sag. But she doesn't say anything.

*choice
    #Step back so she doesn't have to explain.
        *gosub_scene utils increase_empathy
        *set katie_friendship +1
        You gather the wooden dowels together.
    #Stay quiet. Not the right moment to press.
        *gosub_scene utils increase_composure
        *set katie_friendship +1
        You want to say something, but you hold your tongue. You let her recover at her own pace.

    #Think about what it means.
        *gosub_scene utils increase_analysis
        She shoved the paper into the pile like it was an unwanted flashback. You make a mental note.

Her smile reappears, too fast and too wide. "Okay! First session complete!" she says, wrenching the cap on a jar of green ointment tight. "I'll email you some exercises you can do in the meantime."

She hands you a squeeze ball with metal studs embedded in its surface like tiny teeth. "For homework. Press it until it stings. Try not to flinch." Her smile is back, wide and bright, but her hand keeps squeezing the handle of her duffel bag. Tight, loose, tight again. The plastic handle creaks.

You nod. 

"Thanks for showing up, by the way. Most people..." She trails off. "Anyway. Next time?"

*choice
    #"Next time."
        *set katie_friendship +2
        "Next time," you say.

        Katie blinks. Her hand eases off the duffel handle. "Okay. Cool. Yes. That works."

        She glances at the squeeze ball in your hand. "Make a note of your reactions if you can. Words, sensations, anything weird. Doesn't have to be formal."

        She opens the door, and her voice drops even more. "Glad you came. I mean that."

    #"I don't think I'll come back."
        Are you sure you want to decline her offer?
        *choice
            #Yes.
                *set katie_subplot_status "rejected"
                You give a small shake of your head. "Probably not. But thanks for today."

                The smile stays, but the rest of her face doesn't bother pretending. "Ah. Got it. Yeah, no problem."

                "Still," she says, her smile retreating. "Got some good data. Thanks for that."

                She opens the lab door and retreats.

                As you leave, you take one last glance back. She's still at the desk, gazing at the empty hallway.

            #No. [i](Accept her offer.)[/i]
                *set katie_friendship +2
                "Next time," you say.

                Katie blinks once, surprised. Her hand eases off the duffel handle. "Okay. Cool. Yes. That works."

                She glances at the squeeze ball in your hand. "Make a note of your reactions if you can. Words, sensations, anything weird. Doesn't have to be formal."

                She opens the door, and her voice drops even more. "Glad you came. I mean that."

*return

*label event_2
Fluorescent tubes flicker behind cracked plastic coverings, throwing sickly yellow light onto the room. From the far side, an air conditioner emits a low hum, circulating recycled air that tastes stale in your throat. A standard function room in a standard podium clubhouse in a standard private housing estate.

Katie's already here, kneeling by a row of tape measures on the carpet. A large duffel bag is by the wall, sensor cables and unidentifiable wood and metal implements peeking out from it. She's arranging the tape measures and doesn't notice you entering.

You stand a few metres away, and she finally notices. The smile comes too fast.

"You came, ${first_name}! That's cool. I wasn't sure if I confirmed the time properly. I always forget that step. Anyway, you're here!"

She launches into an explanation of how she managed to book the place — how she's not a resident here, but their website uses an old reservation portal, so she logged in as admin, she doesn't remember how, clicked the wrong thing and got in, now it's technically unlisted, which means no one should be here, and then she talked to the maintenance guy until he surrendered the door key.

She looks like she's going to keep going, but then stops.

"Sorry. That was too much info. I'm trying to talk more... normally. Um... but this space is okay, right?"

*choice
    #Focus on her body language.
        *gosub_scene utils increase_analysis
        A practised smile, but no eye contact. Her words speed up as she speaks.
    #Listen to what's underneath her words.
        *gosub_scene utils increase_empathy
        She started infodumping almost as soon as she saw you. Then she flinched before you even said anything.
    #Keep silent for now, giving her space.
        *gosub_scene utils increase_composure
        You just nod, giving her space to gather her bearings.

Katie hands you a folded white towel and a metallic object that looks like a hostile TV remote control, all weird angles and protrusions. "The haptic sensors adapt to your nerve signals!" she says, the words flooding out. "It adjusts in real time to your muscles as they expand and contract. There's a gyroscope for inertial compensation. Filters out noise so we only measure the nerve responses."

Her arms wave energetically as she explains the design. Adaptations for skin pressure, electrical reactivity, biofeedback, and dermal adaptations. Your eyes start to drift, but she continues for a few more breathless sentences before she notices.

"Oh. I was too technical again. I just assume people are interested in the same things I am..." Her shoulders drop. "Never mind..."

She peels the backing tape off a sensor, the adhesive coming off with a wet ripping sound. Holding the sensor delicately, she looks at you. "You can ask stuff if you want, by the way. Some people like to know what's going on."

An uncertain pause, her mouth twitching into a brief frown. "Some people don't. That's fine too. Either way."

*choice
    #Wonder whether she's memorised this entire sequence.
        *gosub_scene utils increase_analysis
        You can hear it in her speech. Her tone is too polished, like a flight attendant reciting safety guidelines.
    #Make it clear that you're still listening.
        *gosub_scene utils increase_empathy
        "I'm following," you say, trying to bring warmth into your voice. "It sounds interesting. I'd like to know more."

        She blinks rapidly, and her gaze meets yours. "Really?" A half-smile appears on her face.
    #Keep steady and wait for her.
        *gosub_scene utils increase_composure
        You stay silent. You wait for her, to let her choose what to do next.

Katie starts explaining again, but this time she talks more slowly and watches your face while speaking.

She crosses to her duffel bag and takes out the wooden dowels, the same ones as before. Three exercises this time, each one targeting different nerve clusters. First, gentle pressure to familiarise the nerves with discomfort. Then, slightly more pressure, but not enough to trigger a panic response, followed by progressive conditioning exercises to build resistance. She explains that the exercises were inspired by judo principles.

"Not published. Yet." Her voice lifts slightly on the [i]yet[/i].

After you complete each exercise, she runs her eyes over the sensor readouts, taps on her tablet, and makes small adjustments to how you hold the rods.

*choice
    #Consider her approach, how she integrates the data into her adjustments.
        *gosub_scene utils increase_analysis
        She reads your micro-expressions and cross-references them with the sensor data. Rapid calculation, precise modifications. Repeat. Her eyes dart from the table to the wooden dowel to your face and back to the table.

    #Notice how she studies you, looking for signs of discomfort.
        *gosub_scene utils increase_empathy
        Her gaze is intense and focused when she's observing you. She scans for discomfort, notices the tightening around your eyes, the clench in your jaw, your cheeks tensing. 

        "This one might spike," she says. You realise she's mirroring your reactions.

    #Hold still through the exercises, to make it easier for her to calibrate.
        *gosub_scene utils increase_composure
        You hold still, your breathing steady even while she's applying pressure to your nerves. She taught you that flinching only amplifies the sensations.

        She pauses after another adjustment cycle. "Most people can't control their twitching. You've learnt to control your response in a really short time."

        The room is almost silent, the only sound being the soft tap of her fingertips on the tablet screen.

Katie retrieves something that looks like a tuning fork from the duffel bag. The two prongs are wrapped in a layer of black electrical tape, and the handle is made of plain plastic. A copper wire extends from the base of the handle, leading to a battery pack.

"This tool is different from the others. It doesn't suppress pain, it [i]modulates[/i] it. It interferes with the actual nerve signals so that your brain doesn't even receive the pain. No one has ever made anything like this before."

*page_break
She looks at it for a second, runs her fingers gently down the tines, and then flicks a tiny switch on the side of the handle. You don't hear anything, but you feel a low, deep vibration, like you're standing in front of a subwoofer. Your skin tightens, and your arms tense up reflexively.

"It delivers targeted vibrations at harmonic frequencies. If it's calibrated correctly to your nervous system, it can scramble nerve signals, exactly like jamming a radio channel with static," Katie explains. She breaks out into a wide grin as she admires the device.

"If the brain gets a scrambled signal from a nerve, it downplays it. This fork distorts the signal just enough to do that, without causing any harm. It's not electrical, it's haptic, like what they use in neural rehab for phantom limb pain."

She kneels at your side and raises the fork to your forearm. You notice her grip on the plastic handle, so tight that her knuckles are white and the veins stand out at her wrist. "It should be fine," she says.

Her eyes are fixed on you. Her hand hovers, the fork a whisper from your skin. She takes a deep breath.

She touches the fork to your forearm.

*page_break
There's no pain.

Something vibrates in your bones. There's no sound. No pressure. Your muscles twitch, like they're reacting to a stimulus that hasn't arrived.

Then it hits. A dislocation. Your arm is still there, but it's no longer yours.

Katie leans forward and looks up at your eyes. Her breathing has quickened, now shallow and irregular. She's staring right at you.

"Did that feel okay?" Her voice is thin.

Then the words tumble out. "It's a lot to take in. Like, your arm doesn't feel like it's yours any more, and it feels weird, not pain, but... Sorry. It's not... I'm not trying to lecture you."

She rises and steps back, looking down at the floor, pulling the fork away with her. As the fork breaks contact, your arm feels like it's returned, but still not quite right. Katie swallows, glances at the tablet, then looks up at you again. "It... worked. Should have worked. You can choose whether you want to feel pain in your arm or not... for the next hour or so."

You pinch your arm, to test. A pinching sensation, but numb. It reminds you of dental anaesthetic. Then you try again, this time expecting pain, and a sharp sting arrives.

Katie's voice wavers. "I can make more. For you. If you want."

She's not looking at her instruments, her data, or your arm now. Just your face. She looks away, then back.

"You're... patient. You don't just... shut down when I talk."

A long pause. Her lips quiver. Then, a deep breath: "Would it be weird if I asked you for help, ${first_name}? Help with... talking with people?"

*choice
    #Sense how much this means to her.
        *gosub_scene utils increase_empathy
        *set katie_friendship +2
        She's barely breathing, as still as a statue. But she hasn't turned away.

        You speak quietly. "No, it's not weird."

        She continues staring at you, as if your words didn't reach her.

        "I'm not great at this either," you say. "But if you want... we can figure it out together."
    #Keep your expression neutral, your voice even.
        *gosub_scene utils increase_composure
        *set katie_friendship +1
        Her shoulders are already drawn in. You maintain steady eye contact and keep your voice even.

        "It's not weird. Let me think about how I might be able to help."

        You see her posture ease. She stops holding her breath.

        "If you want, we can figure this out together."
    #Consider what she is asking for help with.
        *gosub_scene utils increase_analysis
        *set katie_friendship +2
        Her research has rules. Cause and effect. Feedback. Talking with people isn't clear like that.

        "I could provide feedback," you say. "And I want to understand more first."

Katie nods once and mouths "thank you", though the words are inaudible. She tries to form a smile, but it breaks halfway through, becoming just a slight crease at the corner of her mouth. She straightens, says she needs to pack up. Her hands move easily, like she's playing [i]Bishi Bashi Champ[/i], clearing cables, snapping lids shut, collecting sensors.

The silence returns. From somewhere nearby, water glugs through old pipes.

"Thanks for coming today," Katie says, not looking at you. She crams all of the gear into her duffel bag. The zip gets stuck halfway.

Your arm still feels like it's vibrating. Still different, still disembodied. You raise your hand, and your fingers curl into a loose fist by themselves.

Katie opens the door for you. The hallway outside looks exactly like it did before. "I'll send you a link, for scheduling," she says as you leave.

The buzz in your forearm follows you home.

[i]Insight settles in your body.[/i]
*return

*label event_3
The HKU canteen is a long, brightly lit hall. Polished laminate flooring, plastic plants in plastic pots, sagging ceiling lights. A few students sit in ones and twos on hard chairs at wooden tables. The lunch rush has subsided, the tabletops littered with half-finished trays.

You spot Katie at the far end of the hall, seated at a booth for four next to one of the big grid-patterned windows. A few rays of sunlight filter in. She's visible there, but it seems like she's occupying a separate space from the other students.

A neat ponytail and a hint of makeup. An unzipped navy windbreaker frames a white T-shirt with "Bonjour Tristesse" splashed across the front. Dark bootcut jeans, clean canvas sneakers, and a black crossbody bag beside her on the seat.

Back rigid, shoulders square. Both her hands are flat on the table, palms down, elbows at a right angle. A laminated card peeks out from under one hand.

The food on her tray is untouched. A plate of steamed rice, flanked by two thick slabs of chicken thigh, pan-fried to dryness and lacquered in a glossy, rust-coloured gravy. A few scraps of steamed broccoli and half-translucent cabbage huddle at the edge of the plate. Milk tea in a chipped white mug. A thin, unbroken skin has formed on the surface.

Her head pans across the hall. She spots you, and instantly rearranges her face into a smile.

*choice
    #Analyse her actions.
        *gosub_scene utils increase_analysis
        The smile arrives in stages. Eyes first, then mouth, then a slight head tilt, like she's following a checklist for "greeting a friend." Her shoulders drop at the right time.

    #Note her presentation.
        *gosub_scene utils increase_composure
        She's set up her formation. Chosen her position, her appearance, her expression. You note it without judgement and approach.

    #Sense the effort behind her actions.
        *gosub_scene utils increase_empathy
        The smile wavers. She's putting in so much effort that the strain seeps through.

"Hi!" Her voice is too high, but it drops on the next sentence. "Thanks for coming. I got here early to get a good table. This one has the best lighting. Natural light." She flings her right arm at the window, then freezes. "Sorry. I said too much about tables."

Her hands return to their original positions, stuck to the table. Bullet points in neat handwriting peek out from the laminated card under her palm. She slides the card into her jeans pocket.

Your order number flashes on the overhead screen, so you go and get your seafood ramen. On your return, you see that Katie has loosened up her posture, and she's torn the paper wrapper from her chopsticks into a pile of small scraps.

*page_break
"So." She pauses, rearranging the paper scraps into a tiny pyramid. "I asked you here because... I need practice. With this." A vague sweep of her hand indicates the canteen, the untouched food, and you.

Her voice softens, no longer enthusiastic. "I want to be able to just... talk."

She exhales, then stares at your ramen with a tight-lipped smile. "Sometimes I see it when it happens. They stare through me. Their smile turns stiff. They pretend to listen, but they're waiting for the first excuse to exit."

Katie stares at her milk tea, the skin on top still unbroken. She steadies herself, then speaks to her hands.

"I read about how to succeed socially. I practise in front of a mirror. But whatever I do, it feels like... like I know the words, but they never land in the right order." She looks at you. "Does that make sense?"

Her hands are still flat on the table. Her forearms tighten.

"I just want to speak the same language everyone else does."

*choice
    #"You're learning all the unwritten rules. That's hard work."
        *gosub_scene utils increase_empathy
        *set katie_friendship +1
        "You're learning all the unwritten rules. That's hard work."

        Katie's eyes widen. "But it looks so natural for everyone else. They just know what to do in any situation."

        "They learned it without realising they were learning."

        "Really?"

    #"Let's start simple. Tell me about something you enjoyed this week."
        *gosub_scene utils increase_composure
        "Let's start simple. Tell me about something you enjoyed this week."

        Katie looks at the pyramid of paper scraps and exhales slowly. "Something I enjoyed this week..."

        "Yes," you say. "You don't have to have a goal. Just say anything."

        She nods, although her lips are pursed in a slight frown. "Okay, I'll try. Let me think about this a bit."

    #"Maybe it's also about finding people you're compatible with."
        *gosub_scene utils increase_analysis
        *set katie_friendship +1
        "Maybe it's also about finding people you're compatible with."

        "Finding people I'm compatible with," Katie repeats softly.

        "So... learning how to connect, but also, finding the right people to connect with."

        She looks at you and smiles, her forehead creasing. "You're right. I need to do both."

Katie breathes in deep. Her arms and shoulders relax, but her back is still straight. She picks up her milk tea with both hands, raises it to her mouth, and takes a sip. The skin breaks and swirls away.

"You know what's weird?" she says, glancing out the window. "I rehearsed asking if you wanted to sit here. But you just... sat down."

A quiet laugh, this time accompanied by a slight smile. "Does it come naturally to you?"

*fake_choice
    #"I rehearse difficult conversations too."
        "I rehearse difficult conversations too."

        Katie looks back at you. "Yeah?"

        "Yeah. It's reassuring. Keeps me grounded."

    #"I'm no good at keeping in touch with people."
        "I'm no good at keeping in touch with people."

        Katie looks back at you. "Yeah?"

        "It's so easy to want to message someone, and then just not do it."

    #"I don't know how to comfort someone when they're upset."
        "I don't know how to comfort someone when they're upset."

        Katie looks back at you. "Yeah?"

        "Yeah. I never know what I'm supposed to say."

Someone nearby slurps loudly as they drink their soup. "So, I never asked. What do you... do, ${first_name}? When you're not fighting, I mean."

Direct eye contact.

"Work, mostly. Marketing reports that no one reads." You pluck out the lone prawn floating in your ramen. "You?"

"Research and lab work. I'm finishing up my master's thesis." She pauses. "I've been trying to learn Cantonese recently."

"Nice. How's it going?"

"I'm not sure. I can say vasovagal reflex but not pineapple bun."

"Useful."

"Not really. One time, I mispronounced black coffee so badly the waitress had no idea what I wanted."

Katie laughs, relaxing into her seat. It trails off naturally. You see a flash of surprise in her face.

She continues, in the same easy tone. "There's this theory in neurotrauma. They say language rewires itself around pain perception. Like, people recovering from strokes, they relearn words and body mapping at the same time."

It hangs in the air, a bit too long. Her cheeks flush. She stares at her tray, where the chicken still sits, untouched. Her hands drop to her lap.

*choice
    #"When you talk about this, your passion is obvious."
        *gosub_scene utils increase_empathy
        *set katie_friendship +1
        *set katie_masking -3
        "When you talk about this, your passion is obvious."

        She blinks, and looks back up. "Huh. That could be true. Still, I need to figure out better timing."

        She lightly brushes her neck with her fingers, and then smiles. It falters into a frown, but just a small one. "No one else says that, ${first_name}. Everyone else, their eyes glaze over. It's nice that my rambling isn't scaring you off."

        She spears her chicken thigh with her fork and raises the entire thing to her mouth, taking a big bite. She chews for a while.

        "So... the enthusiasm, I should keep that. And look for situations where it fits."

    #"No pressure at all. Let's talk about something simple."
        *gosub_scene utils increase_composure
        "No pressure at all. Let's talk about something simple."

        "Okay, right. Let's do that." She looks up at you, her expression blank. "What's your favourite food?"

        You answer, then wait. Katie tilts her head. "That felt different from what I did."

        She begins to slowly nod her head. "Talking about easy things, it's relaxing. That's why people do it."

    #"We can take turns. I'll tell you all about spreadsheets."
        *gosub_scene utils increase_analysis
        *set katie_friendship +1
        "We can take turns. I'll tell you all about spreadsheets."

        Katie looks back up.

        "Let me explain the difference between VLOOKUP and INDEX MATCH." You launch into a detailed, methodical explanation. She stares at you, mouth parted, eyes starting to glaze.

        "Wait, what's a lookup?"

        "Say I've got a column of customer names, and I need to get their revenue figures from another table. I'd use a lookup."

        "Oh." She sits up straight. "We use merge for that."

        "Fair enough." You lean back into your seat.

        She looks at you and laughs.

A janitor wheels past with a cart of abandoned meals. Katie watches her disappear into the service entrance.

"Do I make you uncomfortable, ${first_name}?" she asks. She fishes out a rubber band from her pocket and hooks it between her thumb and index finger. The rubber makes a tiny zinging sound each time she stretches it.

"I'm still weird, right? I'm trying not to be. Does it... work?"

*if highest_trait = "analysis"
    "You can keep doing that with the rubber band. It doesn't bother me."

    Katie's mouth falls open, and she covers it with one hand. Then, she mumbles, "... thanks. I appreciate it."
*elseif highest_trait = "composure"
    "If I thought you were weird, I wouldn't be here."

    Katie's fidgeting slows. "Maybe I'm improving," she says quietly, mostly to herself.
*elseif highest_trait = "empathy"
    You lean forward. "You're not weird. You're trying hard. I can see the effort you put in."

    Katie stops fidgeting. Her eyes brighten even as she bites her lower lip. She looks down at her meal and a smile flashes across her face.
*else
    *bug Invalid highest_trait

*page_break
You continue talking. Katie asks how you train for fights, whether you prefer morning or evening sessions, how you find the time to fit in your training. She starts to ask follow-up questions.

You're in the middle of explaining your pre-dawn Star Ferry sprints when she interrupts with a question, then cuts it off.

"Sorry. I should have waited for you to finish." She looks down, pressing her palms flat against the table.

"I wrote down some questions last night. For talking." Her voice is flat.

The noise around you continues. Students chatting, a kitchen timer beeping, a dropped pair of chopsticks. But the space between you seems to shrink.

"I feel like... like I'm faking it and everyone knows. Last week, I was talking with someone from the lab. Halfway through, she starts packing her bag."

It's almost a whisper now. "Her eyes just... drifted past me."

Her arms remain on the table, palms flat, fingers braced, but they're shaking. She's looking at you, searching your face.

She hasn't looked away.

*choice
    #Suggest that Katie reconsider her interpretation.
        *gosub_scene utils increase_analysis
        *set katie_friendship +2
        "When someone looks away, what explanation do you give yourself?"

        "It's because they're not interested. They're thinking up an excuse to leave."

        "Do you ever test the other explanations?"

        Katie draws in a breath, then slowly releases it. "No."

        She stares at the ceiling, mouth open, as she rubs her chin with one hand. "I didn't realise I was doing this."

    #Lean forward slightly and affirm that you're here for her.
        *gosub_scene utils increase_empathy
        *set katie_friendship +2
        "I'm still here," you say. "I'm here for you."

        "Really?" Katie's eyes widen, and she searches your face, her breath held. Whatever she finds there, it makes her smile.

        "You mean that," she says. It's not a question.

        She blinks once, then looks to the side. "${first_name}... thank you."

    #Stay steady, grounding yourself and her.
        *gosub_scene utils increase_composure
        *set katie_friendship +1
        You maintain eye contact, staying where you are, breath steady.

        "I'm still here," you say, after a moment.

        Katie relaxes, her grip on the table loosening.

        She looks to the side, but a smile peeks through, before flickering out.

*page_break
Katie takes a long sip from her milk tea. "I... I should finish this chicken." She scrapes the gravy away and stabs the chicken thigh with her fork. She chews slowly, her attention fixed on the chicken.

You both finish your meals quietly, chopsticks scraping against plastic. A drink machine hisses, and the ventilation system kicks in with a rumble.

The sun cuts in at a low angle, throwing soft golden light onto the table. Katie packs her bag. Unhurried.

"Next time, maybe we can go somewhere with better food." She looks at the floor while she's saying it.

"If you're free," she adds, this time meeting your eyes.

Then she's gone, without waiting for your reply.

*return

*label event_4
A familiar pneumatic hiss as the MTR carriage opens in sync with the screen doors. HKU Station is less busy in mid-afternoon, the university jammed into a steep residential hillside. You go up the escalators and out of the station, take in the smell of damp earth, cross the footbridge, and ride more escalators until you arrive at the relatively open space of Centennial Campus. West, up, through another hallway. A slight ache in your thighs.

A glass-fronted entrance, a reception desk, card-access doors. The only sound is the ticking of the wall clock. You give the receptionist Katie's room number and write your name on the clipboard. A few words into the phone, then a click. Soon, a young woman emerges from the lifts. You don't recognise her, but she waves at you, nods to the receptionist, and leads you to the waiting lift.

She clears her throat. "Hey. Katie's been off these few days. Hope you can help her out of it." You mumble something about trying your best. You imagine Katie and her roommate.

Beige corridor, number plates on the doors, tiled flooring. She opens the main door, leads you in, and disappears into her own bedroom. You take a moment to catalogue the space. The rectangular wooden table by the wall is surrounded by four flimsy plastic chairs. It's flanked by the bedroom door and a small kitchen area with just a metal sink and a microwave. The table holds only a box file binder and a slim laptop computer, the cover shut.

Katie's sitting silently on the plastic chair at the long end of the table.

*page_break
She's dressed in a plain sloganless T-shirt, loose sweatpants, cheap plastic slippers. Her unkempt brunette hair flows behind her, reaching slightly below her shoulders. Her eyes, slightly puffy, have bags under them. You've come to expect the [i]snap, snap, snap[/i] of the elastic on her wrist, but there's no sound today. Her legs stay still. No bounce.

You ease into the chair closest to Katie. Her mouth opens to say hello, but it closes again without uttering a word. She stares at the binder on the table. Pulls her legs up, hugging her knees to her chest, arms wrapped around her shins.

*choice
    #Notice how this feels different from her usual frustrations.
        *gosub_scene utils increase_empathy
        It's not only defeat, it feels more like despair. She doesn't usually let failure deter her. What's different this time? You look at her and mouth a silent question.
    #Sit a while more. Let her know you're here for her.
        *gosub_scene utils increase_composure
        Katie looks defeated. But there's no need to rush into action. Sit with her for a while, steady her first.
    #Think about what's wrong with Katie.
        *gosub_scene utils increase_analysis
        She's not her usual self. Reason unknown. But you suspect the binder will have clues. You glance at her, then at the binder.

You sense it's not the right moment to examine the binder. You continue sitting, resting your gaze somewhere past her shoulder, keeping her in your peripheral vision.

She continues to stare at the binder. After a while, she meets your eyes and then looks away.

"I should get us some water to drink," she sighs, and trudges over to the sink. You hear the tap running, see her open the top cupboard, then close it, then retrieve two tumblers from the drying rack. She stands there, water flowing, waiting. Stalling. But it helps.

After enough time to fill a bucket with water, Katie returns and sets the tumblers on the table, still dripping with water. She's sitting upright now, looking up and to her right, at some blank section of the ceiling.

Then she looks at you. She tries to arrange her lips into a smile, but they barely twitch. Her shoulders sag, and she gives a nod towards the binder.

"They've killed it."

You pick up the binder. You don't know what you were expecting, but it feels ordinary, unremarkable.

*page_break You start reading.
[b]PAIN TOLERANCE ENHANCEMENT THROUGH SYSTEMATIC NERVE DESENSITISATION[/b]

BY

KATHERINE REYNOLDS

A thesis submitted in partial fulfilment of the requirements for the degree of Master of Philosophy in Public Health at The University of Hong Kong

School of Public Health, Division of Kinesiology

${current_month} ${current_year}

*page_break You flip through the binder.
You leaf through. An abstract, a background with more than twenty key citations. Phrases that you've vaguely heard before: "linear mixed models," "multiple-comparison control," "primary/secondary endpoints." An ethics submission cover page, stamped "HKU/HA HKW IRB Ref: UW 24-510". A power-analysis printout from something called [i]G*Power[/i] with a pile of numbers for [i]f[/i], [i]α[/i], and [i]η²[/i], whatever that means. Repeated-measures design. ANOVA.

More charts, tables showing "test-retest reliability". Booking confirmations for a sensory-testing room. Loan agreements for a "pressure algometer loan via Dept. of Anaesthesiology Pain Research Unit." Questionnaires with names like "Pain Catastrophising Scale" and "State-Trait Anxiety Inventory."

It's well over two hundred pages.

*page_break You reach the final page.
Katie's voice is flat and mechanical. "That's what I've been working on."

"Impressive." It slips out before you can find better words.

"Here's what they said, though."

She flips open the laptop and turns the screen to you, showing Outlook with the "thesis" folder open. She exhales slowly, nudges the laptop towards you, and leans back into her chair.

You scroll through the emails. The timeline unfolds:

"Clarify stimulus calibration protocol — additional documentation required"
*line_break
"Recruitment materials: remove word 'pain' from poster"
*line_break
"Referral to full review due to deception component"
*line_break
"Primary reviewers indicate substantial revisions would be required for an approvable version"
*line_break
"HKU/HA HKW IRB Decision — UW 24-510"

You click on that last one.
*page_break
[i]Thank you for your application UW 24-510. Following review by the HKU/HA HKW Institutional Review Board, approval cannot be granted in its current form. The Board identified substantive issues relating to risk mitigation, consent documentation, and the adverse-event plan.[/i]

Ah.

*if highest_trait = "analysis"
    You see how Katie answered every email in days. As time passed, the gaps between their emails stretched.
*elseif highest_trait = "composure"
    A harsh rejection. You take a moment to settle yourself.
*elseif highest_trait = "empathy"
    You imagine how Katie would have felt after each reply. Maybe after one more email, they'd accept her thesis.
*else
    *bug Invalid highest_trait

The laptop fan whirs faintly. You glance up. Katie's looking at you, but she's managed to sink into the hard plastic chair with her shoulders drawn in. Now her gaze is drifting past you, unfocused.

You drink from your glass, then slide Katie's towards her. She reluctantly takes a sip and places it back on the table.

You choose your words.

*choice
    #"Could I show you something about these emails?"
        *gosub_scene utils increase_analysis
        *set katie_friendship +1
        "Could I show you something about these emails? I think I have a pretty good idea of what they're looking for."

        She looks at you. "They're looking to shut it down."

    #"Take a breath. This isn't over."
        *gosub_scene utils increase_composure
        "Take a breath. This isn't over. There's a way forward, as long as we have the right strategy."

        She looks at you. "I don't think so. You read the emails. They're not interested."
    #"You don't have to fight this battle alone."
        *gosub_scene utils increase_empathy
        *set katie_friendship +1
        "You don't have to fight this battle alone."

        She looks at you. "I... don't know how to fight this kind of battle."

But she sits up straight and takes a deep breath. Her hands clasp the water glass, and she continues.

"I did everything they wanted. They wanted detailed risk mitigation protocols, I spent days writing contingency procedures for every possible adverse event. I haven't even included the neural feedback devices we used. They would never approve it. [i]Unacceptable participant risk.[/i]" She makes air quotes.

"I submit everything they ask for, and then they respond with new compliance demands. Nothing I do will ever be enough for them."

She slows down. "You see it too, right?"

You're not as sure. Katie's looking at you expectantly. You collect your thoughts.

The review committee doesn't like something about Katie's work. And the escalating paperwork requirements convey a message.

How to explain this tactfully?

*choice
    #"Here's how to play this game."
        *set katie_masking +3
        "Here's how to play this game."

        You explain that the review committee has their own concerns, and it would be helpful to address them.
    #"I might know how to get through to them."
        "I might know how to get through to them."
        
        You explain the institutional dynamics, what adjustments might help to address their real concerns.
    #"I'll go through this with you."
        "I'll go through this with you."

        You say that there are still things she can do, and you'll be there with her to navigate the process.

The familiar snapping sound of Katie's hair elastic returns. You outline a plan: find her supervisor and have an informal chat with them. Submit again, leaving out the parts they're concerned about.

She looks away from you. "${first_name}... I know you're trying to help me. I really do. But I can't do this. That's lying. That's... wrong."

Her hands clench around the water glass, knuckles almost white, but her right knee's bouncing rapidly under the table.

*choice
    #Consider what this reveals about her.
        *gosub_scene utils increase_empathy
        You heard how her voice wavered. But even now, she's here, waiting for you to respond. Her eyes still meet yours, though she's blinking rapidly.
    #Accept her refusal before deciding what to do next.
        *gosub_scene utils increase_composure
        *set katie_masking -6
        She's closed the door. Forcing it open won't help. You breathe steadily, letting her objection exist without needing to meet it.
    #Think about how to overcome her objections.
        *gosub_scene utils increase_analysis
        *set katie_masking +6
        She said, "that's lying." To her, omission is deceit. You could tell her it's about emphasis, not avoidance.

You tell her a story. "We had this client once. A government division."

Katie leans forward, an elbow on the table, head resting on the palm of her hand, focused on you. You continue. "We told the back office like usual. But Dorothy from compliance kept bouncing things back, sometimes with these lists of questions, sometimes with requests for forms to be filled in. All this paperwork was taking weeks and holding things up.

"Some of us bumped into Dorothy at lunchtime one day. We were lining up at Fairwood, and my boss asked Dorothy what in the world was going on, just like that. Dorothy said, 'Paperwork is paperwork, but do you know they're on the PEP list?'

"The client was just handling sewage treatment."

Katie shakes her head. Then she squeezes her eyes shut. Her leg bounces. Her mouth opens as she takes in a gulp of air, and she takes two more quick breaths. A smile tugs at one corner of her mouth, but it twitches, becomes a grimace.

Her eyes are still closed as she speaks. "I didn't understand them, is that it? I didn't understand them. I just never tried to... never thought there might be more to it..."

She looks straight down, chin lowered to her chest. Her shoulders rise and fall. Up, down, up-down.

*choice
    #Say that she doesn't have to talk about it.
        "You don't have to talk about it right now. Take your time."

        "Okay. Thank you." She closes her eyes briefly.

    #Lightly rest your hand on her back.
        *set katie_friendship +2
        You rest your hand gently between her shoulder blades. You feel her warmth through the fabric, a steady heat. Katie's shoulders tense up, and her eyes widen. Then, after a moment, she leans into your touch, gaze still lowered. A tiny smile wavers at the corners of her mouth.

    #Sit quietly beside her.
        *set katie_friendship +1
        You sit with her. Giving her space. You match her breathing. She doesn't notice, but her breathing evens out, her body stills.

"Maybe... you could see your supervisor some time. Do they have office hours? Just something casual."

She sits up straight. Her words come faster now, precise. "Yes, I could. He's free on Wednesday and Thursday afternoons. I could email him to book a time."

"That works. See him and listen to what he has to say? Just some info gathering."

"Yes, I could discover the actual problems, and then I could explain how I can address all of their concerns —"

"Hmm, maybe sleep on it first? Give yourself some time to process it before you respond."

"Why wait?"

You see it: the need to act. Move first, think later.

*choice
    #Suggest learning more instead of rushing to act.
        *gosub_scene utils increase_analysis
        "Katie, it's understandable that you want to take action straight away. But we're going in without any real information. We'll be acting blind."
    #Remind her that she doesn't need to have all the answers straight away.
        *gosub_scene utils increase_empathy
        "Katie, I know that you want to fix things. But right now, that starts with listening."
    #Explain how waiting can be strategic.
        *gosub_scene utils increase_composure
        *set katie_masking +2
        "Katie, holding back here actually keeps you in control."

Katie nods slowly, then swallows. "${first_name}, will... will this really work?"

She covers her mouth briefly with one hand, eyes searching your face.

"It could." You maintain eye contact. "Practise. I can rehearse it with you, if you want."

"Practise. Rehearse... together?" Her eyes widen, then she repeats the words under her breath.

But then she runs one hand through her hair, tangling it further. "What... what if they just shut me down? What if they don't tell me anything?" She looks at the floor, then her eyes dart to you and to the wall clock and back.

*fake_choice
    #"It will work. Trust me."
    #"No guarantees. But it's the best shot we have."
    #"If this fails, we try something else. That's all."

She nods a bit too quickly. Then she notices you've gone quiet, and studies your face. She drums her fingers on the table.

Katie clears her throat. "You know, the fighting is simpler than this stuff. At least the punches hit you." She laughs, as if it were a joke.

Her smile falters. You try to arrange your face into a reassuring smile, then abandon the attempt. Better not to force it.

"Uhh..." She sighs. "This goes against my instincts. I [i]need[/i] to do something, you know? But... I'll try it, ${first_name}. I trust you."

Katie says she should prepare to meet her supervisor straight away. Even though she's looking right at you, it sounds like she's saying it to herself.

She moves to grab her water glass, pulling her chair nearer as she does so. Close enough that the smallest lean would close the gap. She takes a sip, sets the glass down, then her fingers tap lightly against the glass. Then she stops. She doesn't breathe out yet.

"Yeah... my supervisor, right? I can just email him to meet up. He has office hours, that's good, that's when people see him." She nods to herself too quickly.

*temp katie_held_hands false
*choice
    #Give her space, maintaining the boundary between you.
        *set katie_friendship +1
        You sit beside Katie, motionless. The rapid chatter continues, but becomes quieter with each sentence.

        She stops mid-sentence, whispers some reminder to herself. Sits up a bit straighter. Her fingers stop tapping, leg stops bouncing.

        "Yeah."
        
    #Rest your hand on the table near hers, an unspoken offer of connection.
        *set katie_friendship +2
        You rest your hand on the table, palm down, in the space between you. You lower your gaze, letting your eyes drift to the table.

        Katie notices. Her nodding abruptly stops. She stares at you, eyes wide, then looks down at your hand.

        *if (katie_friendship >= 9)
            *set katie_romance +1
            *set katie_held_hands true

            She swallows hard. Then she hovers her hand in mid-air for a moment, and lets it drift down. Her hand wavers, then lands short, finding your wrist instead of your hand.

            "Ah..." The sound's so soft that you feel it more than hear it. She steals a look at you. Then, eyes down, she inches her hand forwards, laying it over yours.

            Her palm is warm against you, her touch light, but deliberate. The space between you seems to shrink, as the moment pauses.

        *else
            She snaps her hair elastic, legs jittering. "Right. Supervisor. Yeah." She stares at your hand, but then looks down at the floor.

            The distance between you remains, unbroken. Her hand lifts, but the moment passes, and it settles back down. You don't push.
            
*if (katie_held_hands)
    She looks at you, steady and quiet, her hand staying on yours. "Thank you, ${first_name}."

    She clears her throat. "I... didn't anticipate this."
*else
    She looks at you, steady and quiet. "Thank you, ${first_name}. It's so easy to talk with you."

*page_break

Hundreds of pages of scholarly analysis. Meetings in sterile research labs and borrowed function rooms. Experimental neural feedback devices. Underground fighting for data collection.

This is how she lives. You wonder what it would mean, to live like that.

But that can wait. Right now, you're here with her.

*return

*label event_5
You make your way up through HKU to the Meng Wah Complex, here to help Katie with her departmental review for her thesis. Well, they call it a review, but it decides whether she's cleared to submit her thesis. A few students drift by, eyes downcast, as you head through the corridor. No voices, just footsteps. You've arranged to meet in an empty classroom next to the conference room. 

*if katie_romance >= 1
    Katie is inside, wearing black pumps and a grey collared blouse, buttoned up high, tucked tightly into dark slacks. A hint of eyeliner. She's sitting upright.
*else
    Katie is inside, wearing a grey collared blouse, tucked tightly into dark trousers. She's sitting upright.
Her duffel bag is on a desk, zipped up, no cables spilling out this time. She's bouncing the heel of one foot on the floor.

Seeing you, she turns and smiles wide. "${first_name}!"

The smile breaks just as quickly. She rises to her feet and moves towards you, but stops an arm's length away.

*choice
    #Look at her and smile. "Whenever you're ready."
        *set katie_friendship +1
        "Whenever you're ready."

        Katie's eyes rise to meet yours, then a smile breaks out on her face. Her arms start to rise, then fall to her sides.

    #Move closer. Hold out your hand.
        *set katie_friendship +1
        *set katie_romance +1
        You move into her space and hold out your hand. Katie's eyes rise to meet yours, unblinking. You feel, rather than see, her lean forward.

        She freezes for a moment. Then she takes your hand, her grip too firm at first, and then soft.

"Thanks for coming, this means so much to me. Okay, okay. They're waiting for us. Remember, let me do the talking."

Katie shuts her eyes and takes a deep breath, then rolls her shoulders back and widens her stance as her lips form silent words, testing her voice with a soft 'ah, ah' that drops in pitch.

She clears her throat, opens her eyes. Straightens. Grasps her duffel bag, curling her fingers around it.

"I'm ready. Let's go." She reaches to her hair tie, but then lowers her hand.

She wears the smile, the one she rehearsed.

You follow her into the corridor, then into the review room.

*page_break
Cold air blasts through the ceiling vents. The desks have been pushed to the walls, leaving the centre of the room empty but for a single plastic chair. Two long desks are arranged side-by-side near the far wall, the committee seated behind them: three Chinese men in their fifties, all in dress shirts. Green-capped Watsons distilled water bottles and thin stacks of loose A4 papers sit in front of each professor. Opposite them, a small table, laptop and projector already running.

"Good morning, Professor Szeto, Professor Ng, Professor Leung. Thank you for coming." Katie bows, then sets her duffel bag on the table and begins unzipping it. Two of the professors look up from their notes and nod.

"Please take a seat, Ms Reynolds."

*fake_choice
    #Look at the professors.
        All three professors look like they appeared, fully formed, from central casting — half-eye reading glasses, poker faces, palms down on the desk. Whatever they're thinking, you can't read it.

    #Look at Katie.
        Katie is setting up her equipment, her eyes on her hands. She's moving slower than usual, lowering each item into place without a sound.

    #Look around the room.
        There's a row of stacked lecture chairs along a wall. Just an ordinary classroom, repurposed into today's review room. You have to keep reminding yourself that this is not the final thesis defence.

The professor in the middle addresses you: "Thank you for assisting today. We've received your consent form. Please have a seat as well."

He waves a hand at a lecture chair behind Katie and off to one side, its folding desk arm down.

"Ms Reynolds, we've read your revised submission. You have twenty minutes for your presentation, followed by the live demonstration and questions. Please address the single-participant design in particular. Begin whenever you're ready."

*page_break
Katie starts speaking, her words controlled, slower than her usual pace. You catch phrases here and there: revised methodology overview, single-participant design justification. It's too technical to follow.

The professor on the left writes something down. The slides click past one after the other.
*if katie_masking > 50
    Katie rolls through her monologue, her voice clean.
*else
    Katie pushes through her monologue, speeding up, the control fraying.
She reaches the last slide. Then silence.

Katie steals a quick glance at you.

*choice
    #Nod and silently mouth to her, "keep it up."
        *set katie_masking +2
        You catch her eye and mouth the words, "keep it up."

        She takes a breath, her shoulders rising, and turns back to the committee.

    #Give her a smile.
        *set katie_masking -2
        You meet her eyes and smile. Her breath catches, and her face softens, maybe. She tears her eyes away from you and faces the committee again.

Professor Ng thanks Katie for the presentation, and asks her to proceed to the live protocol demonstration.

"To clarify, today's sequence is an unblinded demonstration of the protocol. It isn't included in the study data," Katie says.
*if katie_masking > 50
    Then she turns to you and says, "Please join me in the centre."
*else
    Then she turns to you and smiles — the professors can't see it — and says, "Please join me in the centre."

*page_break
You make your way to the chair in the centre. Katie narrates the protocol — "Baseline stimulus, then modulation" — though you already know it. Not for your benefit, for the committee.

She tapes a sensor to your forearm, the sticky gel cool on your bare skin. A single beep from the linked display tablet. The tablet's angled so the professors can see the readout as well. She taps a wooden dowel, once, just above your elbow. You twitch. The live trace on the tablet spikes once, then settles down.

Katie narrates: primary endpoint, raw response. One professor writes something down. The others don't.

She picks up the tuning fork from the table and explains it to the committee: "A haptic modulator, adapted from phantom-limb rehabilitation. Creates harmonic vibrations that selectively scramble nerve signals." They don't respond.
*if katie_masking > 50
    Her hands are steady on the handle as she applies the fork to your elbow.
*else
    Her knuckles are white, her grip tight on the duct-taped handle of the fork, as she applies it to your elbow.

The familiar feeling of dislocation. Your arm is still there, but it doesn't belong to you.

*page_break
Katie leans in and says, "Modulation on", too quietly for the professors to hear. Taps the dowel at the same nerve point above your elbow. You don't feel anything.

She reads out the number on the tablet. The professors straighten up and lean forward.

"Okay, ${first_name}, modulation off." Another tap. It registers this time. You flinch. The live trace spikes.

Katie reads out the number on the tablet. Even in this room, under the professors' eyes, in the silence, you can feel her pride through the way she says it.

Spike, no spike, spike, no spike. The professors are staring, eyes moving from the tablet to the tuning fork to your elbow. One of them has taken off his reading glasses.

*choice
    #Focus on the experiment.
        *gosub_scene utils increase_composure
        You draw your attention to the familiar dissociation in your elbow. Less strange this time, more of a fact that just exists. The equipment is simpler than last time, with a single sensor pad and a sleeker tuning fork. Katie scans the readings, adjusts the sensor, stares at your elbow.

    #Look at Katie.
        *gosub_scene utils increase_empathy
        Katie scans the readings, adjusts the sensor, stares at your elbow. She's too absorbed in her work, and there's no bandwidth for any idle talk. You stay quiet.

Katie removes the fork from your elbow, and your arm returns to normal, faster than last time. You feel an after-echo, fainter than before. She thanks you.

"Thank you for participating." Professor Ng this time.

You take a seat at the back of the room again, leaving Katie in the centre, alone. The questions start:

*page_break
"Ms Reynolds, today's demonstration is unblinded. In the study itself, how did you distinguish the effect of modulation from expectancy or suggestion?"

"Three safeguards. First, the participant knows the study concerns pain modulation, but isn't told whether any individual trial is active or sham. Second, the trial order is randomised, with sham trials interspersed throughout. Third, across repeated sessions, the galvanic responses track the participant's reported sensations, including the difference between active and sham trials."

Professor Ng looks up. "And what can you conclude from a single participant?"

"A repeatable effect in this participant under controlled conditions," Katie says. "I don't claim general efficacy. This is a proof-of-concept study, intended to justify replication with a larger sample."

"Mm-hmm." Professor Szeto's eyes move down his notepad. "Let's set the methodology aside for now. What is the tuning fork actually doing? What's your proposed mechanism?"

Katie's voice picks up. "At 80 Hz, the fork drives muscle spindle Ia afferents almost exclusively. The brain receives a sustained proprioceptive signal indicating movement when the limb is still. The prediction error compounds across roughly forty seconds. The proposal is that body-ownership circuits resolve the conflict by reducing the perceived ownership of the affected segment. This matches what the participant describes."

All three professors are now sitting up straight. Professor Leung speaks next. "Ms Reynolds, you call this dissociation. But the responses are also consistent with peripheral neuropathy. Why is dissociation the right framing?"

Katie hesitates for a few seconds, her hands slipping behind her back. You see her right hand grip her left wrist and squeeze tightly.

*temp nerve_conduction_confident false
*choice
    #Believe that Katie can handle the pressure.
        *set nerve_conduction_confident true
        *set katie_masking +2
        You breathe out easily. Maybe Katie senses it, or not. She releases her wrist grip and stands straighter before answering.

        "Certainly, a good question, and I grant the point. However, peripheral neuropathy involves degraded nerve conduction, whereas my participant has intact conduction, verified through reflex testing, therefore..."

        Her hands are steepled in front of her, at waist level. Professor Leung nods, writes something down on his notepad.

    #Consider the pressure on Katie's desire to be herself.
        *set katie_masking -2
        You breathe in, steadying yourself. Maybe Katie senses it, or not. She grips her wrist tighter.

        "That's a good question. I believe the difference is in the degraded nerve conduction, and I believe my participant has intact conduction. I should be able to confirm this..."

        Her pitch rises, small enough that it should be barely noticeable to the professors. Professor Leung strokes his chin with his thumb and index finger, without comment.

Minutes pass in a blur of jargon. Then: "That will be all. Please step outside. We will call you back after our deliberation."

You both exit. Just like that, you and Katie are back in the empty classroom.
*if katie_masking > 50
    Katie stands frozen in place for a moment, before she drops her shoulders and exhales through her nose. She turns to you.

    "Well, that's that. Hope they think my answers were good enough."
*else
    Katie turns to you. She drops her shoulders and hunches a bit, letting out a long exhale through her mouth, and brushes her ponytail.

    "${first_name}, what do you think? Did it go well?"

*choice
    #Tell her, "Hey. You aced it."
        *set katie_friendship +1
        "Hey, Katie. You aced it."

        "Really? You think so?" She has her arms out, like she's catching a beachball.

        "Yeah. A smooth presentation and then you answered the questions well."

        Katie lowers herself into a chair, and you sit down next to her, neither of you moving or saying much.

    #Reassure her with your hand on her shoulder. "I saw. You held it together."
        *set katie_friendship +1
        *set katie_romance +1
        "I saw, Katie. You held it together."

        You reach over and pat her shoulder. The contact makes a slapping sound, a bit too loud, but she beams and thanks you.

        "You think so, huh? I tried my best."

        She lowers herself into a chair, then pats the chair next to her. You sit down as well. Neither of you say anything, and the silence settles.

    #Recap the departmental review. "You handled it well."
        "You handled it well, Katie."

        "Ah. That's good. I tried my best."

        "Yes, your presentation was smooth, and you held up during the questions."

        You both sit down, neither of you saying much.

*if highest_trait = "analysis"
    Katie managed to present a convincing demo and answered the questions fairly well. She's probably running through it in her head right now.
*elseif highest_trait = "composure"
    Katie managed to mostly hold herself together when it mattered. You can see the cost, too.
*elseif highest_trait = "empathy"
    You told her she did well, but you don't know whether she believes it.
*else
    *bug Invalid highest_trait
*page_break
Three raps on the door and then it swings open. Professor Ng takes a step in and says, "Katie, come back in when you're ready."

Katie stands up straight, and you see in your peripheral vision how her back tenses up.

Then they're both gone, the door clicking shut, leaving you alone inside.

*page_break
The minutes pass in silence. It feels like the wrong moment to check your phone, so you sit there, staring at the door.

Someone shoves the door handle down and the door bangs open. It's Katie, crossing the room fast, stopping right in front of you as you scramble to your feet.

*if katie_masking > 50
    "${first_name}, great news! They think it's good enough to go forward to thesis defence! They said it's much better, and I presented it professionally and was well prepared. You really helped me out!"
*else
    "${first_name}! We did it! They accepted it! It will go forward to thesis defence in a month! They said, they said it was much better, that I really thought about their concerns and I had done the prep for all their questions and my research is really promising, and, and..."

*if katie_romance >= 2
    She leans towards you — more like she's falling — and embraces you. The hug feels rigid, mechanical, like her body is still confronting the committee.

    "You've been with me all this time, ${first_name}, and I don't know how to tell you how much it means to me. You're the only person I trust with... this, with everything. It means everything to me. ${first_name}, I... I —"

    She sags. "A bit dizzy... I need to sit down..."

    Katie sits down, head in her hands, staring at the floor. You rub her back gently.

    It's a few minutes later that she sits up. "Sorry! Sorry. Adrenaline crash. That took a lot out of me."

    She pulls off her hair tie, letting her hair fall loose. She turns to you.

    "Thank you, ${first_name}."

    *choice
        #Tell her that she means a lot to you.
            "Katie. You mean a lot to me." You say it quietly.

            This time, she doesn't break eye contact. She holds it, long enough for you to notice that she's not blinking.

            Then Katie takes your wrist, lifts your hand to her cheek. You feel the sharp angle of her cheekbone. She releases her grip, and you let your hand drop. 

            She darts in and kisses you. You can feel her lips press firm against yours — firmer than she meant to, probably, with too much forward momentum. She pulls back, fast, before you can respond. Faster than you wanted her to.

            "Oh, oops, I had some lip balm on. Hope that's okay."

            She stands, letting out a giggle that turns into a cough. Gathers her things.
            
            "Want to get some food?"

            The two of you leave. Once you're safely past the review room, she slides her hand into yours.
            *set katie_romance +2
        #Tell her that she did the hard part, you were just helping.
            "You did the hard part, Katie. I was just helping."

            Katie shakes her head, but she's smiling.
            
            "I don't know about that. But thank you."

            She looks down at her hands, then brings them up and presses her palms against her eyes.

            Then she stands up, arches her back, and looks over to you.

            "Food. I need food. Coming?"

            The two of you leave, walking side-by-side down the empty corridor, the afternoon light peeking in from the high windows.
*else
    *if (katie_masking > 50)
        Katie sits down and looks at the floor. She exhales through her teeth, then looks up at you with a sudden laugh.

    *else
        Katie sits down, and her hands are shaking. She shuts her eyes hard. When she opens them again, her eyelashes are wet, but she looks at you and smiles, the corners of her eyes crinkling.

    *if (nerve_conduction_confident)
        "I had no idea how to answer Professor Leung. So I just said a bunch of stuff, I don't even remember exactly what, said I already thought of his objection and had it handled. I think it worked, too."
    *else
        "I had no idea how to answer Professor Leung. I just said he made a good point and it was worth studying. Total cop-out, but it worked..."

    She pulls off her hair tie, letting her hair fall loose. She turns to you.

    "Thank you, ${first_name}. Thanks for being my demonstration subject."

    *choice
        #Sit there silently, letting her unwind at her pace.
            You just sit there, facing her, hands resting on your knees. Katie puts her head in her hands. She mumbles at the floor.
            
            "The presentation part went well... I practised that a lot... but there's no way to practise for the questions..."

            Her voice dies out. She raises her head and looks at you, and laughs. "I must look like, I don't know. Like I've just been in a fight."

            You nod and look away, and say nothing.

            "I'm happy that I managed this. But mostly, I'm happy that it's over for now." Katie rises from her seat and starts to pack up her equipment.
            
            "Food. Coming?"

            Food sounds good. The two of you leave, walking side-by-side down the empty corridor, the afternoon light peeking in from the high windows.
            *set katie_masking -2
        #Tell her that she did the hard part, you were just helping.
            "You did the hard part, Katie. I was just helping."

            Katie shakes her head, but she's smiling.
            
            "I don't know about that. But thank you."

            She looks down at her hands, then brings them up and presses her palms against her eyes.

            Then she stands up, arches her back, and looks over to you.

            "Food. I need food. Coming?"

            The two of you leave, walking side-by-side down the empty corridor, the afternoon light peeking in from the high windows.

*set katie_friendship +2
*return

*label event_6
*temp temperature_adj ""
*if current_season = "summer"
    *set temperature_adj "hot"
*elseif current_season = "winter"
    *set temperature_adj "cool"
*else
    *set temperature_adj "warm"
You're at the HKU canteen again. Laminate flooring, plastic plants. Chopsticks clatter on plastic trays as the afternoon sun drenches your booth. A few other students are around, sitting in ones and twos at their tables. The lunch rush has subsided, the tabletops littered with half-finished trays.

Katie said she'd meet you here right after her thesis defence. And there she is. 
*if katie_masking > 50
    A neat ponytail, a crisp white blouse, dark slacks, pumps. She stands tall at the canteen entrance. Her eyes find you across the canteen, and she strides towards you, arms stiff at her sides. But she can't suppress a grin.

    *if katie_romance >= 3
        As you stand up, she wraps her arms around you and squeezes tight, tight enough that a bit of breath leaves you. After a moment, she lets go.
    *else
        As you stand up, she pulls you into a hug, then lets go.
    "${first_name}! It's a pass! Pass with minor revisions!"

    You ask what that means for her.

    "That means they've accepted my thesis! I did it! No... [i]we[/i] did it!"
*else
    She's let her ponytail down, and she's wearing a crisp white blouse, dark slacks, and pumps. As soon as she spots you, she bounds forward, almost breaking into a half-run. She can't wipe the grin off her face.

    *if katie_romance >= 3
        As you stand up, she wraps her arms around you and squeezes tight. She pulls you close, so close that her cheek rests against yours. It's warm. She holds the hug. Then, just as you're wondering if she will stay like this forever, she releases her arms.
    *else
        As you stand up, she pulls you into a hug, holding it for a long while before letting go.
    "${first_name}! It's a pass! Pass with major revisions!"

    You ask what "major revisions" means.

    "That means they liked my ideas, but they want me to fix a lot of things. But still, my thesis defence was successful! I did it. No... [i]we[/i] did it!"

*choice
    #Congratulate Katie and share in her joy.
        *gosub_scene utils increase_empathy
        "Congrats, Katie! All this time... what an accomplishment!"

    #Consider what "we did it" means.
        *gosub_scene utils increase_analysis
        "We did it." Does that mean she considers you a collaborator, not just a demonstration subject? Or even more?

    #Congratulate her and give her room to celebrate.
        *gosub_scene utils increase_composure
        "Well done, Katie." No more words are needed.

You slide into the booth. Katie sits down and starts talking.

"It was intense. Two hours in there, five people facing me, all serious-looking. But something funny happened in the discussion part. Professor Leung got into a debate with the examiner who flew in from NUS for this. They couldn't agree on whether the effect was central or peripheral. I was just sitting there watching them argue for five minutes. I wanted to laugh —"

She stops mid-sentence. You wait for the apology, the excuse.

But then she just looks at you. Her hands rest on the table, palms open.

*if katie_masking > 50
    "${first_name}, you taught me how to deal with the university. I would never have figured this out by myself."
*else
    "${first_name}, you taught me how to deal with the politics. I didn't do everything you suggested. But I survived it."

*if highest_trait = "analysis"
    You see how Katie is discovering her own way to navigate these trials.
*elseif highest_trait = "composure"
    You recognise that it's better to say nothing for now.
*elseif highest_trait = "empathy"
    You see the rise and fall of Katie's chest, the adrenaline still coursing through.
*else
    *bug Invalid highest_trait
Her gaze wanders around the canteen, and she hums a simple tune. Then: "What do you want to eat? My treat!"

*fake_choice
    #Baked tomato pork chop rice, hot milk tea with evaporated milk.
    #"Seafood" ramen in pork bone soup, iced lemon coffee.
    #Steamed [i]choi sum[/i] with plain rice, iced lemon tea with less sugar.

*if katie_masking > 50
    Katie heads to the cashier, and after a short while she comes back with a paper slip.
*else
    Katie bounces over to the cashier, and after a short while she comes back with a paper slip.
You sit there, facing each other. Katie is the first to break the silence.

"So, ${first_name}... what have you been doing? Doing work? Uh, I mean, are you still fighting?"

*choice
    #Tell her about your training.
        *set katie_friendship +1
        You tell her how you still show up to MK Fight after work. Punching the heavy bag, footwork drills with Coach Lam, sparring with whoever's around.
        *if (eric_plot_timer > 1000)
            You still visit Eastside, sometimes, train there.
        *elseif (eric_subplot_status = "available")
            You still visit Eastside, sometimes, train with Eric.
        *if (chloe_subplot_status = "available")
            You've been training with others too, in different places. Harder training, the kind that leaves bruises.
        
        And it still feels good. Feels right. You don't know whether it's wise, but it's something you have to do.

    #Tell her about the office.
        You tell her that you're working hard at the office. No, of course not, you've been hardly working. She groans, but she's smiling.

        You tell her that sometimes it feels like it's all pointless, compared to her work. That you could never go all-in like she does. You admire that.

        Katie looks down at the table and clasps her hands together, a frown flashing across her face.

    *selectable_if (katie_romance >= 2) #Tell her you've been thinking about her.
        *set katie_romance +1
        *set katie_friendship +1
        "I've mostly been thinking, Katie. Thinking about you."
        
        Her cheeks flush, and she bites her lip, but she makes no move to escape.
        
        You go on. "I think about you a lot. It feels nice to do that."

        When she replies, it's a whisper. "I think about you too, ${first_name}."

An electronic chime, and the number flashes for your order. Katie stands up, and you follow, and you both get your trays from the canteen counter. You sit down and are about to eat when you feel Katie looking at you. Her hand drifts to her water tumbler and grips it tight.

"How about a toast?"

*choice
    #A toast. To the future. [i](Stay friends.)[/i]
        "A toast. To the future."

        Katie smiles and raises her tumbler. You bump your glass against hers, plastic striking plastic, a splash of water spilling over the top.

        "I'm going to see where this leads. My research can help people deal with pain. Maybe in a few years, after all the paperwork and postdoc applications..."

        "I think I'll keep fighting. I haven't thought that far ahead."

    *selectable_if (katie_romance >= 3) #A toast. To us. [i](Be her partner.)[/i]
        *set katie_friendship +1
        *set katie_romance +1
        *set katie_partner true
        "A toast. To us."

        Katie scoots forward. "To us? You mean... together?"

        "Yes, Katie. To us. Together."

        She shoots her hands up, palms out. "Yes! To us!"

        She thrusts her tumbler towards you. You bump your glass against hers, plastic striking plastic, a splash of water spilling over the top.

        She can't stop grinning. "To us! Wherever it leads!" 

*page_break
Katie's high spirits can't overpower the food. She grimaces as she takes a bite of her steamed pork patty over rice. The mushroom-pork miasma wafts over, musty and choking. You barely touch your food, trusting that ordering it is enough.

The drink is fine, though. Hard to mess up a drink.

*if katie_partner
    Katie peeks at her phone, which she's tugged halfway out of her trouser pocket. She clears her throat, and says, "${first_name}, I'm free tonight. Would you like to come over and —" She blinks hard. "Netflix and chill?"

    She braves your gaze. "Only if you want, though..."

    *choice
        #Go with Katie. [i](Sex scene.)[/i]
            You push your plate aside and stand up. So does Katie. She moves in close, takes your hand, and leads you out of the canteen.

        #Decline her offer.
            "Maybe not today, Katie."

            "Oh... well... we could still hang out elsewhere?"
            *goto katie_friendship_scene
    
    *page_break
    Katie's dormitory: a glass-fronted entrance, reception desk, card-access doors. The only sound is the ticking of the wall clock. Katie leads you past the reception into the lift, where you watch the floor number climb. You don't speak, and neither does she.

    The lift doors open onto a beige corridor, number plates on the doors, tiled flooring. Katie fumbles with the main door, works it open, and pulls you inside. It's still the same wooden table, cleared this time, the plastic chairs, and the tiny kitchenette, its tap dripping onto the metal sink, [i]dup, dup, dup[/i].

    A door clicks open, and her roommate emerges. She takes one look at both of you, her eyes widening.

    "Hey Katie, I just remembered I have to go... and... pick up my cat. I'll be out for a while."

    She slips past you and out through the door.

    Katie pauses. "Anyway, let's go to my room, it's more comfortable there."

    *page_break
    Katie keeps bouncing on her toes as you approach her room. Without waiting, she darts into her bedroom, and you follow. The room door swings shut, and you no longer hear the water droplets.

    On reflex, you sweep your eyes over the small space: a neat bed with creased sheets, a tiny desk with wooden dowels and plastic squeeze balls. Silence. Katie leads you to her bed and you sit down side-by-side, shoulders touching.

    She turns to you and goes still. You wait. She reaches out and strokes your back with one hand, whispers your name. Katie's eyes close as she leans in, and her warmth reaches you. A faint perfume, the remnants of the morning's defence.

    She closes the distance and touches her lips to yours.

    Your eyes shut and your lips open. A blur of sound, of skin, and Katie presses closer to you, her arms wrapping around, palms bringing you close. Your breath catches and your shoulders lock, for a moment, then you ease into her embrace. Your hands slip beneath her blouse, push it off, as Katie grips the back of your head and pulls you closer. With a final press she breaks off the kiss, and just watches you.

    She grabs your shirt with both hands and pulls it off. You unclasp her bra. Katie pushes you onto the bed, straddles you, palms planted on either side of your head. Your body wants to lift up, to meet her. Then her arms wobble, and a laugh bubbles out as she collapses onto you.

    "${first_name}. You feel so good."

    You get your arms around her back, and she keeps talking into your shoulder. You work at her waistband, but don't get anywhere. She helps. Your trousers come off with one pull. She rises over you again, her hair falling across your face.

    *page_break
    The digital alarm reads 9:45pm. You're back in Katie's room after a quick canteen dinner, lying on the mattress, your muscles heavy, finally. Silence, again, just the rhythm of Katie's breaths, her head on the pillow, turned to you, one arm draped across your chest.
    *if highest_trait = "analysis"
        You glance over at her desk, still covered with wooden dowels, squeeze balls, rods.
    *elseif highest_trait = "composure"
        You notice your breathing, how her arm rises and falls with your chest.
    *elseif highest_trait = "empathy"
        She smells like peppermint shampoo, the morning perfume gone.
    *else
        *bug Invalid highest_trait

    She mumbles something to herself, then laughs. She stretches out, arms over her head. She pushes herself upright, sitting against the headboard.

    "Time to turn in, ${first_name}? I have a spare toothbrush set somewhere around here, grabbed it from a hotel a while ago."

    *page_break
    Inside the windowless room, you're oblivious to the rising sun. The bedroom door is ajar, and again comes the drip from the kitchenette, [i]dup, dup, dup[/i].
    *if highest_trait = "analysis"
        Katie's desk is still piled with the dowels and balls, untouched.
    *elseif highest_trait = "composure"
        Katie's still asleep. Her chest rises, and falls.
    *elseif highest_trait = "empathy"
        A trace of peppermint from Katie's hair, loose across your shoulder.
    *else
        *bug Invalid highest_trait

    A while later, Katie blinks awake. She reaches over, rests a hand on your shoulder.

    "Hey ${first_name}, time to get up. Circadian rhythm."

    She sits up, yawns, and walks over to the bathroom to brush her teeth. You join her, squeezing the last bit of toothpaste from the fun-size tube. You smile, teeth foaming, and she bursts into laughter, spitting flecks of toothpaste onto the wall mirror.

    You hold her hand and walk out, take the lift down, out the lobby, into the ${temperature_adj} morning air. Hand in hand, you stroll along Bonham Road to HKU station, then at the escalators you stand in a single column on the right. They keep going down, and down, and down. 

    Finally you're deposited at the fare gates. A peck on the lips, but you pull her in for a hug, and neither of you lets go. A passenger bumps your shoulder and apologises, and the hug breaks. You descend to the platform without looking back.
    *goto katie_end_of_scene

As she slides the half-eaten food away, Katie says, "I finally have some free time now. We have to hang out! Like, right now!"

*label katie_friendship_scene
*set katie_donki true
You nod and push your food aside as well. Katie trundles off to return her plate, and then asks, "How about walking around Causeway Bay? I know something fun to do there!"

You can't wait to see what Katie considers fun, so with that decided, you head out of the canteen together.

*page_break
You stroll along Bonham Road to HKU station, then at the escalators you stand in a single column on the right. They keep going down and down, until you finally arrive at the fare gates. Down to the Island line platform, where a train is pulling in just as you arrive, and then six slow stops in an uncrowded carriage to Causeway Bay.

As you get out at the Paterson Street exit, Katie announces, "We're going to Don Don Donki! It's a Japanese shopping place but they make it totally overwhelming and disorienting. You'll love it."

You're not sure whether you'll love it, but she seems certain. So you cross the short distance to the tower block where the "DON DON DONKI — JAPAN DISCOUNT KING" billboard confronts you, and slip behind it into the small arcade at the side.

Even at the entrance, the colours assault your eyes, stupid-looking cartoon penguins herding you inside, yellow-and-black arrows pointing the same way, queue ropes squeezing in. The hallway to the escalators is flanked on both sides by rows of capsule toy machines stacked three high, illuminated by the neon green and cyan of diamond-shaped crystals stabbing down from above.

The sign at the base of the escalator announces: all guests must proceed to the fourth floor and descend from there. With no other option, you take the single-file escalators up, Katie in front, past displays of pet food, premium Japanese rice, frozen snow crab, low-quality salad. It's been less than a minute and the background music is already looping, amphetamine tempo, driving bass, Cantopop vocals that never resolve. [i]Don Don Don, Donki...[/i]
 
Katie takes you by the arm as you reach the top of the escalators. "Isn't this great? It really gives your senses a workout!"

*fake_choice
    #"Just what I needed, a boxing match for my brain."
        "Just what I needed, a boxing match for my brain."

        "Huh?"

        Her eyebrows raise, but then she grins. "Yeah! You can't get this kind of circuit training every day!"

    #"Sure is, although I'm going to need a week to recover."
        "Sure is, although I'm going to need a week to recover."

        She grins, nods, "It's so intense, right? They really try to hit all five senses. Or even more than that!"

First up is the premium fruit section — precious gems in misted, refrigerated displays, a single white strawberry on its paper throne, then a cluster of Shine Muscat grapes, each grape enormous and glossy and fragrant, and also a Yubari King melon, only legible to the Japanese. You know people who would pay a hundred dollars for a single strawberry, but you're not sure they would visit here.

The path continues into the freezer aisle, cold mist blasting onto your face, with stacks of seafood, udon, gyoza. A whole frozen Hokkaido snow crab, eight enormous legs and a dotted round shell, a thousand dollars. Canadian [i]uni[/i] sashimi in segmented white plastic trays, blobs of molten yellow and orange, the flesh not yet slimy. Katie has her palms pressed to the freezer wall. She explains, "if you freeze your hands like this for a minute, everything feels super warm afterwards! It's not good for your hands though."

*fake_choice
    #Put your hands on the freezer too.
        You put your hands on the freezer wall too. It's cold, but not so cold that your hands stick to it. Katie sees you doing it and beams.

        "So what do you think? Do you like the feeling? Now try rubbing your palms together!"

        You do so. It feels wrong, like there's a block of ice between your hands, but not unpleasant.

    #Comment that she's doing the thing she just said was bad.
        "Then why are you doing that, if it's bad?"

        Katie tilts her head, eyebrows furrowed. "Oh? Well, you don't know it's bad if you never try!"

        You think that doesn't really make sense, but you don't press the issue.

Nothing here interests you, so you descend to the third floor, where an enormous penguin mascot announces "LIMITED EDITION DRIED CRUNCHY CRABS[i]!![/i]"

"Snacks! This is my favourite floor!"

Katie leaves you behind. She ricochets around the different food islands, darting to the novelty candies, then the seasonal chocolate promotional displays, then the anime-collaboration savoury snacks.

Your eyes are drawn to the Hong Kong collaboration potato chip promotional display.

*fake_choice
    #Get a 50-gram pack of the Ginger-Scallion White Cut Chicken Potato Chips.
    #Get a 50-gram pack of the Tsui Wah BBQ Pork Rice Potato Chips.

Katie gets a bag of Salt Vanilla Tohato caramel corn, and a box of wasabi Kit Kats. She sees your choice and claps. 

"Excellent choice, ${first_name}! They come out with all these crazy gimmicks and I can't help but try them all. So far none of them taste any good, but you never know, it could be the next one, right?"

That makes sense. You agree.

After finishing the loop, you descend to the second floor. It looks like it's mostly selling household goods and... luxury handbags? You come face to face with a product island hawking packs of melamine cleaning sponges. You don't need it — what would you clean? But you already have the packet of chips in your hands, might as well buy the sponges. It's on sale, anyway.

*if katie_masking > 50
    "Are you liking it so far? Some people get overwhelmed."
*else
    "I actually don't know if you'd like this. I like it myself, so that's why I brought you here. Sorry if you don't like it."

*choice
    #Tell her you like it.
        *set katie_masking +1
        "It's okay, Katie, I like it. Different from what I'm used to, but in a good way. And I get to spend time with you."

    #Admit that it's overwhelming.
        *set katie_masking -1
        "It's a bit much, but that's fine. Discomfort is fine. It's just nice to spend some time with you."

"Oh." She brushes the side of her hair, then says, "That's nice, ${first_name}. I like spending time with you, too."

The moment passes. You take the escalator a final time to the ground floor, neither of you saying anything. A stroll through beauty products, skin creams, sunscreens, before it cuts into the checkout area. There are two queues here, the direct one and the long, winding one. Katie goes for the scenic route.

"It passes by this amazing ice cream!"

Interesting. There's a crème brûlée ice cream tub, single-serve, claims to have a genuine torched crust. You get that one, go through the queue maze, and pay at the counter.

After that is the dining area, the last stretch before freedom. Boxed sushi and sashimi in low fridges, burnt yakitori, some kind of dessert pancake stall. The dining area is thin now, before the evening rush. You and Katie find some raised stools at a high bench, and open your ice cream tubs. Yours is just as advertised, but frozen so solid that you can't actually break the crust with the included plastic spoon. Katie gets a wooden rod from her pocket and shatters it with a single strike.

"Be careful with the sugar shards, they can really cut your tongue if you're careless."

You still have to wait a few minutes for the ice cream to soften, and you wrap your palms around the tub, watching Katie eat hers. Nevertheless, it does taste pretty good when you finally get a spoonful into your mouth.

"Hey, so, uh, ${first_name}... thanks for joining me. I know it's a bit silly, but... I had fun today."

"Me too, Katie."

Ice cream finished, you get ready to leave. You don't open your bag of potato chips.

*page_break
It's not far to the MTR. You make plans to go somewhere next week, your turn to choose. Katie's heading back to her dorm.

You say goodbye, not for the last time.

A hug.

Then she's gone, her hair disappearing down the escalator.

*label katie_end_of_scene
*set katie_friendship +3
*return
