*label scene_introduction
*if eric_subplot_scene = 1
    After your fight with Eric, he invited you to train with him at Eastside Combat Club. You remember his disciplined footwork, his energy waves, the blazing uppercut. You've never seen anything like that at [i]MK[/i]. Something nags at you: it's unclear what you could offer him in return.
    *if (eric_almost_lapsed)

        You haven't taken up Eric's invitation yet. His invitation may not remain open forever.
*elseif eric_subplot_scene = 2
    Last time you trained with Eric, you saw his discipline. But he struggled to integrate his energy techniques with his karate. Eric's invited you to train again. You don't know why he finds it helpful to train with you, but he keeps asking you back.
    *if (eric_almost_lapsed)

        Eric hasn't seen you in a while. His time is valuable, and he might find other training partners if you don't reconnect soon.
*elseif eric_subplot_scene = 3
    *if eric_plot_timer = 0
        Eric's been training with you again, but there's been a noticeable change. He isn't working as much on his technique, and he's been taking longer breaks between drills. Instead, it seems like he's trying to figure something out. At the end of your last session, he said, "I want to show you something different." Whatever he means, it won't be a regular practice session at Eastside.
        *if (eric_almost_lapsed)

            Eric's been waiting to show you something different for a while, but he won't wait forever.
    *else
        Eric's last message: "Need some time alone. Hit an energy blockage." After the confrontation with Chloe, he seemed withdrawn. From the looks of it, he won't be reaching out for a training session this week.
*elseif eric_subplot_scene = 4
    *if eric_plot_timer = 0
        The Pearl River Cup is approaching. Eric's been training more frequently, but the rhythm is different. His form is tighter, and he's relentlessly repeating his drills. He messaged you again. "I've been thinking about why I fight." That was it. You don't know whether he wants to talk about it, fight through it, or just let it float, unresolved.
        *if (eric_almost_lapsed)

            This sounds important to Eric. If you don't reach out soon, he'll probably assume you're not interested.
    *else
        The Pearl River Cup is nearing, and Eric's messages have become terse. He's training privately, spending long hours at the Hong Kong Sports Institute. No offer to join him. If he's not ready to show you what he's doing, you'll just have to wait.
*elseif eric_subplot_scene = 5
    *if eric_plot_timer = 0
        The Pearl River Cup has concluded. Eric sent you a short message. A time and a place. Whatever this is about, Eric wants to see you.
        *if (eric_almost_lapsed)

            He's been waiting to tell you about it in person. If you want to catch up with him, now would be the time.
    *else
        Eric's fully absorbed in his final preparations for the Pearl River Cup. You haven't seen him for a while. You'll have to wait until the tournament is over if you want to catch up with him.
*elseif eric_subplot_scene = 6
    *if eric_plot_timer = 0
        Eric's latest message wasn't a text, but a voice message. He says he's been helping out at Master Cheng's new training centre. "I've found it," he says, quiet and deliberate. "I want to show you."
        *if (eric_almost_lapsed)

            If you want to know what Eric found, you'd best make time for him.
    *else
        Eric bombarded you with a jumble of messages and voice memos about cultivation, harmony, intention, performance. Then nothing for days. Master Cheng's training centre must be keeping his thoughts occupied. Whatever's going on there, it's consuming all of his focus.
*elseif eric_subplot_scene = 7
    *if eric_partner
        Eric's helping Master Cheng while continuing to improve his own craft. You've settled into a comfortable rhythm with him: training with him at Eastside, walks in the hills, sometimes just hanging out at your place or his.
    *else
        Eric's helping Master Cheng while continuing to improve his own craft. You've settled into a comfortable rhythm with him: training with him at Eastside, walks in the hills, sometimes just hanging out at the Tai Po centre.
*else
    *bug Eric subplot scene not found
*return

*label scene_choice
*if eric_subplot_scene = 1
    *comment earliest: chapter 2, first fortnight
    *comment eric_friendship from this chapter: 1-4 for accept, 0-3 for reject
    *comment cumulative eric_friendship after this chapter: 1-4
    *gosub event_1
    *set stat_technique %+2
*elseif eric_subplot_scene = 2
    *comment earliest: chapter 2, second fortnight
    *comment eric_friendship from this chapter: 0-2
    *comment cumulative eric_friendship after this chapter: 1-6
    *gosub event_2
    *set boxing_insights_unspent +1
    *set eric_plot_timer 2
*elseif eric_subplot_scene = 3
    *comment earliest: chapter 3, second fortnight
    *comment eric_friendship from this chapter: 2-4
    *comment cumulative eric_friendship after this chapter: 3-10
    *gosub event_3
    *set stat_technique %+4
    *set unlocked_eric_training true
    *set eric_plot_timer 2
*elseif eric_subplot_scene = 4
    *comment earliest: chapter 4, second fortnight
    *comment eric_friendship from this chapter: -1 to 2
    *comment cumulative eric_friendship after this chapter: 2-12
    *comment eric_romance from this chapter: 0-2
    *comment cumulative eric_romance after this chapter: 0-2
    *gosub event_4
    *set boxing_insights_unspent +1
    *set eric_plot_timer 3
*elseif eric_subplot_scene = 5
    *comment earliest: chapter 6, first fortnight
    *comment eric_friendship from afterhours: 0-4
    *comment eric_friendship from this chapter: 3
    *comment cumulative eric_friendship after this chapter: 3 + afterhours = 5-19
    *comment eric_romance from afterhours: 0-2
    *comment eric_romance from this chapter: -2 to 3
    *comment cumulative eric_romance after this chapter: -2 to 5 + afterhours = -2 to 7
    *gosub event_5
    *set stat_toughness %+5
    *set stat_power %+4
    *set eric_plot_timer 3
*elseif eric_subplot_scene = 6
    *comment earliest: chapter 7, second fortnight
    *comment eric_friendship from afterhours: 0-4
    *comment eric_friendship from this chapter: 3
    *comment cumulative eric_friendship after this chapter: 3 + afterhours = 8-22
    *comment eric_romance from afterhours: 0-2
    *comment eric_romance from this chapter: 0
    *comment cumulative eric_romance after this chapter: -2 to 5 + afterhours = -2 to 7
    *gosub event_6
    *set stat_toughness %+4
    *set stat_power %+4
    *set stat_technique %+4
    *set stat_mental %+4
    *set eric_plot_timer 10000
*else
    *bug Eric subplot scene not found
*return

*label event_1
Quarry Bay: a business district defined by its efficiency, where office towers, metal and charmless, press against ageing apartment blocks. A bakery vents fragrant steam into the street. You pass a construction site, silent, wrapped in green netting, a pigeon lounging on a bamboo pole. Then you arrive at the building Eric directed you to.

A facade of grey concrete, a brushed steel door, no signage — it could easily house a cram school or a property management company. You punch the code into the numeric keypad. It lights up green and emits a cheerful, annoying electronic melody. A narrow stairwell of raw concrete leads downwards, and with each step the air becomes cooler. The doors of the gym are open, and you already hear the rhythmic breathing, the squeak of shoes pivoting, the [i]crack[/i] of a solid strike on a training bag.

You spot Eric before he notices you. His red gi stands out amongst the plain white karate gis, boxing shorts, and Muay Thai pants in Eastside Combat Club. As you step through the doorway, the muffled sound of training sharpens. The sweat and old leather smell the same as in [i]MK[/i], but infused with the cool bite of air-conditioning. Fighters glide across clean blue mats, rows of overhead fluorescents flooding the space with white light. A few glance at your outfit before returning to their training.

Eric's coaching a young fighter at the open mat area. "Elbow higher," he says, as he adjusts the student's arm with a light touch. "Now rotate from your centre." The student twists from her core, forearm sweeping across in a flowing parry. Eric nods in approval.

You recall Eric's confidence, his explosive energy, the relentless aggression during your fight. Now he's studying people's stances and adjusting their form.

He looks up and spots you near the entrance, the corner of his mouth lifting into a smile. He bends to say something to his student and then approaches you.

"${first_name} ${last_name}," he says. "Didn't think you'd actually show up."

*choice
    #"I thought it was worth checking out."
        "I thought it was worth checking out," you reply. You nod at the expensive equipment. "This place is professional."
    #"Your fighting style was unique."
        *gosub_scene utils increase_analysis
        *set eric_friendship +1
        "Your fighting style was unique," you reply, watching the students around you. "Spectacular, but also effective. I want to learn more about that."
    #"I wanted to see how different people train."
        *gosub_scene utils increase_empathy
        *set eric_friendship +2
        "I wanted to see how different people train," you reply. "My gym is great, but it's... duct-taped training bags and coaches yelling."

"Been training here for a year," Eric says, his gaze sweeping across the room. "The facilities are good, but more importantly, they let me train my specialised techniques."

He leads you towards the mats. "Come on."

You work with Eric on some boxing drills. He focuses intently on your form as you go through basic combinations.

"Your guard is dropping." He taps your chin lightly with his focus mitt. You reset your guard and land a one-two, drawing a soft grunt of approval.

"Don't telegraph. Less wind-up. Faster, like a whip."

Six more reps. "Your shoulder drops when you go for the cross. Keep it level and snap from your guard."

A flicker of flame leaks from his wrist. "Shoulder. Still dropping."

He adjusts his mitts, then pauses. You're breathing hard.

"You know, I used to think power solved everything," he says, half-smiling.

He watches your guard reset. "It's good seeing you work on the basics. Reminds me how much the fundamentals matter. I forget that, sometimes."

He claps the focus mitts together. "Again."

*page_break
*if (fight_opponent_name = "Katie")
    "Your fundamentals are decent for having only trained a few months," he says during a water break, handing you a clean white towel. "But your guard still drops when you throw anything beyond a jab. Anyone with experience will punish that immediately. Who are you fighting next?"

    "Katie Reynolds. Ring name 'Pressure Point'. Haven't been able to find out much about her."

    "Ugh. Reynolds? She's... it's not even like a normal fight. More like she's conducting experiments that involve a lot of screaming. You're going to have a bad time if you go into the fight like this."

*else
    "Your fundamentals are decent for having only trained a few months," he says during a water break, handing you a clean white towel. "But your guard still drops when you throw anything beyond a jab. Anyone with experience will punish that immediately."

Eric notices your concern. "We'll work on your form. That's the best way to prepare right now," he says, gesturing towards the mat again. Another half hour of pad work. Your shirt is soaked, and you're grateful for the air-conditioning they have here.

Sitting down again, you wipe the sweat from your forehead and think back to the fight with Eric. "You found the weaknesses in my defence pretty quickly in our match."

A small nod. "Yeah. I kept dropping my left hand too when I was starting out. My coach would whack me with a mitt every time it happened." He mimes bringing his guard up, and smiles.

Then, his gaze wanders over the room, taking in the groups of fighters working on grappling, striking, kickboxing, karate. A comfortable silence settles between you on the bench.

"Can I ask you something?" he says, his voice lower. "What made you step into the ring?"

You notice he's looking directly at you. The gym noise fades.

*choice
    #"I'm looking for a new challenge."
        *set eric_friendship +1
        *set fight_reason "I'm fighting to challenge myself."
        You explain how you feel stuck in your office job. Fighting provides a real challenge, with real consequences.
    #"I want to test my limits."
        *set fight_reason "I'm fighting to discover where my limits are."
        "I want to know what I'm capable of," you explain. Some questions can only be answered in the ring.
    #"I just want to improve my boxing."
        *set eric_friendship +1
        *set fight_reason "I just want to improve my boxing."
        "I just want to improve my boxing," you explain. "Then one thing led to another."

Eric nods thoughtfully, studying your face. "I see something in you. It reminds me of when I started." He flexes his fingers, and the veins pulse on the back of his hand. "You have potential. But more than that, you have spirit."

He pauses. "I like to train newcomers, give something back." He looks down at his sleeve, smooths out a crease in the red cotton fabric. "I've been working on my own techniques as well. I want to balance my energy techniques with my karate."

He flexes his hand, clenching and relaxing it. "Most people want to see me perform party tricks. A few others don't want me to use my power at all."

Eric stares at his hands. A fighter calls Eric from across the gym, pointing at the speed bags, and Eric rises, exhaling softly. 

"I have to go, but I'd like to continue this. If you're interested, I train here Tuesday and Thursday evenings. You're welcome to join. I think we could learn from each other."

"Learn from me?" The words escape your mouth before you can stop them. "I'm barely keeping up."

Eric just extends his hand.

"Training partners?"

*choice
    #"Training partners."
        *set eric_friendship +1
        "Training partners."
        
        His handshake is firm and warm. "Good. Thursday, six o'clock. Be ready to work hard."

        He takes a step towards the fighter who called his name, then turns around, glancing at your hands.
        
        "Bring proper hand wraps next time. Your form is actually pretty good overall, but you don't want an injury there."

        Eric's already back to work. He kneels beside his student, tapping her heel gently with his fingers. You sling your bag over your shoulder and take one more breath of the cool air.

    #Decline his offer.
        Are you sure you want to decline his offer?
        *choice
            #Yes.
                *set eric_subplot_status "rejected"
                "I think I'll pass. It was a good session, but I'm not sure this is the path for me."

                Eric nods. "All right. It's not for everyone. I'm sure I'll see you around."

                He shakes your hand firmly, then turns and walks away, kneeling beside the student who called him over. He taps her heel gently with his fingers. You watch him, but he doesn't look back.
            #No. [i](Accept his offer.)[/i]
                *set eric_friendship +1
                "Training partners."
                
                His handshake is firm and warm. "Good. Thursday, six o'clock. Be ready to work hard."

                He takes a step towards the fighter who called his name, then turns around, glancing at your hands.
                
                "Bring proper hand wraps next time. Your form is actually pretty good overall, but you don't want an injury there."

                Eric's already back to work. He kneels beside his student, tapping her heel gently with his fingers. You sling your bag over your shoulder and take one more breath of the cool air.

*return

*label event_2
Weight machines clank, timers buzz, fighters shout [i]kiai[/i]s. You ram another cross into the heavy bag, savouring the shudder as it connects. You review your stance, feeling for a connection with the floor, as you assume the position Eric's drilling.

"Pivot more," Eric calls to you. He then demonstrates on the bag next to you: feet planted, a seamless rotation from his centre, thighs, core, shoulder, arm moving as a single whip, power driving through his fist. The heavy bag shudders. "Power comes from the ground up, not just from your arm."

You adjust your stance, narrowing your feet for better hip rotation, and throw another cross. The bag swings a bit further this time, sending another jolt up your arm all the way to your shoulder.

"Better," Eric says, allowing a brief smile. "Now try the jab. Remember, speed without proper form is wasted energy, ${first_name}."

You pace the jabs, each snap sending a brief jolt through the bag. Then, on Eric's call, you drill the one-two, the heavy bag swinging with the impacts.

"Most fighters dream about the sizzle. They forget the part where you actually learn to cook. The [i]mise en place[/i] of combat."

You pause. Just as you're about to respond, the front door swings open with a force that silences the gym. Conversations stop as every head turns towards the entrance.

*page_break
"Well, well! Fancy finding actual [i]fighters[/i] in this dump!"

A young woman strides through the entrance, shoulders relaxed, advancing with quick, deliberate steps. Her jet-black hair is cropped in a precise bob, her eyes flicking from the heavy bags to the fighters to the mirrors. A sleeveless shirt with a small logo. Bare arms tight with lean muscle. A phone held loose in one hand, the other clutching a bundle of shopping bags.

She sees Eric, and a smile snaps into place. Her white sneakers squeak on the mat as she makes a beeline for him, a fighter stumbling out of her way as she steps right through his space. She doesn't flinch, doesn't slow down, doesn't acknowledge him, never breaks rhythm.

"[i]Blazefist[/i] himself! Just the man I was hoping to see."

Eric's jaw twitches, and a small vein at his neck pulses. "Chloe," he says, each syllable slow and flat.

*choice
    #Stay out of it for now, but observe the situation. 
        *gosub_scene utils increase_composure
        Chloe says Eric's name with just a bit too much space around it. Her footsteps stop a metre from Eric with a final squeak.

        You look from Chloe to Eric. His jaw's tight, but his hands remain loose and open at his sides. This isn't your fight. Not yet.

    #Study her. There's something off about the way she carries herself.
        *set eric_friendship +1
        *gosub_scene utils increase_analysis
        Her strides were long, but the movement didn't ripple through her hips. The shopping bags in her hand: embossed logos, thin tissue peeking out from the top. The heavy arc of their swing would make most people shift their weight, but she doesn't compensate. 

        She stops her advance a metre from Eric, then stands still. A smile that looks like a glare.

    #Let her see you watching. She's abrasive, but rather fascinating.
        *set chloe_friendship +1
        *gosub_scene utils increase_empathy
        You watch as she stops her approach in front of Eric, slightly inside his personal space. The shopping bags swing like a pendulum, but her arm stays steady.

        She gives Eric a smile that's all teeth. Her posture doesn't change. Eric's weight shifts backwards.

        Her eyes flick briefly to you, noticing your attention. You don't say anything, but you don't look away, either. The slightest eyebrow raise, then back to Eric.

"Just finished some retail therapy," she casually says, lifting her shopping bags above her head, forcing everyone's eyes upwards. "Thought I'd stop by and see what all the fuss is about." Her gaze shifts to you, a quick smirk dismissing your tattered gloves.

"Eric always did have a soft spot for... underdogs," she remarks, in a stage whisper that carries to the whole room.

You inhale slowly, raise your eyebrows, but say nothing.

She's close enough that her amber perfume cuts sharply through the gym's usual sweat and leather. "Still working on that jab, cross, hook, Eric?" She mimics the combination with wobbly hands, but her shopping bags keep pace perfectly.

"Where's the fire? Where's the stuff that actually makes you worth watching?"

"We're working on fundamentals," Eric replies, his tone flat. "Foundation work."

Chloe rolls her eyes and sighs with her whole body. You almost hear an "ugh" come out with it. "Boring! You know what people pay to see." She flicks her fingers at Eric's fists with a small laugh. "The flames. The crackle. The stuff that makes you [i]special[/i]. Pearl River Cup is coming up, Eric. Nobody's packing the stands to watch basic combos."

"How I train is none of your business, Chloe." He's speaking slower now, every word controlled.

"Just looking out for a fellow fighter," she smiles. "Playing it safe, basic fundamentals" — she looks directly at you — "might be fine for beginners with nothing special."

Her attention returns to Eric. "You, though? You're wasting your potential."

Heads turn towards Eric. It feels like everyone's holding their breath.

You catch a whiff of ozone. A brief crackle, then a spark flickers on the knuckles of Eric's right hand before vanishing. He glances at his hand, stares at Chloe, and then takes a long, slow breath.

*choice
    #Watch Eric's hands, how he struggles to keep his temper.
        *gosub_scene utils increase_empathy
    #Feel indignation at Chloe's antagonistic attitude.
    #Look around at the other fighters, see how they don't want to get involved.
        *gosub_scene utils increase_analysis

"My energy techniques aren't party tricks," he says, his voice now firm. "They require discipline. Control. Otherwise, everyone gets hurt."

Chloe takes a step closer, less than an arm's length from him. "Discipline? Control? Sounds like something a coward would say. People are starting to wonder if you're stale bread, Blazefist. They're saying you don't have it any more."

Eric's chest expands. His stance drops slightly lower. He inhales deeply, and you recognise it as the same breath before the flaming uppercut in your fight.

The air seems to crackle between them. Then Eric's shoulders relax, although his gaze remains fixed on her.

"My training methods are my own business, Chloe," he says, his voice quiet. "I don't need to justify them to you or anyone else."

*choice
    #Stay silent. Let Eric handle this.
        *gosub_scene utils increase_composure
        Eric doesn't need backup. Not right now. You keep vigil nearby.
    #Try to anticipate Chloe's next move.
        *gosub_scene utils increase_analysis
        Chloe's words don't seem accidental. But you can't tell if she's improvising, or if it's calculated.
    #Watch Eric. Get a sense of why his reaction is so intense.
        *gosub_scene utils increase_empathy
        His voice sounds calm, and he dismisses Chloe's provocation, but his stance tells another story.

Chloe steps closer, her smile sharp. "Oh, but you [i]do[/i] need to, Eric, you do. The Pearl River Cup committee was specifically asking about you yesterday. Wondering if the 'Blazefist' they're promoting will live up to the hype this year. Wondering if they should feature someone more... enthusiastic about giving the audience what they want."

Eric tightens up with a sharp breath. "The committee knows what I can do."

"Of course they do. But they also know what sells tickets." Chloe glances at you, eyes narrowed, before continuing. "Your reputation won't help if you never show your signature moves."

Her voice softens. "Look, there's an exhibition match next week at Central Plaza. The big sponsors will all be there. Come and show them you've still got it. Or people will start saying you've lost your edge."

"I haven't lost anything."

"Prove it, then. Or don't. Keep on doing what you're doing while someone else steals your spot."

She flicks her shopping bags, bunching all of them cleanly onto one shoulder. "Unless you think you're too good for flashy techniques now. Master Cheng would love to hear that."

She smiles as if she'd just ticked something off her to-do list, turns her back to Eric, and glides towards the exit. 

The silence in the gym lifts, and conversations gradually resume. Eric hasn't moved. His expression is blank, but you see the stiffness in his neck, the tension in his jaw.

*choice
    #Wonder if she was actually trying to help him.
        *gosub_scene utils increase_empathy
        She wanted him off-balance, shaken. Then she hit him with her ultimatum. An insult, but also a challenge.

    #Analyse how she set up her proposal. This was planned from the start.
        *gosub_scene utils increase_analysis
        You see how much information she embedded into her proposal. The committee's concerns, the exhibition match, the sponsors. All of it dropped casually into the conversation.

    #Resist the temptation to get involved.
        *gosub_scene utils increase_composure
        Your first instinct is to say something. You let it pass. Take a breath, loosen your shoulders. This is Eric's battle to fight.

Eric exhales slowly and turns to you. "Sorry about that. Chloe... she loves to make things complicated."

"Yeah," you say. At the far end of the room, a timer beeps.

"Is Master Cheng your [i]sifu[/i]?"

Eric nods as he loosens his hand wraps. "Been training with him since I first discovered these abilities." A faint yellow glow briefly envelops his knuckles. "But he believes energy projection should be used to connect with nature, not for combat."

He looks down and shakes his head. "I understand where he's coming from. But that doesn't win championships."

"So what will you do about the exhibition match?"

He doesn't answer, his gaze drifting across the gym, where a few fighters stretch in silence. "Master Cheng says I rely too much on the energy techniques. That I'll burn myself out." He shakes his head, runs his palm absently over the knuckles of his other hand.

*page_break
As you finish towelling off, Eric approaches you again. He starts to speak, but then stops. One hand reaches for the wraps on the other hand, but they're no longer there.

"${first_name}, I've been working on something with Master Cheng," he finally says. "My energy techniques. Not about controlling them, but about intent."

He looks down at his hands. "He doesn't usually receive visitors." The only sound is the low hum of the air conditioning.

"I think it might help. If you wanted to see it. What I've been trying to learn."

*choice
    #"I'd like that."
        *set eric_friendship +1
        You consider his offer. It doesn't sound like a casual invitation.

        "I'd like that."

        Eric nods, but there's a momentary twitch at the corner of his eye, and he glances away.

    #"That sounds... intense. Can I think about it?"
        You consider his offer. It doesn't sound like a casual invitation.

        "That sounds... intense. Can I think about it?"

        "Of course." Eric nods, too quickly. "I'll text you the details anyway. Just in case."

You gather your things and head towards the exit. Eric waves, and sits on the bench, eyes closed, hands on his lap. A faint golden glow flares from his hands, occasionally flashing crimson, never quite settling.

[i]A Boxing Insight takes shape, sharp and half-formed.[/i]
*return

*label event_3
The red minibus rattles along the rural Yuen Long road, three-storey New Territories village houses giving way to corrugated metal warehouses, then to storage depots and bare concrete. Half-abandoned villages dot the countryside, overrun by wild vegetation. You're both in the second-last row, where the floor is raised. Eric stares out the smudged window, his body hunched on the seat. He opens his mouth, then closes it again. The minibus slows as the road gets bumpier.

"We're almost there," Eric says, as a small store and a few dilapidated houses come into view. "Master Cheng's a short hike from the nearest village. He doesn't get many visitors."

The minibus stops in front of a small village. You press a ten-dollar coin into the driver's palm and step off. The air is cool against your skin, smelling of earth, wet leaves, and moss. The few stone houses are old, with faded tile roofs, clustered around some paved paths. A few chickens wander casually around the open areas and peck at insects, their clucks drifting through the open doorways and rusted iron railings. You don't see anyone around, not even at the stone Chinese chess table.

Eric leads the way through the village, turning onto a dirt trail that climbs upwards through bamboo groves. Your footsteps crunch on dry leaves and loose gravel. The air is cooler here, in the shade, and you breathe in wild lemongrass and camphor.

Fifteen minutes later, the trail widens into a forest clearing, bordered on one side by a waist-high brick wall. A yellow hard hat rests against its base. At the centre of the clearing, behind a neat vegetable garden, stands a Hakka dwelling. Blue-grey brick walls, red clay roof tiles, small metal-barred windows, and a squat stone chimney.

"Here we are," Eric whispers. He pauses before the faded wooden door.

*choice
    #Drink in the stillness. No need to act right now.
        *gosub_scene utils increase_composure
        Eric hasn't knocked. He's standing in front of the door, arms relaxed at his sides. You match his stillness. The only sound is of the wind whistling through bamboo.

    #Sense Eric's careful tension. He looks like he's returning to a memory.
        *gosub_scene utils increase_empathy
        Eric's standing in front of the door, weight shifting from one leg to the other. His neck and shoulders stiffen, but it's not the anticipatory energy of competition.

    #Assess your surroundings. Remote location, and a methodical garden.
        *gosub_scene utils increase_analysis
        A single, winding path. The garden: orderly rows, evenly spaced. A caretaker's precision. A hard hat, near the drying cement of the brick wall.

The door swings open and a short elderly man emerges. He's wearing a plain brown shirt, trousers, and cloth shoes. He takes his time closing the distance. His eyes, sharp and piercing, settle on you briefly, before moving to Eric.

"Eric. You're here."

Eric bows low. "Master Cheng, this is ${first_name} ${last_name}, the training partner I mentioned." 

Master Cheng nods. The silence lingers as he studies Eric. After several more seconds, he turns back towards the house. "Come inside."

*page_break
The house smells of aged cedarwood and oolong tea. The main room occupies most of the interior. Wooden staves lean against one wall, beneath a calligraphy scroll: 以和為貴 — "regard harmony as precious." On the opposite wall, wooden racks hold red-tasselled sabres and swords. The middle contains a low wooden table with a clay teapot and three porcelain cups. Your feet move across the wooden floor, a small window spilling amber light across the floorboards.

Master Cheng extends a hand towards the table. He lifts the teapot and pours tea in an unbroken stream into the three cups, sliding one each to you and Eric. The tea, mahogany brown, smells earthy, so rich it's almost overpowering. You bring it to your lips, the steam warming your face, and take a sip. The tannins hit sharp and settle deep into your body.

Master Cheng studies you. "So you are Eric's new student," he says, turning towards Eric.

"Training partner," Eric says gently. "We've been training together for more than a month now."

Master Cheng clears his throat and lifts his teacup, taking a slow sip. His attention returns to you. You adjust your hips on the cushion, and notice how particles of dust dance in the air where the light streams in from the window.

He speaks quietly. "Eric says you fight without formal sanction. That carries danger, ${first_name} ${last_name}, and no reward. And he says you're not interested in fame and glory. So why do you fight?"

*choice
    #"To find something real, something different from my office job."
        *set fight_reason "I'm fighting to find something real."
        You explain your office life, reading through reports, clicking on spreadsheets, sitting through endless meetings. "Fighting felt different, right away. When I land a punch or take a hit, it's real. The bruises next day prove it."

    #"To discover where my limits are, and maybe push them."
        *set fight_reason "I'm fighting to discover where my limits are."
        "Every time I fight, I learn something new about myself," you tell Master Cheng. "What I do under pressure, how much I can endure. I see my flaws, fix them, and try to do the best I can."

    #"I'm still figuring that out. But I know this is something I need."
        *set fight_reason "I'm still figuring out why I fight."
        "I'm not sure why, myself," you admit to Master Cheng. "When I land a good punch, or when I'm totally exhausted and can't go further... all of that, it feels right. This all started as exercise, but it's more, now. I can't just go through the motions like before."

He leans forward as he listens to you. Then he nods slowly. "You do not lie to yourself. A promising beginning."

Turning to Eric, he continues, "How about you, Eric? Have you found the answers to your questions?"

"I'm refining my energy techniques, Master Cheng. Working on control and using them at the proper moments. It's challenging, but I'm making some progress."

"Hmm." Master Cheng sets down his tea cup. "Show me."

Eric rises and moves to the open space between the table and the entrance. He begins a flowing [i]kata[/i] that you haven't seen before, involving slow, whole-body movements. Instead of fire, a faint amber glow envelops his fists and feet.

Master Cheng watches, eyes focused on the energy flow. Eric finishes, returning to a standing ready stance, and bows. Master Cheng nods once, then touches two fingers to his chin, eyes narrowed.

"Better," he notes. "But you still see it as something you need to control."

Eric's forehead creases as he glances at Master Cheng. "I thought the point of our training was to control it."

Master Cheng starts to say something, but then he stands up and nods at the doorway. "Come, both of you."

He leads you outside to a small practice yard behind the house, a circle of packed dirt twenty paces across. In the middle, there's a line of six wooden poles, the shortest barely above your knee, the tallest rising above you, each one just wide enough for a single foot.

"Watch," he says.

*page_break
Arms behind his back, Master Cheng walks over to the shortest pole, and signals for you to stay a few paces away. He steps onto the short pole, balancing on one foot as if it were solid ground.

Then he brings one arm out from behind his back. The hand holds a palm-sized porcelain bowl, but it's too high for you to see what it holds. Master Cheng bends his knee, and hops to the next pole, landing on it with the same foot. He then climbs up the line of poles, hopping each time, without looking at his feet. He stays at the highest pole for a few seconds, his shoulders relaxed.

He looks from Eric to you, then to his bowl. He steps down the poles at a steady pace, landing in front of you as if returning from a walk.

Then you see the contents of the bowl. It's filled with tofu pudding, a golden film of ginger syrup and a small heap of yellow rock sugar on top, undisturbed. Master Cheng brings his other hand forward, holding a porcelain spoon. He scoops a mouthful of the tofu, and savours it with his eyes closed.

He opens his eyes and raises an eyebrow at Eric.

"Mmm. Tofu pudding."

Eric sighs, closing his eyes for a moment, then makes a sound that's almost a laugh. "Master Cheng... I know what you mean. I want that too."

"Yes, yes. But..."

"I haven't forgotten your teachings, Master." Eric straightens up, inhales deeply. "I compete to test myself. To measure my skills against others."

Master Cheng steadily lifts a spoonful of tofu to his mouth, his eyes fixed on Eric. Eric holds his gaze.

*choice
    #Focus on Eric's posture, and what it says about his state of mind.
        *gosub_scene utils increase_empathy
        You see how Eric's jaw is clenched, how his hand has curled into a loose fist. The quiet tension of a familiar argument.
    #Recall Eric's frustration at the gym when Chloe challenged him.
        *gosub_scene utils increase_analysis
        When Chloe questioned Eric's ability to impress the committee, his reaction was similar. Same tension in the jaw, same intense stare. But more restrained here. Everything staying within safe limits.
    #Focus on your own breathing. Don't get involved.
        *gosub_scene utils increase_composure
        You breathe deep. This isn't your place to intervene.

"Enough." Master Cheng turns to you. "Stand here."

You step forward.

"Attack Eric. Light contact only."

Master Cheng fills the next hour with the most basic of drills. Blocks, one-twos, footwork. He nudges your elbow down, and pushes your wrist to the left with his palm. His foot taps your knee back into alignment. Even your jab feels clumsy. He taps Eric's shoulder with two fingers as he reminds him, "Softer. You're trying to overpower the energy flow."

At the end of the hour you see Eric sweating, his arms occasionally shaking. Then Master Cheng turns to you.

"Close your eyes," he says. "Feel the air around you. Don't focus on your skin. Try to feel it from your centre. Sense the presence of others."

You shut your eyes and try to follow his directions.

*fake_choice
    #Try to sense Master Cheng's energy.
        At first, the only thing you can sense is your own heartbeat and your breath. Gradually, your senses heighten, and you notice the coolness of the air entering your lungs, the pressure of the ground beneath your feet, how your shirt clings to your skin.

        Your focus feels physical now, something to be moved around at will. You focus it on where you think Master Cheng is, attempting to detect any energy there. Nothing. Just darkness behind your closed eyes. You fight the urge to open them.

        "Mmm," you hear Master Cheng say softly, as if from far away. "A good start."

    #Try to sense Eric's energy.
        At first, the only thing you can sense is your own heartbeat and your breath. Gradually, your senses heighten, and you notice how your shirt clings to your skin, the coolness of the air entering your lungs, the pressure of the ground beneath your feet.

        Your focus feels physical now, something to be moved around at will. You focus it on where you think Eric is, attempting to detect any energy there. Nothing. Just darkness behind your closed eyes. You fight the urge to open them.

        "Mmm," Master Cheng says softly. "A good start."
    
    #Try to sense the threshold between your energy and the surroundings.
        At first, the only thing you can sense is your own heartbeat and your breath. Gradually, your senses heighten, and you notice how your shirt clings to your skin, the coolness of the air entering your lungs, the pressure of the ground beneath your feet.

        Your focus feels physical now, something to be moved around at will. Rather than directing it outwards, you turn it inwards, trying to find the border where "you" ends and the rest of the world begins. Try as you might, you can't quite manage it. But the hairs on your skin tingle; the air you breathe in feels colder.

        "A good start," Master Cheng says softly.

*page_break
The afternoon sun begins to sink below the bamboo, and Master Cheng concludes the session. Inside again, simple bowls of tofu pudding await. Eric takes his with yellow rock sugar, while you add ginger syrup. The ginger barely bites, its sweetness blending with the silky tofu.

Dessert finished and tea poured, Master Cheng rolls his shoulders, and Eric leans back. The conversation turns to Eric's latest activities. He brings up the approaching Pearl River Cup, although he doesn't mention Chloe or the situation with the committee.

"These commercial events," Master Cheng says, as he sets down his teacup with a soft clink.

"They pay the bills, Master," Eric says. "In today's world, I need a platform to reach people. Then I'll be able to show them what real skill looks like."

"I hope that is so."

Silence returns to the room. You stare at the tea in your cup, watching how the surface ripples with every tremor of your hand.

Master Cheng sighs, long and slow. Then he looks at Eric, his gaze soft. "Your improvement is impressive, Eric. Your control is better, your understanding is deeper."

He turns to you, his eyes bright and piercing. "What about you, ${first_name}? What do you think of my former student?"

*choice
    #Say that you admire Eric's commitment and discipline.
        *gosub_scene utils increase_composure
        You tell Master Cheng that you admire Eric's commitment to improving his skills and his determination to keep pushing forward. That you appreciate his willingness to teach others and give back.

        He listens to you, eyes never leaving yours, and then nods. "He has always worked hard, and he has always been willing to support others."
    #Agree that Eric is competitive, and add that he also respects his former master.
        *gosub_scene utils increase_analysis
        *set eric_friendship +1
        You choose your words: that he's intensely competitive, yet also appreciates his mentor's teachings.

        Master Cheng considers your words for a long time, his eyes becoming distant. Finally he says, "That is good to hear."
    #Note that Eric respects Master Cheng more than he lets on.
        *gosub_scene utils increase_empathy
        *set eric_friendship +2
        You note that their disagreement about the right path forward is clear, but Eric still speaks of his mentor with deep respect, and often draws from his wisdom in his training.

        Master Cheng's expression is almost unchanged, but a flicker of a smile crosses his face. "That is good. Respectful disagreement is healthy."

He says nothing more. Motioning for you to stay, he rises, and walks outside to the garden. He returns with a small cloth bag tied with a hemp cord.

"Just as a precaution," he tells Eric. "Use this healing salve sparingly. And I've included something for your friend's wrist." He glances briefly at you. "I noticed ${he} @{gender_num favours|favours|favour} it slightly during the cross."

You instinctively touch your wrist, where you hadn't noticed anything.

"Thank you, Master Cheng," Eric says, bowing as he accepts the bag in both hands.

*page_break
Master Cheng escorts you to the edge of the clearing. "Eric. The energy flows to where your attention is. The world will always try to steal your attention."

Eric lowers his head, eyes closed. His eyelids flutter. "I will give it my best effort," he says finally, meeting Master Cheng's eyes. "I don't know if I can. But I will try."

Master Cheng nods, and places a hand on his shoulder, lingering longer than tradition would require. Then he turns to you. "It was interesting to meet you, ${first_name}. Perhaps you will help Eric work things out." A smile dances at the corners of his eyes. "He has always been better at teaching than listening."

*choice
    #Become aware of your position here.
        *gosub_scene utils increase_composure
        You've been quietly included in their mentor-disciple relationship, not as a student or stranger, but as something in between. It's fine.

    #Pick up on how Master Cheng watches over Eric.
        *gosub_scene utils increase_empathy
        On the surface, frustration and amusement. You see his smile flicker, then return. Pride, maybe. But then the silence after, longer than expected.

    #Observe how Master Cheng balances his criticism with praise.
        *gosub_scene utils increase_analysis
        Praise for Eric's effort, then subtle disapproval that he feels the need to impress.

You and Eric walk back to the village in silence, your shoes crunching on the dirt path, a few crickets chirping in the dusk. Thoughts bubble to the surface, of Master Cheng's graceful movements, of your attempts to sense the energy around you. As you leave the village behind and wait on the dusty road, Eric clears his throat.

"So... that's Master Cheng," he says, with a wry smile. "He taught me how to use my energy powers. Then he told me to never use them."

He gazes back at the village, shaking his head. "You know how I first discovered I could project energy? It was an accident, during a tournament. I just burned the hairs on my hand. But the next day, Master Cheng found me. Said he felt the energy resonance, that he'd been watching for someone like me."

Eric exhales. The minibus pulls up beside you, and you board together, tapping your Octopus to the fare reader. You sit side by side as the minibus pulls away.

The village disappears from view. The surroundings soon return to the familiar urban landscape. Eric stares out the window, one hand cradling the cloth bag in his lap.

"He's not wrong," he says quietly. "But it's not enough. Not for me."

The reflection in the window shows his lips pressed tight, his eyes flickering. Then it's gone, a thin smile replacing it.

[i]Master Cheng didn't officially train you. But you learned enough now to practise what he taught, alone.[/i]
*set eric_friendship +2
*return

*label event_4
Night has settled in. Gym bag slung over your shoulder, you walk to Mong Kok East to take the East Rail. You exit at Fo Tan, where the high-rises crowd you on all sides as you emerge on to the almost-deserted street, and duck into a narrow overpass that crosses a six-lane highway.

The Hong Kong Sports Institute appears ahead, a large, squat complex of glass and steel.
*if current_season = "winter"
    The automatic glass doors slide apart.
*else
    The automatic glass doors slide apart and a puff of cool air hits you.
Inside, the walls are lined with busts of former Olympic medallists, inspirational billboards from bespectacled politicians, donor plaques featuring property tycoons. You head straight past. The creaking lift takes you to the wushu training hall, where Eric has the entire space to himself at this late hour.

Eric greets you. He's in a white [i]gi[/i] today, sweat darkening the fabric despite the air-conditioning. He sweeps his hand over the large hall, empty except for metal benches along one wall and a digital signboard mounted high above them. You set your bag down slowly on the bench, next to his. It slides off and hits the floor with a soft thud that echoes through the hall. You leave it.

"Told the director it would be safer if no one else was around," he says, his voice tight. He passes you a pair of focus mitts. They feel twice as heavy as the ones at [i]MK[/i].

"I can control the fire during basic combinations. These mitts are fire resistant. Let's take it slow."

*choice
    #Feel the strain in Eric's posture and voice.
        *gosub_scene utils increase_empathy
        No friendly greeting, straight to the point. Something's on his mind, but you don't know what it is yet.
    #Assess the precautions Eric has taken.
        *gosub_scene utils increase_analysis
        Empty hall. Fire-resistant mitts. An attempt at damage control.
    #Prepare yourself mentally for whatever might happen.
        *gosub_scene utils increase_composure
        You try on the mitts. The heaviness is almost comforting.

He winds his hand wraps, and you notice the metal strands embedded in the cloth, glinting in the white light. You hold the mitts as he instructs: both high, then angled left, then a left-right-left sequence. A faint amber glow surrounds his fists, and warm heat radiates to your arms when he makes contact, although your mitts stay cool to the touch.

He starts with basic punches, and then moves on to more complex sequences. The force seems to come more from his arms than his body, producing sharp, insistent punches without much follow-through. As he works through longer combinations, the glow intensifies but becomes unstable, wavering, flickering, like a torch in wind. Sweat runs down his face, his jaw clenched tight.

Straight punch, elbow, straight punch. But on the last punch, a crack, like thunder. Eric exhales sharply through his teeth, stifling a yell. The air smells of scorched ozone. He gasps, then wobbles before steadying.

Then he sits down, takes a long drink from his water bottle, and wipes his face with a towel. He doesn't say a word. 

*choice
    #Compliment his effort and his progress with the energy integration.
        *set eric_harmony -2
        "The fire looks like it's following your movement now."

        "Thanks. I just need to control it better."
    #Consider what Master Cheng would advise in this situation.
        *set eric_harmony +2
        You think back to the visit with Eric to Master Cheng's abode, and what Master Cheng might think about this.

        Eric notices your frown. He sighs. "I know. I shouldn't over-exert myself."
    #Ask about how this relates to the upcoming Pearl River Cup.
        "Are you training so hard because of the Pearl River Cup?"

        "Yeah. The sponsors want winners, but they also want them to look good while doing so."

        Makes sense. They need to draw crowds, after all.

He takes another sip of water, and looks into the distance.

"This next technique, I've been training it for months. The Cup is the first time anyone will see it. It has to be perfect."

Eric stands up slowly, then looks down at his hands. A frown crosses his face. Then he turns his head to look at you, and forces a smile.
*if eric_harmony < 50
    You return a small smile.
*elseif eric_harmony > 50
    You don't smile back.
*else
    You nod.

The muscles on his arms go taut, his hands balling into fists.

"The [i]Volcanic Dragon Ascent[/i]."

Eric strides to the middle of the training hall, well away from you, and extends his arm towards you, palm out.

He bends his knees and takes a deep breath, his face tight with concentration. You feel a vacuum pulling you towards him. A roar of flame erupts in a column around him. He spirals upwards, fist extended skyward. The fire intensifies into a vortex around him.

Then the flames disappear in a flash as he lands unsteadily on one knee, hands planted on the floor, sweat dripping onto the singed mat. Wisps of black smoke float up, distorting the air. The smell of ash and ozone reaches you. It's several seconds before he rises.

A sharp cough. "Damn. Still unstable. I can't use this." 

He walks over, cradling his right hand at the wrist, where it trembles.

*choice
    #Steady his wrist. He shouldn't injure himself before the Cup.
        *set eric_romance +1
        *set eric_friendship +1
        You see the veins at his wrist pulsing rapidly, the skin reddened. You almost tell him to rest, but you see his clenched teeth, the tension around his eyes. Not the time for words.

        You take his wrist between your hands, feeling the residual heat, the trembling muscles. You press your thumbs gently along the tendons.

        His hand jerks, but he doesn't pull it away. You feel him holding his breath. The rest of his body doesn't move.

        "I couldn't control the fire." He cuts off the words with a short laugh.

        "You don't have to do this for me." His eyes are studying the floor mats.
    #Ask him what makes the [i]Volcanic Dragon Ascent[/i] so challenging.
        "That's... a lot of energy. What makes it so hard to control?"

        "The energy always needs to be in motion. If I lose focus for even a second, it will go out of control." He points at the scorched floor mat.

        "So it's about focus? Intention? Something like that?"

        "Exactly. Guiding it, letting it know where I want it to go."

        The hall is silent except for the sound of your breathing. The faint burning smell starts to clear.

*page_break
Eric shakes his head with a slight smile. "Master Cheng would never approve. Too flashy."

He stares at the scorched floor mat for a few seconds. Then, his jaw set, he pulls on his wrist wraps and stands up.

He begins the [i]Volcanic Dragon Ascent[/i]. The flame column blasts you with a wave of heat, and this time the tendrils of fire move smoothly. He lands on both feet, his chest heaving with effort.

As soon as his breath evens out, he launches into another one. But this time the flames split. A loud snap cracks through the air, and the pillar collapses before he completes the ascent. A smell like burning honey reaches you.

He lands hard on the mat with a thump. Pale, trembling, his hands and knees on the floor.

*choice
    #Encourage him to push through and make the move work.
        *set eric_harmony -4
        *set eric_friendship +1
        "You almost had it. Catch your breath and give it another shot if you feel up to it."
        
        Eric takes a deep breath. "Okay. I'm... fine," he manages. "Just pushed it too far on the last one."

    #Suggest that he take a breather.
        *set eric_harmony +2
        *set eric_friendship +1
        "You look pretty drained. Do you want to ease off a bit?"

        Eric takes a deep breath. "Yeah. That's a good idea. Pushed it a bit too far on that one."

He lowers himself onto the floor mats. Your eyes drift to his hands. They're still shaking.

"What happened?" you ask, taking a seat beside him.

"Burnout. I didn't move the energy fast enough, and it burned me from the inside."

He winces. "Master Cheng warned me about this. Many times."

*if (eric_romance >= 1)
    You rest a hand on his shoulder.
*else
    You give him space.

He forms a fist with his right hand. But his fingers loosen and tremble. Eric shakes his head, and his eyes drop to the floor.

He goes over to his gym bag and takes out the small cloth bag Master Cheng gave him last time. He fishes a bottle from it and opens it, massaging the ointment into his arm. A faint smell of mint, camphor, medicinal roots. The trembling eases, gradually.

*page_break
"One last attempt," he whispers.
*if eric_harmony > 50
    Seeing your expression, he adds, "different this time."
*else
    Seeing your expression, his mouth twitches, then he flashes you a brief smile.

"Less fire. Maybe that works better."

He stands slowly and smooths out the fabric of his [i]gi[/i]. He breathes deliberately. In, out, in, out. Then he nods at you, and you retreat to the bench.

He rises again in the [i]Volcanic Dragon Ascent[/i]. The fire is golden, not crimson. The flames seem to move almost languidly, expanding and contracting with his movements. A wave of warmth reaches you, softer on your skin, and more sustained.

He lands smoothly on his feet, the fire melting away. Quick but not laboured breaths. The warmth lingers.

"That... felt different." He looks at you with the slightest frown, but his eyes are gleaming.

*choice
    #Confirm that it looked and felt different.
        *gosub_scene utils increase_composure
        "Yes, it was different. Gold fire, not red. The flames stayed tight and moved with you."
        
        He smiles, his voice steadier than before. "Well, what do you think? Is this version better?"

    #Ask him how it felt compared to previous tries.
        *gosub_scene utils increase_empathy
        "How did it feel to channel the energy this way?"

        His eyes go out of focus. "Hmm. Not as hot. I mean, internally as well. I didn't feel myself burning inside much."

        You point at the space above him where the flames rose up. "It looked different too. The flames moved with you."
        
        He smiles, his voice steadier than before. "So what do you think? Is this version good enough?"

    #Note the practical advantages of this modified move.
        *gosub_scene utils increase_analysis
        *set eric_harmony -2
        "This is much more controlled. You'll be able to rely on it in the tournament."
        
        He rolls his shoulders back and nods. "Yeah. It didn't take as much out of me either."
        
        He smiles, his voice steadier than before. "So do you think this version is tournament-ready?"

"Yeah. You're ready, Eric."

Eric shrugs his shoulders, smiles, and slowly rolls his neck. "Guess I'll find out soon."

He opens his mouth to speak again, but nothing comes out. After a pause, he clears his throat. He stares at you, making sure you're looking at him before he continues. "You shouldn't come."

"If I know you're watching, I'll make it hotter. Flashier.
*if eric_harmony > 50
    That's the wrong reason to fight."
*else
    I won't be focused on the fight."

*label cup_choice
*choice
    #"I understand. It'll be easier to focus without distractions."
        *set eric_harmony +1
        "I understand. It'll be easier to focus without distractions."

        Eric nods slowly. "I'm happy you understand what it means to me."

    #"I understand. Don't hold back."
        *set eric_harmony -1
        "I understand. Don't hold back."

        Eric nods and lightly claps you on the shoulder. "I'll give it my best effort."

    #"I'll miss seeing you at the Cup, Eric. But I'll still be thinking of you."
        *set eric_romance +1
        "I'll miss seeing you at the Cup, Eric. But I'll still be thinking of you."

        Eric's ears redden. He breaks eye contact, his gaze dropping to your neck.

        "I'll be thinking of you too, ${first_name}. Thank you. For being here with me." He clasps your hand in his, and smiles. After a moment, he releases his grip.

    *hide_reuse #"I've been with you all this time. I'm attending anyway."
        *set eric_friendship -2
        "I've been with you all this time. I'm attending anyway."

        Eric's jaw tightens. He takes a slow breath before he speaks. "If you show up, ${first_name}, I won't be able to keep training with you."

        Are you sure you want to go?

        *choice
            #Yes.
                "I'm going."
                
                Eric doesn't say anything at first. His mouth opens part way. Then the warmth leaves his eyes, and he closes his mouth again.

                "Okay," he says. It sounds almost formal.

                "Then we stop here. Take care, ${first_name}."
                
                He steps back from you, straightens up, and leaves.
                
                *page_break
                A few weeks later, you go to the Pearl River Cup. From the back of the crowd, you see glimpses of Eric's red [i]gi[/i], golden flames. After the match, he scans the spectators. His eyes settle on you.
                
                He doesn't react. Not even a flicker.
                
                Then he turns away.
                
                You never see him again.
                *set eric_subplot_status "rejected"
                *set eric_friendship 0
                *set eric_romance 0
                *goto event_end
            #Let me reconsider.
                Eric's shoulders ease.
                
                "Thank you," he says quietly. "I need to be completely focused when I'm in the ring."
                *goto cup_choice

The ventilation system powers down, and the training hall becomes completely quiet. Eric spares a last glance at the charred floor mat.

*temp temperature_adj "warm"
*if current_season = "summer"
    *set temperature_adj "hot"
*elseif current_season = "winter"
    *set temperature_adj "cool"
Both of you step outside into the ${temperature_adj} evening air. Eric gives a small bow, bending at the neck. "See you soon, ${first_name}."

*if eric_romance >= 1
    He turns to you one last time, his gaze lingering a bit too long. Then he's gone.
*else
    Then he's gone.

[i]A Boxing Insight settles into your body. An understanding of energy.[/i]

*label event_end
*return

*label event_5
It's been an hour on the 118 bus as it rumbles towards Siu Sai Wan, when you finally see the soaring towers of the Island Resort estate, eight blocks of brown tile and sea-green glass. As the bus turns into the terminus, the ocean spreads out before you, marking the end of Hong Kong Island. A clear day today.

You get off the bus and find the meeting point inside the mall, where Eric is already waiting. He's wearing a red polo shirt tucked into blue jeans, with a brown leather belt.
*if eric_romance >= 1
    "${first_name}!" He embraces you in a hug, holding it slightly longer than necessary. You return the hug. Eric's warm. Physically warm, even in the air-conditioning.

    He lets go and says, "So happy to see you again. You were the first person I wanted to tell about the Pearl River Cup!"

*else
    "${first_name}!" He shakes your hand firmly.

    "Great to see you again. Always nice to see an old friend."

You walk through the ground floor level, past unlit shopfronts where restaurants used to be, piles of unopened letters slipped under the glass doors. Arriving at one of the towers, Eric taps a passcard and waves at the security guard, and you take the lift up to the sixth floor podium deck.

*temp lost_match ""
*if eric_harmony > 50
    *set lost_match "quarter-finals"
    "The Cup was great. I made it to the ${lost_match}. Didn't even summon the fire that much, just when it counted. The spectators liked the gold flames, I think."

    He smiles to himself. "Anyway. Was a good experience."
    
*else
    *set lost_match "semi-finals"
    "The Cup was great. I made it to the ${lost_match} and had some spectacular fights. I think there's a video of the quarter-final knockout online."

    He pulls out his phone and scrolls through it. "Huh, can't find it. I'll send it to you later."

*page_break
*if current_season = "summer"
    The windswept deck overlooks a large swimming pool, dotted with recreational swimmers.
*else
    The windswept deck overlooks a large swimming pool, unused at this time of year.
There's a children's play area to one side, two toddlers laughing and chasing one another through the plastic play equipment, their minders sitting on a ledge nearby. A sudden gust catches you off-balance; Eric doesn't seem to notice it.

Eric continues: "My biggest tournament so far, way bigger crowds than I'm used to. Managed to keep it together, no blunders. Fingers crossed for next time."

*if eric_harmony > 50
    "Clean wins to start. Quarter-final was against this Choy Li Fut guy, read all my moves. Just couldn't create any openings. Fair."
*else
    "Clean wins to start. In the semis I over-extended with an uppercut and he punished it. Probably could have won if I waited a bit more..."

You cross the short distance to the clubhouse entrance, the wind silenced as soon as the door closes.

"Committee seems happy with my performance. Sponsors are circling. But they'll want me to put in more appearances."

*choice
    #"Sounds like a big opportunity."
        *set eric_harmony -2
        "Sounds like a big opportunity."

        "Yeah, you think so, huh?" He laughs, big, and smiles at you, teeth flashing. Then he looks away.

    #"Only worth it if it's what you want."
        *set eric_harmony +1
        "Only worth it if it's what you want."

        "Yeah... maybe. It's what I'm here for, right? I don't know, though." He looks over at the marine-blue glass of the reception desk.

    #"What do you want to do?"
        *set eric_harmony +2
        "What do you want to do?"

        He stops walking, right in front of the reception desk, and a staff member almost stumbles into him. "Huh. Good question. It would be nice to be more recognised..." He rubs his chin.

"Come on, let me show you what the sponsors put on."
*if eric_romance >= 1
    He leads you by the arm down the spiral staircase.
*else
    He tips his head towards the stairs, and you descend together down the spiral staircase.

The bottom floor of the clubhouse opens into a wide residents' lounge with a few rows of empty sofas, broken up by racks of newspapers that look like they're still swapped out every day. You walk past a mahjong room into a function room, with folding tables, a TV bracketed to the wall, and stacks of identical plastic chairs. A foil penguin balloon bobs at head height on its tether, and scattered paper streamers and small piles of confetti litter the floor. A huge cardboard banner — CONGRALUTIONS mr. JIANG — occupies most of the short wall.

"Congralutions, Eric! Whatever that means!"

He chuckles. "Heh. That's what I was doing this morning. This sponsor group threw a party for me, which turned out to be some kind of photo shoot as well."

He picks up a leftover name card from the table. "This one is 'Shantou Jiahe Biologic Technology'. I don't know what they even do, honestly."

*choice
    #Watch Eric turn the name card over.
        *gosub_scene utils increase_empathy
        Eric turns the name card over, reading the back. His eyebrows knit. It's the face you make when trying to work out if an email is a scam.

        He shrugs. "It's all good, they need some publicity, and it helps me pay the bills."

    #Don't pry into the celebration.
        *gosub_scene utils increase_composure
        Not the grandest celebration you've ever seen. But it's not your business. No need to pry unless Eric brings it up himself.

    #Inspect the banner more closely.
        *gosub_scene utils increase_analysis
        You inspect the banner more closely. At the bottom, below the large "CONGRALUTIONS mr. JIANG", is an additional line:

        "Karate Master, Eliminated in ${lost_match}."

        Just-in-time manufacturing.

"You know, ${first_name}, this is what I've always wanted. I dreamed about this when I was a kid in Shunde. The first time I memorised a kata, I made my mum watch me."

His voice drops, almost to a whisper. "But I haven't even called her yet. I don't know how I should say it."

Eric jabs the penguin balloon in slow motion, and it sways almost down to the ground before the helium lifts it up again, gently resting against his face. Eric pushes the balloon away and smiles. Sighs.

He faces you. "Thanks for making it all the way here. Quite a trek from Mong Kok."

*temp eric_first_advance_accepted true
*if eric_romance >= 1
    He sets the name card down and comes over to you, stopping a pace away. His arms hang loose at his sides. His hands open. They drift towards your hands, then stop.

    *choice
        #Take his hands.
            *set eric_romance +1
            You fit your hands into his, palm to palm. You feel, rather than see, him lean in. He draws you in closer.

            "${first_name}."

            He looks down at you, and you smell something like embers. He holds there, longer than needed, then releases your hands.

        #Keep your hands still.
            *set eric_romance -1
            *set eric_first_advance_accepted false
            You keep your hands at your sides. Eric stops, then his hands settle back.

*else
    He claps his hand on your shoulder, once.

"Well, this room sucks. Let's take a walk around."

*page_break
You follow Eric out, past a glass-walled wine room, and stop at the squash courts. Two lean middle-aged men are rallying, squash ball thwacking this way and that. The ball clips the tin and dies. There's a row of chairs outside the courts, and Eric sits down on one of them. You take the one next to him.

He watches for a while. Then, eyes on the court, he speaks.

"Master Cheng wasn't always a recluse. Used to be a minor celebrity. You know that? It's why he's so agile. Had really good dance moves."

His gaze drifts to four women walking past, their badminton gear shouldered.

"These past few months he's been busy in Tai Po setting up his new training centre. He wants to teach people martial arts and traditional Chinese medicine. They're mostly the same thing, right?"

He scratches his head. "I'm thinking of maybe helping out a bit. They might need a janitor or something, I don't know."

You try to read what's behind his words.

*fake_choice
    #Escape? The appearances, the publicity?
        Escape? The appearances, the publicity, none of it really belonging to him? And maybe following Master Cheng will be a way to disappear.

    #Ambition? Mastery of the power he couldn't control?
        Ambition? Mastery of the power he couldn't control, learning more from Master Cheng to create something even better? Maybe he has something in mind already.

    #Return? To the student he used to be?
        Return? To the student he used to be, before all this? Maybe he's trying to find the way back, to something simpler.

"That sounds interesting, Eric. What's the centre going to do?"

"I'm not sure either. He emailed me this huge pitch deck, but I didn't manage to get past the first few slides. I do know that it's mostly Chinese medicine and qi work. No fighting. The martial arts is mostly for cultivating the qi."

He shifts towards you, knees drawn together, and clears his throat. "Would you be interested in taking a look? I'll be going there soon. I can tell you more once I check it out."

He stands up before you can reply. "We should find somewhere more comfortable."

You follow him back past the function room, its floor still strewn with confetti, penguin balloon still swaying, and arrive at the lounge area.
*if eric_romance >= 1
    Eric's pulled a single-seater sofa to face another one. You take the sofa opposite him, close enough that your knees are almost touching.

    *if eric_first_advance_accepted
        "So, ${first_name}... you've been here for me, these past few months. And I feel like... I don't know if it's something you want, but I could be here for you."
    
        He leans forward, hands on his knees. He takes a deep breath and waits.

        *choice
            #"I want you to be here for me." [i](Be his partner.)[/i]
                *set eric_partner true
                "I want you to be here for me."

                Eric releases his breath and smiles at you, his cheeks dimpling. "I'm happy to hear that, ${first_name}."

                He reaches across and takes your hands in his.

            #"I'm not ready for that." [i](Stay friends.)[/i]
                *set eric_romance -1
                "I'm not ready for that. Sorry, Eric."

                Eric releases his breath. His hands close, open again.

                "I'm glad I asked, anyway."

                He sits up straight. "Well, let me just catch up on the news."

    *else
        "So, ${first_name}... I just want to thank you for being here with me."

        He sits straight, with his hands on his knees, palms turned up. He says nothing more.

        *choice
            #Put your hands into his. [i](Be his partner.)[/i]
                *set eric_partner true
                You put your hands into his, feeling the steady heat of his palms. Eric releases his breath and smiles at you, his cheeks dimpling.

                "${first_name}... thank you."

                His hands close around yours.

            #Thank him back. [i](Stay friends.)[/i]
                *set eric_romance -1
                "Thank you, Eric."

                He nods. "Good. Let me just catch up on the news."

*if eric_partner
    *set eric_romance +2
    *set eric_friendship +3
    *if not(eric_first_advance_accepted)
        "You've been here for me, these past few months. And I feel like... I could be here for you, too."

    He moves close, so close that you can feel his breath, see a drop of sweat on his face.

    He takes his time. He looks down from your eyes to your mouth. Then there's no more gap. You kiss him, and he returns it, his hands tightening around yours. His mouth is warm, and tastes faintly of tea.

    He releases your hands and wraps his arms around you, drawing you off your seat and into his lap. A low, even heat radiates from his body.

    You hold the kiss as the lounge seems to go quiet. Then Eric loosens his arms, and you settle back onto your sofa, knees still touching. He says nothing, just looks at you.

    *choice
        #"I'd like to go somewhere more private with you." [i](Sex scene.)[/i]
            "I'd like to go somewhere more private with you."

            Eric doesn't respond for a moment. His chest rises.

            "My place is a twenty-minute walk from here."

            *page_break
            The afternoon sun beats down as you stroll along Siu Sai Wan Road, hand in hand. You walk in silence, the pavement wide and mostly empty, with just an elderly woman going the other way, two teenagers on the rim of a planter box, a mother and son at the bus stop railing. Twenty minutes disappear into the silence. Yee Shing Street, then Yee Tsui Court: three tower blocks in white tile, laundry strung out overhead.

            "Here we are. It might be a bit messy inside." A wall of mailboxes in the lobby. The lift fan is loud, and dust cakes the grille. Eric's grip tightens.

            A shoe rack by the front door, shoes in two rows, all facing out. A drying rack folded against the wall, a dining table with two chairs, a kitchen only four feet wide. Next to the open bedroom door, a shelf with small trophies and framed certificates.
            *if highest_trait = "analysis"
                There's no dust on the trophies, even the ones at the top.
            *elseif highest_trait = "composure"
                One placemat on the table. Nothing on the floor.
            *elseif highest_trait = "empathy"
                It smells like washing powder or shampoo.
            *else
                *bug Invalid trait
            
            Eric crosses to the counter and comes back with two bottles of water. He holds one out to you. "Some water?"

            You crack the cap and drink, then set the bottle on the table. Eric empties his in one go and puts it beside yours. You lean in and kiss him, and he kisses back.

            Both his hands are on you now, one at your hip, the other between your shoulder blades. You lean back under his kiss, arms around his waist. Eric breaks away and tips his head towards the bedroom.

            *page_break
            Sun comes in through the window, across the desk and onto the double bed. The room's warmer than the rest of the flat.

            Eric stops with his hands on the collar of his polo, then pulls it off. He gets your shirt halfway up, and you take it off. He's trying to take his time, but his hands won't stop moving.

            He guides you onto the bed and lowers himself on top of you. His weight settles onto you, and he's warm, then hot, and he doesn't notice.

            You dig your fingers into his hair and bring his mouth down to yours.
            
            Eric pushes up onto one hand and undoes his belt buckle with the other. The belt catches on the loop. He rolls beside you and pulls it free, then the rest goes quickly. Your clothes are already on the floor.

            He gets back over you and looks into your eyes. You hold his gaze. You place both hands on his back and pull him down onto you.

            *page_break
            The air conditioner hums. You lie under the covers on your back. The pillow's damp where your hair meets it. Eric comes back from the shower with his hair wet and gets in beside you. He pushes your hair back, his hand cool against your forehead. He lies back.

            "Stay for dinner? I can cook."

        #Stay here with him.
            You take his hand between both of yours and squeeze. His warmth spreads through your fingers.

            The lounge comes back into focus. Behind you, someone rustles a newspaper.

*else
    *set eric_friendship +3
    Eric's pulled a newspaper off the rack, the paper clamped in its reading rod, and sits on a low single-seater sofa. You sit on the one opposite, a low table in between.

    He lays the paper down and spreads it open, the edges overflowing the table. "People still read newspapers. You wouldn't think it."

    He flips through the pages, his head bobbing as he runs a finger down the columns. "The Pearl River Cup results should be in the newspapers by now."

    You lean over to help, although you can't make out much of it upside down.

    Eric reaches the end of the paper. "Nothing. Weird. Maybe they had budget cuts and couldn't send a reporter."

    You agree with him.

    Eric says something under his breath. He keeps staring at the back page.

*return

*label event_6
It's a short walk uphill from the Tai Po Market station, the early morning sunlight warming the air. In front of you appears a two-storey whitewashed stone compound, set behind a short lawn and a low metal fence, with a sign on the gate introducing the place as a heritage site and former police station.

You push the gate open and enter the grounds. The low, wide blocks surround a small courtyard. Eric's waiting outside one of the buildings, dressed in a blue polo shirt, slim-fit jeans, and ankle boots, and smiles when he sees you.

*if eric_partner
    He pulls you into a hug right away, hands warm on your shoulders, and kisses you, once, on the lips, before he steps back.

    "Hey, ${first_name}, glad you're here."

*else
    He shakes your hand. The warmth radiates from his palm.

    "Hey, ${first_name}, glad to see you again!"

Eric leads you into the largest block, then to one of its rooms. The hallway sign announces it as "The Centre for Qi Therapy". The door's closed — a sign says it opens at 11:00 — but he pushes it open and shows you inside.

Sunlight streams in from the casement windows, dazzling you. The air is bitter with medicinal herbs. Your eyes start to adjust to the light. A grid of small herb drawers along one wall, a door to what looks like an office, a reception desk, and a wheeled whiteboard, stained with permanent marker, on bare wood flooring. A large bronze plaque, mounted on wood, hangs on another wall, proclaiming "Foundation Sponsors — $250,000" with a half dozen corporates and the obligatory Jockey Club, then the Platinum sponsors, Gold, Silver, and finally Bronze at $10,000.

*fake_choice
    #You were expecting something like this.
        You were expecting something like this when you heard Master Cheng was setting up a centre of his own. A heritage building that's easy to reach but set apart from the noise of the city. Master Cheng seems to have the business side handled as well.
    #This isn't what you expected to see.
        This isn't what you expected to see when you heard Master Cheng was setting up a centre of his own. Although it's in a heritage building, the sponsor plaque seems too large for the room.

"Master Cheng should be back soon. He's setting something up with an international school nearby."

Eric walks over with you to the reception desk. It's chest-high and made of solid wood, with a mesh swivel chair behind it. A sign reminds visitors to download the app for bookings and updates.

*if highest_trait = "analysis"
    You consider the sponsor tiers, booking app, school connections. Master Cheng's idea now has an infrastructure.
*elseif highest_trait = "composure"
    Fancy apps and sponsor plaques. Underneath it all, a desk, a chair, a whiteboard, and bare floors.
*elseif highest_trait = "empathy"
    Sponsor plaques, bookings, school connections. A lot of people must have helped with this.
*else
    *bug Invalid trait

Eric places a hand on the desk, resting it there as he turns to you. "Isn't this wonderful? It's what Master Cheng always wanted, and he finally managed to do it."

*choice
    #"It's wonderful, Eric!"
        *set eric_harmony -1
        "It's wonderful, Eric. He actually did it!"

        Eric grins and claps you on the back. "I'm so happy that Master Cheng managed to get this thing off the ground. He never told me outright, but I always knew he wanted this."

    #"It feels a bit too commercial."
        *set eric_harmony +1
        "It feels a bit too commercial. This plaque is pretty big."

        Eric strokes his chin. "I see what you mean. It all costs money. Not what you'd expect him to do, right? Hmm. Maybe."

    #"It feels commercial, but it's still wonderful."
        "It feels commercial, but it's still wonderful. An interesting mix."

        Eric nods. "I know what you mean. It's hard to square the money side with what you'd expect from Master Cheng, right?"

It's then that Master Cheng slides through the entrance. He's wearing a plain brown shirt, trousers, and cloth shoes. He nods to Eric, then greets you.

"${first_name}, a pleasure to see you. I'm honoured by your visit. Come, let's have tea."

*page_break
Master Cheng shows you into the office. The room crowds in on you, with a shelf of knick-knacks, cushions tucked into a corner, and a scratched wooden desk occupying most of the remaining space. On the desk, a stack of applications for government grants in Chinese medicine, sustainability, community-building.

Eric catches you looking at the papers. "I've been helping Master Cheng out with some paperwork. There's more of it than I expected."

Master Cheng says, "Eric keeps the place running. Come, sit down and have some tea."

You settle onto a cushion as Eric takes the one beside you. Master Cheng brings over a footed serving tray, holding an earthenware teapot and three cups. He wraps his palms around the teapot. Not long after, the lid clatters and wisps of steam rise. He pours the tea and sits down opposite you.

You raise the cup to your lips and breathe in. Earthy, but it reminds you of a clear morning sky. A sip. It tastes like almost nothing, but it's warm, and a sweetness lingers on your tongue.

*fake_choice
    #Say nothing.
    #Ask Master Cheng what this centre is for.

Master Cheng takes a sip of his tea. "I want to bring qi therapy to more people. I hope this can do some good."

He looks directly at you, and his eyes are clear, catching the sunlight from the window. Eric is turning his teacup in his hands, eyes fixed on it. Master Cheng finishes his tea and continues: "Whatever you do, always do it fully."

You have nothing to offer, so you just nod.

Master Cheng says he will take care of some matters outside, and leaves you and Eric alone in the office.

*page_break
Eric doesn't say anything. He rubs the rim of his teacup with his thumb, making a rasping sound that he doesn't seem to hear.

"Master Cheng was always telling me to retreat into solitude. But look at this."

You finish your tea, and remain seated. Eric's still staring into his tea, so you give him time to work it out.

Eric sits up straight, a bit of tea spilling from his cup. "I think I get it, maybe? Like, this whole centre..."

He looks at you.

*choice
    #"Master Cheng said to retreat into solitude, but now he's commercial."
        *set eric_harmony -2
        You collect your thoughts before responding. "Master Cheng said to retreat into solitude, but now he's commercial."

    #"Master Cheng seems to be at peace with needing to do commercial things."
        *set eric_harmony +2
        You collect your thoughts before responding. "Master Cheng seems to be at peace with needing to do commercial things."

Eric goes quiet, his thumb no longer rubbing the rim of his cup. He leans back against the wall and shuts his eyes, creases appearing on his forehead. You wait patiently.

After a long moment, he opens his eyes. He speaks, more to himself than to you. "How is Master Cheng so comfortable with this? What does this mean for me?"

*if eric_harmony > 50
    His gaze moves from his empty teacup to the paperwork on the desk. Grant applications. Utility bills. Marketing campaigns.

    He rubs his chin. "He's really gone all-out to make this thing work. But he taught me not to do this."

    Now Eric's pacing around in the room, turning every three steps. "Although, you know... whether it works or not, I reckon he'd be fine with it. Would I feel like that?" 

*else
    His gaze moves from his empty teacup to the sponsor plaque outside the office. Then he stares at the desk: grant applications, utility bills, marketing campaigns.

    "He's really gone all-out to make this thing work. But he taught me not to do this."

    He rubs his chin. "Or maybe he didn't?"

    Now Eric's pacing around in the room, turning every three steps. "You know... all this time, I thought Master Cheng had all the answers."

*if eric_partner
    Eric grips you by both shoulders, his hands hot through your shirt. "I think that's it! Let's go find him!"
*else
    Eric stands up in a single motion. "I think that's it! Let's go find him!"

*page_break
You try to catch up as Eric half-runs across the courtyard to Master Cheng.

The words spill out of him. "Master Cheng! I understand now. Thank you... thank you for being so patient with me."

Master Cheng stares at Eric. Then, he pats him on the shoulder, and smiles. "Eric, I'm glad you've found your way. It makes an old teacher happy."

*if eric_harmony > 50
    Eric sighs, the breath leaving him. He nods, then looks down at his feet.
*else
    Eric nods and looks up at the sky with a smile.

Then Master Cheng turns to you and says, "We're just getting started, so it helps if you download the app and leave a review."

His eyes twinkle.

Eric lets out a breath. He bows deeply to Master Cheng, who answers with a fist pressed into his palm. 

*page_break
*if eric_partner
    Master Cheng takes his leave, returning to the office. Eric moves close, close enough that the hairs on your skin rise towards his heat.

    "I think I know what to do. For myself. For us. But first —"

    He takes both your hands in his.
    *if eric_harmony > 50
        You feel the warmth radiating from his palms, a campfire's soft embers.
    *else
        You feel the warmth radiating from his palms, a flame hungry for more.
    He takes you to the low stone wall at the edge of the courtyard. Both of you sit down, as if sharing the same breath, hands still joined.

    His thumbs work slow circles into your palms. It feels like your energy clears and flows into his. You lift your eyes from the grass to him. He's already looking at you. No need for words.

    The morning sun touches your face. It feels warm.

*else
    Master Cheng takes his leave, returning to the office. Eric bows his head in Master Cheng's direction. He breathes out, slow, then turns to you. His entire frame eases, and he's smiling without knowing it. He clears his throat.

    *if eric_harmony > 50
        "I think I know what to do. For myself. For everyone."
    *else
        "I think I know what to do. For myself. For everyone who's been standing with me."

    He leads you to the low stone wall at the edge of the courtyard. He lowers himself slowly onto the stone, and you join him.

    You look at the grass. Thin, browning, but it's still grass. You rarely see grass.

    Eric doesn't say anything, and neither do you. No need for words.

    The morning sun touches your face. It feels warm.

*set eric_friendship +3
*return