*if (stats_screen = "start")
    You're currently unknown in the circuit.
*elseif (stats_screen = "main")
    [b]${first_name} ${last_name}, ${epithet}[/b]
    *line_break
    "${fight_reason}"

    [b]Stats[/b]
    *line_break
    [i]Power:[/i] ${adj_power} current, ${stat_power} at full energy
    *if (stat_power < 15)
        — Basic
    *elseif (stat_power < 25)
        — Developing
    *elseif (stat_power < 35)
        — Skilled
    *else
        — Exceptional
    *line_break
    Raw strength, heavy punches. Powering through resistance.

    [i]Technique: ${adj_technique} current, ${stat_technique} at full energy[/i]
    *if (stat_technique < 15)
        — Basic
    *elseif (stat_technique < 25)
        — Developing
    *elseif (stat_technique < 35)
        — Skilled
    *else
        — Exceptional
    *line_break
    Footwork, timing, evasion. Dodges, slips, parries on defense, exploiting openings on offense.

    [i]Toughness: ${adj_toughness} current, ${stat_toughness} at full energy[/i]
    *if (stat_toughness < 15)
        — Basic
    *elseif (stat_toughness < 25)
        — Developing
    *elseif (stat_toughness < 35)
        — Skilled
    *else
        — Exceptional
    *line_break
    Endurance. Taking hits on your guard and lasting through long exchanges.

    [i]Mental: ${adj_mental} current, ${stat_mental} at full energy[/i]
    *if (stat_mental < 15)
        — Basic
    *elseif (stat_mental < 25)
        — Developing
    *elseif (stat_mental < 35)
        — Skilled
    *else
        — Exceptional
    *line_break
    Awareness, focus, reading opponents. Determines your success at reading and countering opponent actions in combat.

    Each action in a fight tests one or two of these stats. Your energy determines how close your current stats are to their maximum values.

    *gosub_scene utils display_fighting_style

    *if highest_trait_num >= 2
        [b]Outlook[/b]
        *line_break
        *if highest_trait = "analysis"
            You tend to approach situations analytically, looking for structure and patterns. You prefer to map out scenarios before you decide what to do.
        *elseif highest_trait = "composure"
            You're usually in control of your emotions. You rarely panic. You value discipline, and you're comfortable in high pressure situations.
        *elseif highest_trait = "empathy"
            You tend to intuitively sense what others are feeling. You notice subtleties and tells, and you prefer to make decisions based on what feels right.
        *else
            *bug Invalid highest_trait

    [b]Boxing Skills[/b]
    *line_break
    *if jab_level = 0
        ${jab} — A light, fast strike. Can interrupt momentum or maintain distance.
    *elseif jab_level = 1
        ${jab} — A clean, tight strike that probes for weaknesses or interrupts their attack.
    *elseif jab_level = 2
        ${jab} — An accurate, powerful blow. A jab you can throw without thinking.
    *else
        *bug Jab only upgradeable to level 2
    *line_break
    *if flurry_level = 0
        ${flurry} — Charge forward with a flurry of arm punches. Applies pressure, but exhausts you quickly.
    *elseif flurry_level = 1
        ${flurry} — A rapid sequence of strikes. Lands more cleanly than before. Applies pressure and keeps opponents on the defensive.
    *elseif flurry_level = 2
        ${flurry} — A burst of sustained pressure. Reliable aggression that doesn't leave you too open.
    *else
        *bug Flurry only upgradeable to level 2
    *line_break
    *if combo_level = 0
        ${combo} — A jab-cross-hook that sometimes finds its mark. Still telegraphed, still mechanical.
    *elseif combo_level = 1
        ${combo} — Reliable basic combinations, efficient force generation. Effective when there's an opening.
    *elseif combo_level = 2
        ${combo} — Flowing combinations that can exploit openings or create pressure.
    *else
        *bug Combo only upgradeable to level 2
    *line_break
    *if block_level = 0
        ${block} — An instinctive block. Often leaves the body exposed.
    *elseif block_level = 1
        ${block} — A stable shell defence that absorbs hits on the arms and gloves. Surrenders the initiative, but protects effectively.
    *elseif block_level = 2
        ${block} — A reactive guard that anticipates incoming attacks and absorbs pressure.
    *else
        *bug Block only upgradeable to level 2
    *if dodge_level = 0
        *comment unable to dodge/slip
    *elseif dodge_level = 1
        *line_break
        ${dodge} — Avoid telegraphed strikes with footwork and head movement.
    *elseif dodge_level = 2
        *line_break
        ${dodge} — Smooth weight transfer enables fluid bobbing, weaving, slipping. Clears the line of attack, then resets to neutral.
    *elseif dodge_level > 2
        *bug Dodge only upgradeable to level 2
    *if counter_level = 0
        *comment unable to counter
    *elseif counter_level = 1
        *line_break
        ${counter} — Avoid a predictable strike and reply with a clean hit. Breaks the opponent's rhythm.
    *elseif counter_level = 2
        *line_break
        ${counter} — Stay close, baiting an overextension, then an instinctive punish.
    *elseif counter_level > 2
        *bug Counter only upgradeable to level 2

    [b]Boxing Insights[/b]
    *line_break
    ${boxing_insights_unspent} unspent, ${(boxing_insights_unspent + boxing_insights_spent)} total

    [b]Fight record[/b]
    *line_break
    ${record_wins}
    *if record_wins = 1
        win,
    *else
        wins,
    ${record_losses}
    *if record_losses = 1
        loss,
    *else
        losses,
    ${record_draws}
    *if record_draws = 1
        draw
    *else
        draws

    [b]Prizes and awards[/b]
    *line_break
    *if (glutinous_rice_chicken_eaten)
        Lemon tea carton
    *else
        Glutinous rice chicken and lemon tea carton
    *line_break
    *if (eric_result = "win")
        Certificate of Victory
        *line_break
    *elseif (eric_result = "loss")
        Certificate of Loss
        *line_break
    *if (katie_result = "win")
        Research participation flyer
        *line_break
    *elseif (katie_result = "loss")
        Foil packet, empty
        *line_break
    *if (danny_result = "win")
        Black dragon T-shirt, size XXS
        *line_break
    *if (chloe_result = "win")
        Embossed name card
        *line_break
    *elseif (chloe_result = "loss")
        Embossed name card
        *line_break
    *if (camille_result = "win")
        [i]The Intelligent Investor[/i], revised 1973 edition
        *line_break
    *elseif (camille_result = "loss")
        [i]The Intelligent Investor[/i], revised 1973 edition
        *line_break
    *if (queenie_result = "win")
        Two Tai Tong Organic EcoWorld tickets
        *line_break
    *elseif (queenie_result = "loss")
        One Tai Tong Organic EcoWorld ticket
        *line_break
    *elseif (queenie_result = "frog")
        Smiling plush frog
        *line_break
*elseif (stats_screen = "alternate_ending_1")
    [b]Hong Kong's Saviour, Great Hero[/b]
    *line_break
    "I saved Hong Kong. Now, I'll save the world."

    [b]Stats[/b]
    *line_break
    [i]Power:[/i] 100 current, 100 at full energy — Superhuman
    *line_break
    Raw strength, heavy punches. Powering through resistance.

    [i]Technique:[/i] 100 current, 100 at full energy — Superhuman
    *line_break
    Footwork, timing, evasion. Dodges, slips, parries on defense, exploiting openings on offense.

    [i]Toughness:[/i] 100 current, 100 at full energy — Superhuman
    *line_break
    Endurance. Taking hits on your guard and lasting through long exchanges.

    [i]Mental:[/i] 100 current, 100 at full energy — Superhuman
    *line_break
    Awareness, focus, reading opponents. Determines your success at reading and countering opponent actions in combat.

    Each action in a fight tests one or two of these stats. Your energy determines how close your current stats are to their maximum values.

    *gosub_scene utils display_fighting_style

    [b]Outlook[/b]
    *line_break
    You instantly analyse situations and deduce the optimal action. You're always in complete control of your emotions. You notice the smallest micro-expressions and automatically know exactly what others are feeling.

    [b]Boxing Skills[/b]
    *line_break
    [i]Tuned Jab[/i] — An accurate, powerful blow. A jab you can throw without thinking.
    *line_break
    [i]Controlled Flurry[/i] — A burst of sustained pressure. Reliable aggression that doesn't leave you too open.
    *line_break
    [i]Chain Combo[/i] — Flowing combinations that can exploit openings or create pressure.
    *line_break
    [i]Rolling Block[/i] — A reactive guard that anticipates incoming attacks and absorbs pressure.
    *line_break
    [i]Quiet Dodge[/i] — Smooth weight transfer enables fluid bobbing, weaving, slipping. Clears the line of attack, then resets to neutral.
    *line_break
    [i]Predictive Counter[/i] — Stay close, baiting an overextension, then an instinctive punish.

    [b]Boxing Insights[/b]
    *line_break
    You have completely understood all of boxing, so you have no use for additional boxing insights.

    [b]Prizes and awards[/b]
    *line_break
    Lemon tea carton
    *line_break
    Hong Kong Boxing Championship trophy, first place
    *line_break
    Greater China Boxing Championship trophy, first place
    *line_break
    Pan-Asia Fighting Championship trophy, first place
    *line_break
    World Boxing Championship trophy, first place
    *line_break
    World Fighting Championship trophy, first place

*elseif (stats_screen = "alternate_ending_2")
    [b]Hong Kong's Saviour, True Great Hero[/b]
    *line_break
    "Saving the world isn't enough. I'll save the universe."

    [b]Stats[/b]
    *line_break
    [i]Power:[/i] 1,000 current, 1,000 at full energy — Transcendent
    *line_break
    Raw strength, heavy punches. Powering through resistance.

    [i]Technique:[/i] 1,000 current, 1,000 at full energy — Transcendent
    *line_break
    Footwork, timing, evasion. Dodges, slips, parries on defense, exploiting openings on offense.

    [i]Toughness:[/i] 1,000 current, 1,000 at full energy — Transcendent
    *line_break
    Endurance. Taking hits on your guard and lasting through long exchanges.

    [i]Mental:[/i] 1,000 current, 1,000 at full energy — Transcendent
    *line_break
    Awareness, focus, reading opponents. Determines your success at reading and countering opponent actions in combat.

    Each action in a fight tests one or two of these stats. Your energy determines how close your current stats are to their maximum values.

    *gosub_scene utils display_fighting_style

    [b]Outlook[/b]
    *line_break
    She came here prepared to fight a madman, and instead she found a god.

    [b]Boxing Skills[/b]
    *line_break
    [i]Tuned Jab[/i] — An accurate, powerful blow. A jab you can throw without thinking. Creates explosions on hit.
    *line_break
    [i]Controlled Flurry[/i] — A burst of sustained pressure. Reliable aggression that doesn't leave you too open. Its sheer speed makes time slow down.
    *line_break
    [i]Chain Combo[/i] — Flowing combinations that can exploit openings or create pressure. Paralyses opponents by striking pressure points.
    *line_break
    [i]Rolling Block[/i] — A reactive guard that anticipates incoming attacks and absorbs pressure. Completely immune to attacks up to and including depleted uranium rounds.
    *line_break
    [i]Quiet Dodge[/i] — Smooth weight transfer enables fluid bobbing, weaving, slipping. Clears the line of attack, then resets to neutral. Evasion is enhanced with instantaneous short-range teleportation.
    *line_break
    [i]Predictive Counter[/i] — Stay close, baiting an overextension, then an instinctive punish. The punch is way harder than before.

    [b]Boxing Insights[/b]
    *line_break
    You have completely understood all forms of martial arts as well as reality itself, so you have no use for additional insights of any kind.

    [b]Prizes and awards[/b]
    *line_break
    Lemon tea carton
    *line_break
    Hong Kong Boxing Championship trophy, first place
    *line_break
    Greater China Boxing Championship trophy, first place
    *line_break
    Pan-Asia Fighting Championship trophy, first place
    *line_break
    World Boxing Championship trophy, first place
    *line_break
    World Fighting Championship trophy, first place

*else
    *bug Invalid stats_screen
*check_achievements
*choice
    #Close this window.
        *finish
    *if (choice_achieved_game_completed)
        *if (fight_vision)
            #Turn off Fight-Vision. [i](Currently on.)[/i]
                *set fight_vision false
                Fight-Vision is now disabled.
        *else
            #Turn on Fight-Vision. [i](Currently off.)[/i]
                *set fight_vision true
                Fight-Vision is now enabled. During fights, you'll see which stats each option tests.
    *if (checkpoint0) #Rewind to the character selection screen.
        *if (choice_saved_checkpoint_ch0)
            *restore_checkpoint ch0
        *else
            *bug Quicktest guard
    *if (checkpoint1) #Rewind to the beginning of Chapter 1, Eric "Blazefist" Jiang.
        *if (choice_saved_checkpoint_ch1)
            *restore_checkpoint ch1
        *else
            *bug Quicktest guard
    *if (checkpoint2) #Rewind to the beginning of Chapter 2, Katie "Pressure Point" Reynolds.
        *if (choice_saved_checkpoint_ch2)
            *restore_checkpoint ch2
        *else
            *bug Quicktest guard
    *if (checkpoint3) #Rewind to the beginning of Chapter 3, Danny "The Dragon" Chan.
        *if (choice_saved_checkpoint_ch3)
            *restore_checkpoint ch3
        *else
            *bug Quicktest guard
    *if (checkpoint4) #Rewind to the beginning of Chapter 4, Chloe "Wildcard" Wong.
        *if (choice_saved_checkpoint_ch4)
            *restore_checkpoint ch4
        *else
            *bug Quicktest guard
    *if (checkpoint5) #Rewind to the beginning of Chapter 5, The Hungry Ghost Festival.
        *if (choice_saved_checkpoint_ch5)
            *restore_checkpoint ch5
        *else
            *bug Quicktest guard
    *if (checkpoint6) #Rewind to the beginning of Chapter 6, Camille "The Mime" Durand.
        *if (choice_saved_checkpoint_ch6)
            *restore_checkpoint ch6
        *else
            *bug Quicktest guard
    *if (checkpoint7) #Rewind to the beginning of Chapter 7, James Yeung.
        *if (choice_saved_checkpoint_ch7)
            *restore_checkpoint ch7
        *else
            *bug Quicktest guard
    *if (checkpoint8) #Rewind to the beginning of Chapter 8, Queenie "Freestyle" Wai.
        *if (choice_saved_checkpoint_ch8)
            *restore_checkpoint ch8
        *else
            *bug Quicktest guard
    *if (checkpoint9) #Rewind to the beginning of Chapter 9, Bob "Ichigeki" Chow.
        *if (choice_saved_checkpoint_ch9)
            *restore_checkpoint ch9
        *else
            *bug Quicktest guard
