*label scene_introduction
*if danny_subplot_scene = 1
    Danny's easy to find online: dozens of forum posts analysing his philosophy, video clips with thousands of views, fan comments full of dragon emojis. But his physical presence is a different story. No contact information, no known gym affiliation, no way to reach the man behind the legend. If there's any way to reach Danny "The Dragon" Chan, it will involve your contacts in the scene.
    *if (danny_almost_lapsed)

        Your leads are freshest right after the fight. Wait too long, and Danny's trail will go cold.
*elseif danny_subplot_scene = 2
    *if danny_plot_timer = 0
        Coach Lam handed you a piece of paper. Neatly folded, edges sharp. "Kowloon Park, Chinese Garden. Morning." No signature. Lam shrugged, saying, "Could be Danny. Could be someone else doing exercise in a yellow tracksuit. Your call."
        *if (danny_almost_lapsed)

            You have a time and a place. If you don't show up, you'll never find out if it's Danny.
    *else
        *if (danny_investigation_success)
            Your investigation at Pak Tin community centre paid off: booking records showing "Chan", locals who've seen someone in a yellow tracksuit, tai chi practitioners and fruit stall vendors describing a polite man. It's strong evidence of Danny's presence. But Danny himself remains out of reach. Returning now would cross the line from curiosity into stalking.
        *else
            Your investigation at Pak Tin community centre offered some tantalising clues: booking records showing a "Chan", a local who thinks she saw someone in a yellow tracksuit, fragments of a morning exercise routine. But each lead turned out to be inconclusive. Danny remains out of reach.
            *if danny_plot_timer = 2
                It's not something you can rush. Returning now would cross the line from curiosity into stalking.
            *else
                You've done all that you can. What happens next isn't up to you.
*elseif danny_subplot_scene = 3
    *if danny_plot_timer = 0
        Danny invited you out for dinner. It's at a claypot rice stall in Yau Ma Tei. You recall it's a famous one, known for the quality of its crispy rice crust.
        *if (danny_almost_lapsed)

            Danny doesn't invite people to dinner often. If you don't make time for him, he'll assume you're not interested.
    *else
        Danny's gently turning down offers to meet up again. He says only, "Needs time to cook."
*elseif danny_subplot_scene = 4
    *if danny_plot_timer = 0
        It's been a while since you've heard from Danny. But now: "Rehearsal in Lai Chi Kok. Casual. Want to come?"
        *if (danny_almost_lapsed)

            Danny doesn't invite people to rehearsals often. If you don't make time for him, he'll assume you're not interested.
    *else
        You get the pattern: Danny doesn't accept offers to meet up, he moves on his own schedule. So you wait.
*elseif danny_subplot_scene = 5
    *if ((current_month = end_month) and (danny_plot_timer = 0))
        A message from Danny, coming out of nowhere: "Would like to see you. An arcade?"
    *else
        Danny's been quiet, doing his own thing. You give him the space he needs.
*elseif danny_subplot_scene = 6
    Danny's told you that he'll be in jail soon. You hope to see him again, sometime.
*else
    *bug Danny subplot scene not found
*return

*comment danny_friendship from danny_fight: 0 to 4
*label scene_choice
*if danny_subplot_scene = 1
    *comment earliest: chapter 4, first fortnight
    *comment danny_friendship from this chapter: 0 for accept, 0 for reject
    *comment cumulative danny_friendship after this chapter: 0 to 4
    *gosub event_1
    *set stat_mental %+3
    *set stat_energy +5
    *gosub_scene utils clamp_energy
    *comment danny_plot_timer is set to either 2 or 3 based on the investigation result
*elseif danny_subplot_scene = 2
    *comment earliest: chapter 5, first fortnight
    *comment danny_friendship from this chapter: 2-4
    *comment cumulative danny_friendship after this chapter: 2-8
    *gosub event_2
    *set stat_mental %+3
    *set stat_energy +5
    *gosub_scene utils clamp_energy
    *set boxing_insights_unspent +1
    *set danny_plot_timer 2
*elseif danny_subplot_scene = 3
    *comment earliest: chapter 6, first fortnight
    *comment danny_friendship from afterhours: 0-4
    *comment danny_friendship from this chapter: 1-4
    *comment cumulative danny_friendship after this chapter: 3-12 + afterhours 0-4 = 3-16
    *gosub event_3
    *set unlocked_danny_training true
    *set danny_plot_timer 3
*elseif danny_subplot_scene = 4
    *comment earliest: chapter 7, second fortnight
    *comment danny_friendship from this chapter: 2-4
    *comment cumulative danny_friendship after this chapter: 5-16 + afterhours 0-4 = 5-20
    *gosub event_4
    *set stat_energy +10
    *gosub_scene utils clamp_energy
    *set stat_mental %+5
    *set danny_plot_timer 2
*elseif danny_subplot_scene = 5
    *comment earliest: December
    *comment danny_friendship from this chapter: 2-4
    *comment cumulative danny_friendship after this chapter: 7-20 + afterhours 0-4 = 7-24
    *gosub event_5
    *set stat_mental %+10
    *set stat_energy +25
    *gosub_scene utils clamp_energy
    *set danny_plot_timer 10000
*else
    *bug Danny subplot scene not found
*return

*label event_1
*temp minutes_passed 0
*temp info_gathered 0
MK Fight is busy tonight. The scent of sweat, leather, and Tiger Balm lingers in the air, accompanied by the sound of gloves and shins on heavy bags. You spot one of the regulars cooling down, a large, muscular guy who always brings a small pile of Japanese rice balls with him. You wait for him to finish his stretches and approach.

"Danny Chan?" He stands up straight and loosens his shoulders. "The Bruce Lee guy? I've heard about him, but he's never trained here."

He leans in slightly. "Heard he trains somewhere in Sham Shui Po." His eyes scan for familiar faces in the gym. "Hey, Eunice! Where does that yellow tracksuit guy train now?"

A tall woman, now wearing thick glasses after removing her contact lenses, wipes her mouth with the back of her hand. "Some community centre in Sham Shui Po, I think? Or maybe it was a sports ground. No, it was renovated just last year. Wait, actually, I think I've gotten that backwards. Pretty sure it's a community centre now."

"Early mornings. Tuesdays. Or Thursdays. Tuesdays and Thursdays just blend together, you know?" She shrugs and reaches for her water bottle. "Or maybe it alternates?"

You don't interrupt. You just remember the information, chaotic as it is.

The muscular guy nods. "Kelvin said the same. But he thought it was an outdoor park, not a community centre."

Eunice frowns. "No, Auntie Ng insisted it was a community centre. True, she's not the most reliable one. Her tofu pudding is great though."

Sham Shui Po. A community centre, maybe Tuesdays. Or Thursdays.

*choice
    #Head to Sham Shui Po early on Tuesday to investigate.
        Have to start somewhere. You set your alarm for 5am. Should provide enough time to scout the community centres and maybe catch the breakfast crowd. Someone practising Jeet Kune Do in a yellow tracksuit at dawn should be fairly conspicuous.

        You thank them for the lead and return to your stretches. Ankles still tight. Hamstrings need work too.

    #Let it go. This is too vague to chase.
        Are you sure you want to stop looking for Danny?
        *choice
            #Yes.
                *set danny_subplot_status "rejected"

                Unreliable gossip about someone who might be training somewhere in Sham Shui Po isn't worth losing sleep over. If Danny wanted to be found, he would have contacted you.

                You thank them for the information and return to your stretches.
                *return
            #No. [i](Continue to investigate.)[/i]
                Have to start somewhere. You set your alarm for 5am. Should provide enough time to scout the community centres and maybe catch the breakfast crowd. Someone practising Jeet Kune Do in a yellow tracksuit at dawn should be fairly conspicuous.

                You thank them for the lead and return to your stretches. Ankles still tight. Hamstrings need work too.

*page_break
You breathe in the smell of coconut milk and diesel exhaust. There's no rush in Sham Shui Po, unlike in the downtown areas. Here, only the leisurely rhythm of people preparing for another long day. You pass by a dessert shop window, misty with condensation. Trays of red bean soup and mango pudding peek out from behind the glass, resting in their large metal trays.

The Pak Tin community complex rises ahead, harsh green and white metal panels reflecting the morning light, flanked by ageing public housing blocks, laundry strung outside their windows.

Inside, past the entrance doors, the main hall opens into a large, empty space, with high ceilings, waxed wooden floors, and lime-green plastic chairs stacked along the walls. Overhead lights bathe the space in a white fluorescent brightness. At the far end of the hall, there's a raised stage framed by heavy velvet curtains.

No one in a yellow tracksuit. No one practising Jeet Kune Do or tai chi. No one here at all, in fact.

So far, you haven't found any traces of Danny.

*choice
    #Study the hall, looking for evidence of Danny.
        *gosub_scene utils increase_analysis
        You sweep your eyes over the room. The floor is waxed and polished, and there are no scratches that would suggest martial arts practice. You scrutinise the green plastic chairs stacked against the wall. In one section, the chairs are pulled out more often, the floor wax worn away. Group exercises of some sort occur here regularly, though it's unclear whether Danny is involved.

    #Feel the mood in the main hall.
        *gosub_scene utils increase_empathy
        The fluorescent lights are on, fighting with the early morning sunlight. A harsh atmosphere. The green plastic chairs, the waxed wooden floor, the faint antiseptic smell — these would belong anywhere, in community centres, in elderly care homes, in school assembly halls.

    #Absorb the silence. Expect nothing.
        *gosub_scene utils increase_composure
        The fluorescent lighting throws the court lines on the floor into sharp relief. Badminton in blue, basketball in red, some sport you don't recognise in green. You stand at the centre, where all the lines meet. You inhale the filtered air. Nothing comes to mind. Danny trains here, or he doesn't.

Here in this building or in the streets nearby, you might find more clues. The residue of daily routines, the small details only apparent to those who've spent years in the neighbourhood. Several angles seem promising: the building staff who might know the regulars, or the shopkeepers and early morning exercisers. You could gather your thoughts, see if you missed anything in this sterile building. An hour to ask the right questions — if you know what they are.
*label search_carousel

*if minutes_passed >= 60
    *goto carousel_finished
*elseif minutes_passed <= 9
    It's 7:0${minutes_passed}am.
*else
    It's 7:${minutes_passed}am.
You'll need to leave at 8:00am to reach work on time.

*choice
    *hide_reuse #Ask building staff about anyone practising martial arts.
        The reception desk is staffed by a disinterested middle-aged man in a rumpled uniform who yawns and dismisses your questions. "No, nothing, sorry, bye bye." He stares blankly at the wall behind you.

        A janitor in a Baguio vest overhears you and pauses her mopping. "A tai chi group's here every morning at seven." She gestures vaguely at the hallway. "A man wearing a yellow tracksuit? Not sure. There's a polite man who books the hall early sometimes. Good man, comes alone, cleans up after himself."

        At the counter, you find a clerk who helps you look up the booking in the computer system. "Here we are. Private booking under the name [i]Chan[/i]. Last Thursday at 9am." He shrugs.

        "He used to stay longer," the janitor comments. "Now he leaves after an hour. Doesn't stop to chat any more."

        She returns to her mopping.

        *if highest_trait = "analysis"
            Chan. Common name. By itself, not very useful. But the time and date match. A potential connection. Spending less time here suggests change of some sort. Maybe a busier schedule, maybe caution.
        *elseif highest_trait = "composure"
            Chan. Common name. By itself, not very useful. But the routine changed. That's all you know. No point guessing why.
        *elseif highest_trait = "empathy"
            Chan. Common name. By itself, not very useful. But the janitor sounded sad when she told you about his reduced hours.
        *else
            *bug Invalid highest trait
        *set info_gathered +2
        *set minutes_passed +10
        *goto search_carousel
    *hide_reuse #Examine bulletin boards and booking schedules.
        *gosub_scene utils increase_analysis
        You peruse the bulletin board. The usual flyers for yoga, tai chi, badminton, and private tutoring. But near the top corner, obscured by a cooking class flyer, is a weekly printout for hall bookings. You focus on one entry that repeats every Tuesday and Thursday: "Private booking — 9:00am to 10:00am — no course listed."

        *if highest_trait = "analysis"
            It's not proof. But it fits with the picture you're assembling.
            *set info_gathered +2
        *else
            It's not proof. But at least it's consistent with the rest of your knowledge.
            *set info_gathered +1
        *set minutes_passed +10
        *goto search_carousel
    *hide_reuse #Walk outside and chat with the tai chi practitioners and joggers at the park.
        *gosub_scene utils increase_empathy
        Outside, seniors move through a slow tai chi exercise on the basketball court. An elderly instructor leads the group, calling out poetic instructions: cloud hands, single whip. Their silent movements seem to create gentle currents in the morning air. You wait for them to finish and then approach.

        "Yellow tracksuit?" A woman in a plain cotton T-shirt considers your description. "I do see someone like that sometimes. I'm pretty sure he wears yellow tracksuit bottoms, at least." She turns to a man who's adjusting his wire-rimmed glasses. "You remember? The serious young man?"

        He nods. "Very polite man. Always walks into the community centre alone. Stands tall, back straight. Never seen him checking his phone, not even once."

        They smile at you and pick up their tai chi swords, and you bow slightly, watching them return to their practice.
        *if highest_trait = "empathy"
            *set info_gathered +3
        *else
            *set info_gathered +2
        *set minutes_passed +20
        *goto search_carousel
    *hide_reuse *if (minutes_passed >= 10) #Make small talk with the fruit and congee vendors.
        *gosub_scene utils increase_empathy
        The congee stall owner barely looks up from her massive pot, as steam rises up from it, obscuring her face. "Yellow tracksuit? Maybe. Hard to remember everyone. Do you want congee or not?" She adds raw beef slices to a bowl, then ladles the thick rice porridge over them.

        The fruit vendor is more talkative. "The Bruce Lee guy? Comes by sometimes. Same thing every time: one apple, one orange. Pays with exact change."

        He performs a Jeet Kune Do side-step, hands down by his hips, bouncing from one foot to the other. "Very polite but doesn't like to chat."

        "When does he arrive?" you ask.

        "Early morning. Sometimes he comes twice a week, but sometimes I don't see him for an entire month." He offers you a mango.

        You buy an apple and an orange instead. Exact change.

        *if highest_trait = "empathy"
            As you hand over the cash, he leans in. "There's something strange about him though. Looks like he's always expecting bad news. Always ready for the worst. You know what I mean?"

            He adds, "One time, he took a call. Listened for a long time. Then he just replied, 'Okay'. Stood there. I stopped moving too."

            He glances around, then straightens up.
        *else
            As you hand over the cash, he adds, "He always looks at the sky before he leaves."

        Someone coming early, alone. Pays with exact change. Doesn't make small talk. You thank the vendor, and head back to the community centre.
        *if highest_trait = "empathy"
            *set info_gathered +3
        *else
            *set info_gathered +2
        *set minutes_passed +15
        *goto search_carousel
    *hide_reuse *if (minutes_passed >= 30) #Wait by the doors. Observe the clientele.
        You find a spot by the entrance and settle into a green plastic chair. The morning traffic passes by: women with yoga mats, a janitor wheeling cleaning supplies, a pair of badminton players. Outside, children in school uniforms, shouldering huge backpacks.

        No one in a yellow tracksuit. A few people in athletic gear, but they take the stairs up to the basketball courts. They queue, they check boxes, they submit registration forms.

        Ten minutes pass. Still no yellow tracksuit. It's all just sports gear and school uniforms.

        *set minutes_passed +10
        *if (minutes_passed >= 50)
            You check your phone. Time to leave soon.
        *else
            You check your phone. Time to try something else.
        *goto search_carousel
    *hide_reuse *if (minutes_passed >= 30) #Sit quietly. Consider why Danny might practise here.
        *gosub_scene utils increase_composure
        You find a chair near the wall and observe the morning activity. Early risers, getting in their exercise before the day's work. Maintenance staff pushing a large cart. The PA system with its garbled announcements.

        If Danny is indeed here, what would attract him to this place? Maybe because it doesn't demand anything from him. A place where he can be Danny Chan, not "The Dragon."

        Any community centre would do. But this one is in the heart of working-class Sham Shui Po. Even if he were to be recognised by others, they would give him his space.
        *if highest_trait = "composure"
            You understand the appeal.
            *set info_gathered +2
        *else
            *set info_gathered +1
        *set minutes_passed +10
        *goto search_carousel

*label carousel_finished
*page_break
The booking terminal is still looping. Outside, commuters queue for double-decker buses and MTR trains, a mass of bodies that moves as one. It's 8:00am.

*comment Possible range is 7 to 12
*if info_gathered <= 8
    *set danny_plot_timer 3
    *set danny_investigation_success false
    You didn't find conclusive proof of Danny's whereabouts. Just a handful of fragments: a "Chan" on the booking sheet, some unreliable secondhand accounts, the vague outlines of a routine. Weak signals.
*else
    *set danny_plot_timer 2
    *set danny_investigation_success true
    You didn't find proof of Danny's whereabouts. But the pattern is unmistakable: regular morning bookings, multiple mentions of a polite man, secondhand stories. All of it fits together. Danny. Probably.

You sit for a while longer. There doesn't seem to be anything further to do.

Eventually, you stand. Outside again, into the exhaust fumes, the steam from the breakfast stalls, the press of the crowd. As you reach the MTR escalator, your reflection stares back at you from a glass panel.

The train arrives. You step on.
*set danny_investigated true
*return

*label event_2
You emerge from Tsim Sha Tsui MTR at Exit A1 into the early morning air. The mosque on Nathan Road emits a faint call to prayer, already drowned out by the rumble of traffic. You turn onto Haiphong Road, where the electronics shops are hidden behind steel shutters at this hour, and pass a gaunt elderly woman struggling with a huge pushcart stacked high with dirty cardboard. You step around her without slowing down.

The traffic fades as you continue past the congee vendors, with only the occasional delivery truck trudging down this smaller street. You enter Kowloon Park at the side entrance, where the stone wall gives way to a sloped expanse of asphalt and wet earth. The trill of a songbird comes from somewhere ahead. The city noise has faded entirely. Around the bend: a dozen white-haired enthusiasts, absorbed in tai chi, wushu, or dance.

And there, you see him. Seated on the long stone bench by the moss-covered pond, in a simple black cotton shirt and trousers, straight and motionless.

*page_break
Danny sees you and stands. You're unsure what to do — go for a handshake? Bow slightly? You settle for a small nod. Danny gestures to the bench, and you both sit down, silently watching the morning exercisers perform their tai chi routines.

Danny quietly watches the group perform graceful circular movements. You stay seated beside him, hands on your lap, patiently taking in the scene.

Minutes pass. One of the tai chi aunties wobbles in her crane stance. Danny rises smoothly and adjusts her form with a gentle touch at her shoulder. She smiles at him and mouths a silent thanks. Danny returns and sits down next to you.

The group finish their routine, hands resting at their sides. Some of them nod or wave to Danny. Then they collect their water bottles and towels, dispersing quietly, leaving the Chinese Garden to you, Danny, and an elderly man with a songbird in a bamboo cage. Danny continues to sit in silence, gazing straight ahead.

*choice
    #Comment on the peaceful atmosphere here.
        "This place is very peaceful," you say.

        Danny nods and extends his hand, palm up, towards the elderly man. "The birdsong is pleasant."

        Both of you settle into a comfortable silence. After a while, Danny speaks. 

    #Wait for Danny to speak.
        *set danny_friendship +1
        You remain quiet.

        Danny extends his hand, palm up, towards the elderly man. "The birdsong is pleasant."

        Both of you settle into a comfortable silence. After a while, Danny speaks.

"${first_name}. When people seek me out, usually they want a curiosity. That's not right for me. I just want to train."

He stands up and motions at the path to the Sculpture Walk. You walk at a relaxed pace, passing by the outdoor amphitheatre, the picnic lawn where the sprinklers catch you both in a fine mist, enjoying the silence. Upon your arrival, you see a group of younger fighters practising some form of wushu. One of them nods at Danny and salutes him, fist over palm, which Danny returns respectfully.

Danny stands at the edge of the practice area and continues quietly. "I don't mind being recognised within the underground fighting circuit. But I don't want that in my personal life. Outside the circuit, I'm just another person."

You incline your head. The tai chi group recognised him.

*choice
    #"The tai chi group seemed to know you. Do you come here often?"
        "The tai chi group seemed to know you. Do you come here often?"

        "Not every day. Maybe once a week. I learn a lot from just being here."

    #"What do you see when you watch them practise?"
        "What do you see when you watch them practise?"

        Danny thinks for a while before answering. "Repetition."

    #"Why keep a low profile when most fighters seek glory?"
        "Why keep a low profile when most fighters seek glory?"

        "I just want to improve my Jeet Kune Do."

The silence stretches. You let it. After a while, Danny speaks again.

"I was at the civic workshop in Wan Chai when Ah Lam struck up a conversation with me. Your coach. He said you were looking for me, that you actually went to Sham Shui Po and politely asked around. Vouched for your character. So I said, since you think highly of ${him}, I'd like to meet ${him} properly."

He turns to you. "${first_name}, I enjoy your company. But I can't offer you anything. I don't win fights. I can't teach you how to win. And I don't think training Jeet Kune Do with me would improve your boxing."

*choice
    #Consider why Danny would meet you, if he won't train with you.
        *gosub_scene utils increase_analysis
        You analyse the sequence: your initial fight, your investigation in Sham Shui Po, his message passed through intermediaries, his explanation and refusal. You notice that he took the initiative to reach out, yet now he's shutting you down pre-emptively.

    #Accept Danny's conviction.
        *gosub_scene utils increase_composure
        You notice his posture, his expression. No change from baseline. He won't be easily swayed from his decision.

        No matter. There are other reasons to know someone. Now to discover what they might be.

    #Understand what lies behind Danny's refusal.
        *gosub_scene utils increase_empathy
        He doesn't seem apologetic or regretful. He really believes that training you wouldn't be right. Why he believes that, you don't know.

Danny doesn't say anything further. He sits alongside you, on the stone bench, continuing to take in the morning scene.

A procession of two dozen middle-aged women, most wearing silk scarves and colourful tracksuits, parades into the clearing. The leader sets down a wheeled speaker the size of a carry-on suitcase and assembles the group into formation. As they begin a [i]dama[/i] dance, the speaker fills the air with cheerful pop music. The tai chi practitioners give them a resigned look and relocate elsewhere.

Danny stands up and quietly walks along the path. You follow him towards the fitness stations, matching his pace. Behind you, the music fades.

You find a low stone ledge and you both sit down. The air is damp and earthy here, near the lotus pond, and irregular squeaks reach your ears from the elderly man at the leg press station.

Danny draws your attention to a few middle-aged health enthusiasts at the reflexology track. It's a narrow concrete path embedded with irregular stone pebbles, each about the size of a walnut. Each person takes off their shoes and walks gingerly along the pebbles, wincing from the pain. Danny observes, "The pebbles dig into the soles of your feet. It hurts every time."

Slight pause. "They keep on walking every day."

*choice
    #Comment on the persistence of the reflexology enthusiasts.
        *set danny_friendship +1
        You say to Danny that if they've been walking every day, it sure doesn't look like it gets easier. A smile plays across Danny's lips.

        "That is true."

    #Question why they choose this discomforting form of therapy.
        You say to Danny that these people don't look like they are having fun. Surely, they could find some other therapeutic method that is more pleasant. Danny is silent, eyes looking straight ahead. He breathes out slowly. Then he replies, "Yes, they could."

    #Thank Danny, then watch in silence.
        *set danny_friendship +1
        You thank Danny for his observation, then continue to watch the walkers. Some of them place their feet one ahead of the other, slowly shifting their weight. Others power through at a regular walking pace, grimacing as they do so. Danny glances at you, and the briefest smile plays across his lips.

Danny stands to leave, then pauses. "Good to meet you properly, ${first_name}. Until next time."

You nod, seated, and watch him walk towards the main path. He doesn't look back.

The sun climbs higher into the sky, warming your face. You absently watch the exercisers, as you replay the conversation with Danny.

A young, athletic man enters the fitness area at a rapid jog, sweaty from his run. Setting down his plastic hip flask, he moves directly to the pull-up bar and pumps out five rapid pull-ups. Taking a few breaths, he transitions to the incline sit-up bench and cranks out twenty sit-ups.

[i]Only later will you notice: a Boxing Insight had taken shape, on its own.[/i]
*set danny_friendship +2
*return

*label event_3
*temp rice_choice 0
*comment 1 = sausage, 2 = chicken, 3 = vegetarian
*temp temperature_adj ""
*temp beer_drinkers_clothing ""
*if current_season = "summer"
    *set temperature_adj "hot"
    *set beer_drinkers_clothing "white singlets"
*elseif current_season = "winter"
    *set temperature_adj "cool"
    *set beer_drinkers_clothing "stained overalls"
*else
    *set temperature_adj "warm"
    *set beer_drinkers_clothing "long-sleeved T-shirts"
The address Danny gave you is on Temple Street in Yau Ma Tei, not the Night Market tourist section, but the part with the residential towers. It's only a single stop away from your Mong Kok flat, so you walk over. The air is ${temperature_adj} this Saturday afternoon, the rain stopping and starting, spattering onto pavement and vehicles and asphalt. For once, no car horns blaring.

In a few minutes you arrive at the restaurant. Large red characters are painted across the facade, sheltering wide windows over mosaic tile and an entrance with no door. Inside, there's space for around thirty. Half the tables are occupied: elderly couples, a family of four. A grimy analogue wall clock reads 4:55. Along the back wall, a row of charcoal stoves, clay pots stacked beside them in columns of five or six.

Danny already has a seat at the long raised table in front of the charcoal stoves. He's seated on a small round plastic stool, the red stackable kind. He gestures to the one beside him. You greet him — just a nod — and sit down, side by side, facing the cooking area. Only four clay pots are on the stove right now. Wide and shallow, with glazed lids that rattle slightly, wisps of steam carrying the fragrance of fresh rice and meats.

There are plastic menu cards scattered on the table. Two choices for the claypot rice, and the usual drink list. The first choice is the double Chinese sausage rice: regular [i]lap cheong[/i] and [i]yun cheong[/i], the kind with duck liver. Otherwise it's the chicken mid-joint wings, served with [i]choi sum[/i].

Danny says, "I'll have what you have. It doesn't matter."

*choice
    #Order the [i]lap cheong[/i] and [i]yun cheong[/i] claypot rice.
        *set rice_choice 1
        You call out your choice to the cook behind the stove, a thick-armed man with greying sideburns, who grunts at you. The cook looks over at Danny, who nods. "Same for me, Lok."

    #Order the chicken mid-joint wings claypot rice.
        *set rice_choice 2
        You call out your choice to the cook behind the stove, a thick-armed man with greying sideburns, who grunts at you. The cook looks over at Danny, who nods. "Same for me, Lok."

    #Ask if there's a vegetarian option.
        *set rice_choice 3
        You ask the cook, a thick-armed man with greying sideburns, if there's anything vegetarian. He grunts at you.

        "Could make one with mushroom. Same price."

        You agree, and he looks over at Danny, who nods. "Same for me, Lok."

Lok lifts two clay pots from the stove, setting them on the metal counter, then taps a brass bell. Seconds later, a lanky server with short sleeves grabs a clay pot in each hand and weaves through the chairs and tables to a corner booth.

*if highest_trait = "analysis"
    He pulls two empty clay pots from a stack and sticks thin slips of paper on them, oily thumbprints seeping into the order tickets. "That's ours," says Danny, pointing at them. He says it like this is a familiar routine. The cook recognised him, barely needed any words.
*elseif highest_trait = "composure"
    He pulls two empty clay pots from a stack and sticks thin slips of paper on them, oily thumbprints seeping into the order tickets. "That's ours," says Danny, pointing at them. His voice is steady.
*elseif highest_trait = "empathy"
    He pulls two empty clay pots from a stack and sticks thin slips of paper on them, oily thumbprints seeping into the order tickets. "That's ours," says Danny, pointing at them. He says it softly.
*else
    *bug Invalid highest_trait

Lok flicks a splash of oil into each pot with a small ladle and adds a scoop of raw rice. Next, a pour of broth from a dented steel pot on the prep table behind him. @{rice_choice [i]Lap cheong[/i] and [i]yun cheong[/i] follow, sliced diagonally into thin oval strips, and a single piece of cured pork belly.|Chicken wings follow, round balls with two bones protruding on the sides, and then sliced mushrooms.|Sliced mushrooms follow, then a generous portion of [i]choi sum[/i].} He covers the clay pots with charred ceramic lids, and sets them over the charcoal.

*if highest_trait = "analysis"
    Danny's gaze is fixed on the pots. He was tracking everything Lok did, looking at how he layered the ingredients, how he closed the lid.
*elseif highest_trait = "composure"
    Danny's gaze is fixed on the pots. He's waiting, but not impatient. It puts you at ease.
*elseif highest_trait = "empathy"
    Danny's gaze is fixed on the pots. Like his attention is somewhere deeper than the pots themselves.
*else
    *bug Invalid highest_trait

*page_break
With little else to occupy you, you watch the pots too, seeing the charcoal glow orange-red, the coals crusted with white ash at the edges, air distorting around the bottoms of the clay pots.

Around you, diners hunch over their food, chopsticks and spoons working steadily. A young couple settles their bill at the counter, the [i]doot[/i] of their Octopus card cutting through the background din. A line has formed at the entrance, half a dozen people deep, spilling out onto the pavement. Four men at a corner table, all of them in ${beer_drinkers_clothing}, down glasses of Blue Girl beer, refilling from a shared pitcher. A man steps outside with a cigarette between his lips, lighter already flicking.

Next to you, Danny's motionless, his gaze resting on the clay pots. You pull your phone out of your pocket by habit, and you've already swiped up before you catch yourself. You slip it back in.

*choice
    #Danny feels slightly off-beat with the rest of the room.
        *gosub_scene utils increase_empathy
        You're waiting for your rice. Fidgeting, leg bouncing, attention flitting from table to table. Danny is waiting too, but he hasn't moved a muscle.

        A man two tables away barks loudly into his phone, berating someone. You flinch a bit.

    #Everyone else is moving. Danny isn't.
        *gosub_scene utils increase_composure
        *set danny_friendship +1
        Everyone else here is spread out, elbows wide, backpacks and handbags claiming space. Danny's just sitting straight. Looking straight ahead, hands on his lap.

        The waiters rush everywhere, but they tuck in their trays as they pass behind Danny. The woman next to him keeps her chopsticks on her side.

    #It's hard to understand his attention to the clay pots.
        *gosub_scene utils increase_analysis
        *set danny_friendship +1
        Danny is just staring at the clay pots. You follow the line of his gaze. Is he studying the pattern of the charcoal fire? Maybe some kind of rhythm or sound? Nothing fits.

        You consider how his body rises and falls, slowly, with each breath. It's so steady.

        You feel like you're still missing something.

The clay pots bubble slowly, clacks sounding out as the lids skip up and settle repeatedly. Lok lifts the lid of one of them, checks inside, and sets it down again. This place feels familiar now. You're hearing things: the workmen complaining about the site supervisor, the scratch of a spoon as a woman scrapes the burnt rice from her pot.

You sense that Danny's also listening to the clay pots. A crackle joins the hissing, as the crust forms at the base. Steam escapes with a hiss.

Your legs feel a bit heavy. You shift your weight, then walk over to the plastic carboy and draw two cups of water. Danny thanks you.

"They cook the rice from raw," he says.

*choice
    #Consider that this place suits Danny.
        *gosub_scene utils increase_composure
        *set danny_friendship +1
        Your legs are heavy from sitting so long. But now, it anchors you. It makes it easy to just sit, and notice.

        "They cook the rice from raw," he said. That's the right thing to say here.
    #Observe that Danny's still just sitting there.
        *gosub_scene utils increase_empathy
        You hear the rough Cantonese around you, the bright clink of a dropped spoon. Danny doesn't seem to notice any of that. He's just sitting there. You tune into that, too.

        "They cook the rice from raw," he said. It feels disconnected from the scrape of spoons around you.
    #Watch whatever Danny's watching.
        *gosub_scene utils increase_analysis
        You watch the clay pots the way Danny's doing. Tracking the small changes in the sound of the crackles, feeling the heat rising from the charcoal. Your legs are heavy from sitting so long.

        "They cook the rice from raw," he said.

The clay pots continue to bubble. The cook cracks the lid, stirs once, closes it again.
*page_break

You're hungry.

You watch the pots, crackling and popping. Lok lifts the lid again. The fragrance blooms, deeper now, with bitter hints of @{rice_choice caramelised meat, soy sauce, ginger|caramelised meat, soy sauce, ginger|scorched mushroom, soy sauce, ginger}.

You blink, straighten. Danny is watching you, his gaze steady. Not searching for anything in particular. Just observing, for now.

There's a bead of sweat right between your nose and your upper lip. You can feel it accumulating, tiny traces of sweat pooling into a droplet. You're tempted to lick it away, but you resist.

You turn back to the clay pots. The air shimmers as heat licks at the ceramic. The voices in the background seem distant. The aroma of @{rice_choice cured meat|fresh chicken|fresh mushroom} escapes through the rattling lid.

Lok lifts the lids, a small cloud of steam rising as he does so, and he stirs the rice once more. Sets the lid back firmly.

"Almost," he says to Danny. Danny says nothing. He's been watching the clay pots the entire time.

*page_break
The cook takes the clay pots off the stove, and the waiter carries them over, one in each hand, the clay sizzling with heat. He removes the lids with a flourish. Steam billows. The fragrance hits you: @{rice_choice aromas of pork, liver, fat,|steamed chicken skin, mushroom umami,|mushroom umami, soy, ginger,} the smoke of charred rice crusted around the pot. A plastic dish of sweet soy sauce arrives alongside.

Hunger hits you all at once. But you don't dive in. First, you pour the sweet soy sauce, swirling it over the @{rice_choice meat|meat|mushrooms}. Tiny wet spheres cling to the @{rice_choice sausage slices|chicken skin|mushroom slices}, the rest quickly absorbed into the rice, turning it a glossy brown.

You brush aside the @{rice_choice sausage|chicken|mushrooms} with your metal spoon, instead scooping up a mouthful of rice, not the crust, just the soft sauce-darkened rice. You raise it to your mouth, put it in, roll it around. @{rice_choice Pork, liver, fat|Chicken, mushroom umami, broth|Mushroom, soy, broth}, absorbed through an hour over charcoal.

You chew it slowly.

For the next spoonful, you add @{rice_choice a slice of [i]yun cheong[/i]|a mouthful of chicken, bones removed|a slice of mushroom}. It's hot, fresh, fragrant, and chewy, and pairs perfectly with the seasoned rice. Then you scrape the crust off the edges of the clay pot. It's crispy, charred, almost crunchy. This mouthful breaks apart pleasantly, but then it sticks to your teeth, and the oil coats your tongue, a bit too heavy.

Danny eats his rice with his eyes closed partway. He says nothing.

The mouthfeel of @{rice_choice lard|cooking oil|cooking oil}. The scent of @{rice_choice half-melted pork fat|chicken and mushroom|mushroom}, and the burnt notes of the rice crust. You savour it.

*page_break
Your clay pot is almost empty now. The only things left are the stubborn crust welded to the pot by black char and @{rice_choice a strip of pork fat|a few chicken bones and vegetable scraps|a folded leaf of [i]choi sum[/i]}. You can still taste the fragrant rice flavoured with broth, the @{rice_choice chewy, fatty sausage|silky chicken and tender [i]choi sum[/i]|juicy mushroom and tender [i]choi sum[/i]}, the crunchy crust, more burnt than caramelised.

Danny's already finished his. He rises, and you follow. At the register, he pays for both of you, exact change. "You can get the next one," he says.

You walk out onto the narrow path outside the restaurant. A line of people crowds the pavement, the queue reaching the shuttered shopfront beside it. It's only early evening, but it's quiet now. No cars passing by. You can still smell the burnt rice wafting out from the restaurant.

You're refreshed,
*if highest_trait = "analysis"
    more than food alone could account for.
*elseif highest_trait = "composure"
    disproportionately so.
*elseif highest_trait = "empathy"
    like you've slept, not just eaten.
*else
    *bug Invalid highest_trait
Both of you stand there a moment, looking out at the street. A motorcycle idles at kerbside, then pulls away after its passenger climbs on. Danny shakes your hand. "See you around, ${first_name}."

*set danny_friendship +1
*return

*label event_4
"Having a rehearsal Friday night. Want to come? Casual."

The Lai Chi Kok MTR dumps you out onto Cheung Sha Wan Road, the pavement narrower here, rust-stained buildings crowding in on both sides. You pass an empty mall with a Bitcoin ATM just inside the entrance, its unplugged cord hanging loose. Two streets away is the Great Wall Factory Building. It has the look of a former industrial building repurposed as a regular tower block, cracked pink paint and a grid of air-conditioning units on the exterior.

You enter at the ground floor car park, the air smelling like old cabbage. The hydraulic lift winches you up to the ninth floor, the hallways too wide from the textile factory days. Half the slots in the tenant listing board are blank, but you find the room. One Hour Studio.
*page_break

You knock and ease open the door, the plastic strip along the door bottom wheezing as it scrapes the linoleum. Inside: a single large room, walls encased in soundproofing foam, guitars hanging from wall hooks, a drum set in the centre, electronic keyboard to the side.

A rehearsal studio, but not in the music scenes of Kwun Tong or Mong Kok. Different.

Danny waves to you from near the amps, electric bass slung over his black T-shirt. There are two other bandmates with him, middle-aged men in collared T-shirts and jeans. One is adjusting his electric guitar, the other is tuning his snare drum. They look up and say hello and then turn back to their instruments.

*choice
    #Settle in. See where this impromptu jam session goes.
        *gosub_scene utils increase_composure
        This could be any other band room in the city, stocked with the usual middle-aged uncles. No fuss.

    #Wonder if the bandmates know about "The Dragon".
        *gosub_scene utils increase_analysis
        Danny shows no sign of being "The Dragon" here. He doesn't even seem to be the leader of the group; no one leads, or they all do. And if they know about Danny's fighting career, they don't seem to care.

    #See how Danny and the bandmates interact with each other.
        *gosub_scene utils increase_empathy
        They pass each other cables and equipment without needing to ask. Danny doesn't say much, and it doesn't look like anyone is in charge. Everything's about setting up for the next song, but no one's in a rush.

You drop into a wooden chair near the wall, watching the bandmates tune. Now you notice their equipment: the bass neck worn smooth, the guitar body scratched around the bridge, while the drum set appears to be the venue's house kit. A pair of new drumsticks.

The guitarist says you can sit out the first song, and then cracks a smile at the drummer. "Okay, let's start with Stephen's favourite. One... two..."
*page_break

The song starts on three with a reedy guitar note, ascending the scale, and the drums and bass join in. Slow, easy, not particularly tight. The guitar continues its leisurely progression, drums coming in a bit too enthusiastically.

You recognise the song after a few seconds. 《光輝歲月》 — Glorious Years, by Beyond. Danny anchors the drift, slow and steady, one note per measure. The bass isn't loud, but it fills the space.

The guitarist sings the chorus. A high-pitched squeal kicks in from the amps on the last syllable. He nudges his microphone down, a muffled thud punching from the amps as he catches the mic head, and the audio feedback dissipates.

Danny smiles as he holds the bassline.

*choice
    #Notice how they regard you.
        There's no judgement in their eyes, just looseness, easy expressions, smiles. You're Danny's friend, coming along with them to play some songs together.

    #Look at the bandmates more closely.
        Old jeans, plain shirts, a concerning lack of hair. They're not flashy rockers. They don't even look like musicians. More like the kind of uncle you'd see at the municipal cooked food centre.

    #Consider the vibe.
        What hits you most is how quiet it is. Even without the soundproofing, this band wouldn't make enough of a racket to disturb anyone. It feels like a group of old uncles at early morning [i]yum cha[/i].

The song winds down, instruments bowing out as the vocals trail off, and then the guitarist clears his throat, too close to the microphone. The three of them smile at each other. Danny hands you a pair of small marching cymbals, brass, maybe eight inches in diameter. He says to clash them together when it feels right.

You wonder when it would feel right. You don't worry about it too much.

The drummer picks the next song: 《半斤八兩》. Familiar, whimsical, the classic working-class anthem. Danny takes the backing vocals this time.

The second verse is ending and the chorus is coming up. Clash your cymbals?

*choice
    #Clang them together.
        *set danny_friendship +1
        You clash the brass cymbals, the faces bouncing off each other. The sound is bright, brassy, and loud, overpowering the verse, even though it was just a light tap. It arrives in the gap between the verse and the chorus, too early yet also too late.

        The drummer looks at you for a fraction of a second, then he's already back to the beat.

    #Don't clang them here.
        They continue smoothly into the chorus, now all three of them joining in. The lack of cymbals is unremarked upon. Later. Or never. Either is fine.

The song ends with a guitar solo. It doesn't sound anything like what you remember of the song.

"Great playing, Danny. You always bring it together." The drummer yawns slightly.

Danny accepts with a quiet "mmm".

"Another? Let's do a rock song this time. 《不再猶豫》?"

The drums come in first, a fast rhythm anchored by the heavy kick drum. Then the guitar, driving the tempo, every chord bright. They're smiling.

In no time at all, they're at the guitar solo. His fingers move quickly, surely, the notes clean. He's coming to the end of it. Your hands tighten around the cymbals.

*choice
    #Clang them together.
        *set danny_friendship +1
        CLANG! Too loud. The drummer flinches. But they're back into it without missing a beat, Danny's bass pushing louder. The guitarist flashes you a smile.

    #Don't clang them here.
        A fast-paced rock song is begging for cymbals. But you don't feel like it. You hold still.

They all sing the chorus together, not quite at the same pitch or even in the same key. They're loud, joyfully loud. The song reaches the last chorus, one last crash from the drums, then the vocals trail off, then a last guitar note held until it dies.

The guitarist lifts the strap of the guitar over his head. "I think that's enough for me tonight. Wife expecting me back. Thanks for coming, ${first_name}."

They start packing up. Danny winds up his cable into a tidy loop. You hang your cymbals back onto the wall hook.

Danny turns to you and smiles.

"Thanks for humouring me, ${first_name}. It's good to spend time playing music together."

*if highest_trait = "analysis"
    Only three songs. No rehearsal. Perhaps the most inefficient jam session you've ever been to.

    You don't know why it worked.
*elseif highest_trait = "composure"
    You weren't humouring him, but you don't mention it. You just showed up.

*elseif highest_trait = "empathy"
    Humouring? You were all playing music together, enjoying the moment.

    You want to tell him what this evening means to you, but you don't. Not now.
*else
    *bug Invalid highest_trait

*page_break
*temp temperature ""
*if current_season = "spring"
    *set temperature "cool"
*elseif current_season = "summer"
    *set temperature "humid"
*elseif current_season = "autumn"
    *set temperature "cool"
*elseif current_season = "winter"
    *set temperature "cold"
They stay behind to tidy up. You overhear the drummer say to Danny, "Don't know when we'll see each other again. Let's meet up when we can."

Danny replies, "Yes, when we can."

You take the slow lift down to the car park and walk out into the ${temperature} night air.

*set danny_friendship +2
*return

*label event_5
Danny gave you a shop number in Allied Plaza, on the corner of Nathan and Nullah Road in Prince Edward. The entrance is recessed and easy to miss, between a claw-machine parlour and a shuttered shopfront with to-let signs pasted over other to-let signs. There's a single escalator up, narrow enough that you have to pull your shoulders in, and you need to loop around the whole floor to reach the next one, through a single-file corridor. Every unit is tiny: rare trading cards behind glass, painted figurines, baking supplies, novelty phone cases. It's the early afternoon, before the schools let out, and there isn't a single other person around, neither shopper nor shopkeeper. The air is warm, stuffy, but scentless.

The tightness eases on the third floor, where the corridor gives you room to breathe. You pass by clothes shops, a closed property management office, and then you see the pachinko place. The Formica counter is unattended, and next to it is a ball dispenser, shrieking about members' specials, volume discounts, limited-time promotions.

No one else is here apart from Danny, hunched over one of the machines, knees up on a too-short stool meant for schoolkids. There's a deep tray of white balls on the glass pane in front of him. You nod at him, tap your card — this one's $50 for 200 balls — and wait for the balls to chonk into your tray, one by one. Then you join him at the adjacent machine.

*if highest_trait = "analysis"
    You glance up, above your machine, and see a rectangle of bare plaster on the wall. Probably the signboard of whatever was here before.
*elseif highest_trait = "composure"
    Behind you, the ball dispenser is playing an electronic melody, repeating and repeating. You pay it no heed.
*elseif highest_trait = "empathy"
    There's a haze of artificial white noise emanating from everything here. Too loud for an empty room.
*else
    *bug Invalid highest_trait

Danny turns to you. "${first_name}. Have you been well?"

*fake_choice
    #Say you've been well, and ask how he's been.
        "I've been well, Danny. And you?"

        "Could be better."

    #Comment on the choice of location.
        "This place... it's quite loud."

        He says, "Used to be a dispensary. Had drawers full of dried herbs."

Danny turns back to his game. You take a moment to look at your machine. You need to feed the balls in and pull the plunger to fire one to the top. It then travels down through a field of metal pins to pass through one of the slots at the bottom. A green light on a slot means you win more balls, and sometimes a reward card, redeemable for prizes. There doesn't seem to be any strategy to this.

You start playing. There's a victorious chime when you drop the balls in, and lights flash whenever a ball passes through a lit slot. Your tray dwindles steadily. You repeat the motions, again and again. You look over at Danny. He's feeding his machine carelessly, sometimes jamming in several at once, pulling the plunger and not watching where they land. He hasn't won a single card yet.

He straightens. He turns on the stool, his whole body facing you, the machine forgotten. Now he waits for you.

*choice
    #Tell Danny about how your fighting's been going.
        You tell him about your wins and losses, the unfamiliar venues, the strange mix of opponents. You tell him that you've kept up your training, for almost a year now.

        Danny lets you finish. Then he asks you: "Why do you fight?"

        *choice
            #"To find something real, something different from my office job."
                *set fight_reason "I'm fighting to find something real."
                "To find something real, something different from my office job."

            #"To discover where my limits are, and maybe push them."
                *set fight_reason "I'm fighting to discover where my limits are."
                "To discover where my limits are, and maybe push them."

            #"I'm still figuring that out. But I know this is something I need."
                *set fight_reason "I'm still figuring out why I fight."
                "I'm still figuring that out. But I know this is something I need."

        Danny nods. Without looking away, he pushes a few more white balls into his pachinko machine.

    #Ask Danny what he's been doing.
        *set danny_friendship +1
        "What have you been doing lately, Danny?"

        "Mostly the usual."

He looks at you, unwavering.

*page_break
"Next week, I'll go to jail. Two years."

You freeze. You search his face for any sign of a joke. There isn't one.

"I've been doing this for five years now. I ignored their warnings, so I knew it would happen eventually. Stability maintenance."

*choice
    #Feel what it must be like.
        *gosub_scene utils increase_empathy
        Danny will lose his freedom in a few days, but he's sitting here with you, feeding balls into a machine. Just another day for him. You can't quite follow him that far.
    #Take it calmly, like Danny would.
        *gosub_scene utils increase_composure
        You fix your attention on Danny, the electronic jingles fading into nothing. Two years. You force yourself to sit still.
    #Think about why this would happen.
        *gosub_scene utils increase_analysis
        He ignored their warnings. Once he persisted, it became inevitable. Stability maintenance: you know what that means.

You still have to find out more. "But Danny, what are you charged with?"

"Incitement to incite public nuisance."

He doesn't elaborate.

After a moment, you steady yourself. You ask Danny what he plans to do.

"I'll keep on doing the same thing. Put one foot in front of the other."

*choice
    #Tell him you understand why he won't stop.
        *set danny_friendship +3
        You've only known him briefly, but even so, the news lands hard. Can't imagine what it's like for him. But from what you know of Danny, he was never going to do anything different.

        You tell him this.

        Danny doesn't respond. Or he doesn't seem to. But you know him now. His lips don't smile, but his cheek muscles lift, his eyes soften.

    #Try to think of how to help him.
        *set danny_friendship +1
        You try to think of something that could help Danny. Could you find him a lawyer, or talk to anyone? You come up empty. You apologise to him, saying you wish there were something you could do.

        Danny says he'll be fine, it's what he expected. He'll handle things as they come up.

        "When it's cooked and brought to you, you eat it."

        There was never anything to do.

*if danny_friendship > 12
    "Thank you, ${first_name}. For making the time. Next time, you choose where we meet."
*else
    "Thank you, ${first_name}. For making the time."

*page_break
Danny stands up, preparing to leave. Then he notices his half-full tray, still on the glass pane. He sits back down, hunched on the stool. He's facing the machine, not you.

One by one the white balls trickle in. He pulls the plunger, drops in another handful, pulls again. He ignores the occasional reward cards that spring out. The tray dwindles.

Your own tray is empty, now. You stay, watching him.
*return