*label scene_introduction
*if chloe_subplot_scene = 1
    After the fight at The Cauldron, Chloe didn't apologise at all. Instead, she invited you to meet her at the Upper House. It's a rooftop bar in Admiralty, far from the ex-yoga studio where you fought. She was vague about why exactly she wanted to meet, only saying that she had things to talk about.
    *if (chloe_almost_lapsed)

        Chloe's invitation won't stay open for long. If you don't show up soon, she'll move on.
*elseif chloe_subplot_scene = 2
    Chloe invited you to a private training session, saying she wants to "get serious," though you're not sure what she means.
    *if (chloe_almost_lapsed)

        Chloe doesn't seem like the kind of woman to wait around forever. She'll lose interest if you don't take her up on it soon.
*elseif chloe_subplot_scene = 3
    *if chloe_plot_timer = 0
        Chloe's been messaging you again. She says her brother Roland wants to meet you.
        *if highest_trait = "analysis"
            "You'll see what the family empire looks like up close. Think of it as a free anthropology tour."
        *elseif highest_trait = "composure"
            "He's basically a CEO in training. Perfect hair, perfect suit, perfect stress wrinkles. You'll love it."
        *elseif highest_trait = "empathy"   
            "He wants to know who I trust. So... I thought you would fit the bill."
        *else
            *bug Invalid highest_trait
        You'll be seeing them at his office in Central.

        *if (chloe_almost_lapsed)

            It's been a while since you've responded to Chloe. You're sure she's aware of that, too.
    *else
        Chloe's still in touch, but she says some family stuff has come up and she won't be free for a while.
*elseif chloe_subplot_scene = 4
    Chloe says that Roland has agreed to go on the family boat on the weekend. She's invited you along.
    *if (chloe_almost_lapsed)

        Chloe's waiting for your response, but she won't wait forever.
*elseif chloe_subplot_scene = 5
    *if chloe_plot_timer = 0
        Chloe's invited you to dinner. She wants to discuss your fight at the Cauldron. She can arrange a private room at the restaurant.

        *if (chloe_almost_lapsed)
            Chloe sent you another message. "I want to see you. It's important to me." It sounds serious.
    *else
        Chloe's still been messaging with you. She's been thinking about some things, she said, and needs some time to herself.
*elseif chloe_subplot_scene = 6
    *if chloe_plot_timer = 0
        Chloe's invited you out again: Roland has finally agreed to join her for lunch, and she'd like you along as well. Roland's coming, so it's on a Sunday, naturally.

        *if (chloe_almost_lapsed)
            Roland's schedule is difficult. If you keep putting it off, she'll go ahead without you.
    *else
        Chloe's busy with some family events. That's what she told you last.
*elseif chloe_subplot_scene = 7
    *if chloe_partner
        Chloe's busier than ever with social obligations, but she always makes time for you. Meals together, training, sometimes just dropping by after work.
    *else
        Chloe's busier than ever with social obligations, but she still has time for you. Meals together, the occasional training session, whatever new attraction she's decided is a must-see.
*else
    *bug Chloe subplot scene not found
*return

*label scene_choice
*if chloe_subplot_scene = 1
    *comment earliest: chapter 5, first fortnight
    *comment chloe_friendship from other events: 0-1 from eric_subplot, event_2
    *comment chloe_friendship from this chapter: 3-4 for accept, 0-2 for reject
    *comment cumulative chloe_friendship after this chapter: 0-5
    *gosub event_1
    *set stat_mental %+6
*elseif chloe_subplot_scene = 2
    *comment earliest: chapter 5, second fortnight
    *comment chloe_friendship from this chapter: 1-4
    *comment cumulative chloe_friendship after this chapter: 4-8
    *gosub event_2
    *set stat_toughness %+3
    *set stat_power %+3
    *set boxing_insights_unspent +1
    *set unlocked_chloe_training true
    *set chloe_plot_timer 2
*elseif chloe_subplot_scene = 3
    *comment earliest: chapter 6, second fortnight
    *comment chloe_friendship from afterhours: 0-4
    *comment chloe_friendship from this chapter: 0-3
    *comment cumulative chloe_friendship after this chapter: 4-11 + afterhours 0-4 = 4-15
    *comment chloe_romance from afterhours: 0-2
    *comment chloe_romance from this chapter: 0-1 (-1 possible)
    *comment cumulative chloe_romance after this chapter: 0-1 + afterhours 0-2 = 0-3
    *gosub event_3
    *set stat_mental %+4
    *set stat_toughness %+3
*elseif chloe_subplot_scene = 4
    *comment earliest: chapter 7, first fortnight
    *comment chloe_friendship from afterhours: 0-4
    *comment chloe_friendship from this chapter: 2-5
    *comment cumulative chloe_friendship after this chapter: 6-16 + afterhours 0-4 = 6-20
    *comment chloe_romance from afterhours: 0-2
    *comment chloe_romance from this chapter: 0-3
    *comment cumulative chloe_romance after this chapter: 0-4 + afterhours 0-2 = 0-6
    *gosub event_4
    *set stat_power %+4
    *set stat_energy +10
    *gosub_scene utils clamp_energy
    *set chloe_plot_timer 2
*elseif chloe_subplot_scene = 5
    *comment earliest: chapter 8, first fortnight
    *comment chloe_friendship from afterhours: 0-4
    *comment chloe_friendship from this chapter: 0-4
    *comment cumulative chloe_friendship after this chapter: 6-20 + afterhours 0-4 = 6-24
    *comment chloe_romance from afterhours: 0-2
    *comment chloe_romance from this chapter: 0
    *comment cumulative chloe_romance after this chapter: 0-4 + afterhours 0-2 = 0-6
    *gosub event_5
    *set stat_technique %+5
    *set stat_mental %+3
    *gosub_scene utils clamp_energy
    *if chloe_partner
        *set chloe_plot_timer 1
    *elseif (chloe_apology = "reject")
        *set chloe_plot_timer 2
    *elseif (chloe_romance >= 2)
        *comment PC turned down Chloe's offer to become partners
        *set chloe_plot_timer 2
    *else
        *set chloe_plot_timer 1
*elseif chloe_subplot_scene = 6
    *comment earliest: chapter 8, second fortnight
    *gosub event_6
    *set stat_technique %+7
    *set stat_energy +10
    *gosub_scene utils clamp_energy
    *set chloe_plot_timer 10000
*else
    *bug Chloe subplot scene not found
*return

*label event_1
@{gender_num Black midi dress, beige cardigan, black patent flats.|White dress shirt, grey blazer and chinos, scuffed leather shoes.|Collarless shirt, slim black trousers, leather ankle boots.} The outfit you usually only pull out for the company annual dinner or cousin Winnie's weddings. It fits uncomfortably on you as you ride the MTR.

Admiralty is a huddle of glass-and-steel skyscrapers, the shopping complexes and office towers connected by elevated walkways. You could roam the entire area and never touch the ground. You stride out onto the polished marble of the Pacific Place mall, rows and rows of luxury boutiques always empty of shoppers. Several long escalators bring you out for a brief breath of traffic-choked air, then up to the Upper House hotel.

Perched above the five-star JW Marriott, the Upper House has floor-to-ceiling windows with views of the Hong Kong skyline. Your shoes sink into the thick carpet as you wait for the lift. Inside, it smells like ginger.

Up a few floors. The lift doors glide open, revealing a wood-panelled atrium. Mushroom-coloured banquettes dot the marble floor. Architecture books anchor the low wooden coffee tables. An enormous fireplace is at the far side of the lounge. The usual crowd of bankers engage in muted conversation. None of them give you a second glance.

*page_break
You hesitate before approaching the severe-looking woman at the concierge stand. She's wearing a power suit with a nameplate that says "Winky".

"Good evening. Do you have a reservation with us tonight?" she asks, looking through you.

"Yes."

She stares at you, a tight-lipped smile the only change in her expression.

"Oh, right. Sorry. I'm here to see Chloe Wong."

A raised eyebrow. "Certainly, please come this way."

She escorts you through the atrium. At the threshold to the rooftop lounge, she gestures you through. She's back at reception before you can thank her.

All around, manicured hedges frame the twilight skyline. Enormous white candles shed vanilla fragrance. You walk across stone tiles towards the central seating area, crossing a strip of zen pebbles onto a patch of artificial lawn. Tuxedoed waiters with silver trays of smoked salmon on blinis drift across the terrace.

You see a young Chinese woman seated on a sofa, leaning comfortably into the cushions. Black hair neatly tucked behind both ears, a small skull earring on one side. A black silk slip dress that hangs easily on her, high neckline. Legs crossed casually at the ankles, minimalist black leather slides. A small handbag with no logo you can recognise rests on the sofa, while she idly scrolls her well-worn phone.

You realise this must be the same woman you fought at The Cauldron.

*choice
    #Wonder what it takes to present yourself so differently.
        *gosub_scene utils increase_empathy
        Which one is the real Chloe? Will she transgress boundaries here?
    #Centre yourself. It's still the same Chloe.
        *gosub_scene utils increase_composure
        Unfamiliar environment to you. Familiar environment to her. No matter. Breathe. Relax.
    #Evaluate the difference in her appearance, and what it suggests.
        *gosub_scene utils increase_analysis
        She's comfortable playing different roles. But even here, she's slightly off-kilter. Deliberately or not, you don't know.

You've stood there unmoving for too long when she looks up. She sits up straight, commanding the central seat of the C-shaped sofa, and waves you towards the short arm. A low ottoman rests in the curve of the sofa.

"All dressed up! I half expected you to show up in boxing gloves." The words are sharp, but the edge isn't there. She raises a finger, and a waiter scurries over, sporting a strained smile. Chloe turns to you. "Would my honoured guest like a drink?"

"Oh. Water please, thank you."
*if highest_trait = "analysis"
    You notice the waiter came over immediately, like he was assigned to her.
*elseif highest_trait = "composure"
    No need to disrupt things just now.
*elseif highest_trait = "empathy"   
    You can feel the tension. Better to make things simple here.
*else
    *bug Invalid highest_trait
She gives an offhand instruction, and the waiter nods and hurries away. You sit on the sofa arm, back straight, palms on your knees.

"Actually didn't know if you'd come." You look at her to see what she means, but her face is unreadable.

*choice
    #"Why did you invite me here?"
        *gosub_scene utils increase_analysis
        Chloe knows how to navigate this social space. But one detail has been occupying your thoughts since you first arrived at this elaborate venue.

        "Why did you invite me here?" The question spills out.

    #"You're a different person today."
        *gosub_scene utils increase_empathy
        "You're a different person today."

        "Oh, thank you! I didn't realise."

        You wait for her to continue.

    #Remain silent. Wait for her to make the next move.
        *gosub_scene utils increase_composure
        *set chloe_friendship +1
        You maintain your bearing, revealing nothing. You feel the artificial lawn rustle under your shoes, grounding you. This might be her territory, but she asked you here. She's the one who should make the next move.

        She studies you. Then a small twitch plays on the edges of her lips.

"I asked you here because I enjoy your company, of course," Chloe says with a smile that could mean anything. "All this..." she waves a careless hand at the curated elegance around you, "it gets tiresome, you know?"

"Must be hard to frequent rooftop lounges all the time."

A clipped laugh from her, more like a cough. Her eyes move past the clump of bankers at an adjacent sofa, and she gazes at the distant evening skyline. "Don't get me wrong. Having money solves problems."

The staff hover in the background, reading her cues.

"${first_name}, you see those three towers up on the hill? The ones that look like giant incense sticks? My family built those. These two circular ones that look like they're stuck together? Those too." Her gaze remains fixed on the skyline, not meeting your eyes.

*choice
    #Consider what this reveals about her intent.
        *gosub_scene utils increase_analysis
        She's disclosing her wealthy background, but she doesn't seem to be evaluating your reaction.
    #Take her perspective to see why she's sharing this.
        *gosub_scene utils increase_empathy
        Giant incense sticks. That's not a very complimentary term.
    #Absorb what she's said, but don't rush to respond.
        *gosub_scene utils increase_composure
        She told you about her wealth like it's a bare fact. You don't respond.

"Living the dream, right?" She sits forward.

"All these people around us, that's what they dream of. But it comes with a price. I can enjoy helicopter rides to tasting dinners in Macau, but I can't even fight someone who fights back. My Muay Thai coaches are afraid to push me. Wouldn't want the delicate princess to strain a muscle or something. I'm only allowed to have glorified aerobics classes."

The waiter brings you a crystal highball glass of water nestled in a small paper napkin, then retreats.

Chloe shivers. Might be the wind. Her gaze lingers on your glass, then she takes a short breath and looks right at you.

"You're not afraid of me. I want you to train me."

She continues. "And I could teach you a few things. How people get into your head, how to prevent that. You've got grit, but you don't have the experience."

*choice
    #"That's a bold ask, considering what you did at the Cauldron. Why should I trust you?"
        *set chloe_friendship +1
        "That's a bold ask, considering what you did at the Cauldron. Why should I trust you?"

        Chloe doesn't answer, instead directing her gaze to the ottoman between you. Then she speaks without looking at you.

        "It's underground fighting. Things happen that wouldn't happen elsewhere. I'm exploiting the rules. I'm not saying I'm an angel. But finding advantages is a legitimate part of fighting. I'm playing to win."

        She meets your eyes, but seeing your expression, she glances away.

        "For those twenty seconds, I wasn't thinking about anything else. It was just you, and me."

        She continues. "You probably thought, this crazy bitch is crushing me as part of some twisted game."

        She waits. Not forcing a response, but leaving room for one.
        *if highest_trait = "analysis"
            But what she said wasn't an apology. It was a justification.
        *elseif highest_trait = "composure"
            You stay silent, give it space.
        *elseif highest_trait = "empathy"
            You get the sense that this was difficult for her to say.
        *else
            *bug Invalid highest_trait
    
        "You, ${first_name}... you're tough. You didn't crumble. You got up and went for round two."

        She observes you, lips pursed. "Why should you trust me after what I did? Good question. Well... I don't fuck people over?"

        A pause. "I guess that sounds like bullshit right now."

        You make a noncommittal [i]hmm[/i], which she takes as a signal to continue. "I take care of my people though. Mostly."

        "And most people who can read people like I can, they're dangerous. I'm not, you know, the bad kind of dangerous."

        *choice
            #"Okay, I'm willing to give it a try. But if you cross any lines, I'm done."
                *set chloe_friendship +2
                Chloe leans back, arms crossed. Then she freezes. She processes your words. She breaks into a broad grin, crinkles appearing at the corners of her eyes.

                "Wow, ${first_name}, I was half-expecting... this is great. Thanks. Thanks for accepting. I mean, it's not something you get offered every day. Um."

                There are faint red marks where her fingernails dug in. Chloe shifts on the sofa, her foot tapping rapidly on the floor. "Wow. Okay. Wasn't expecting that. Uh... well, let's celebrate! To the future!"

                She summons the waiter again, and you overhear her order some kind of caviar service. Then she looks at you, smile faltering, and fidgets with her earring. "It's all on my father's tab anyway. Not like he cares about the money."

                Chloe then takes in a deep breath and stands up abruptly. "I... need to go. Thanks. I'll be in touch." She leaves, stumbling as she crosses the strip of zen pebbles.

                You wait a while more, sitting by yourself on the spacious sofa, surrounded by the elite of Hong Kong high society, just letting things settle.

                The waiter returns with a silver platter the size of a steering wheel, upon which rests a crystal bowl filled with gleaming black caviar pearls, two tiny silver spoons, and a stack of fluffy blinis. Another waitress arrives with a fold-out service table and aligns the spoons.

                No reason to waste food. You pinch a spoon with your thumb and index finger, scoop a big pile of caviar onto a blini, and pop it into your mouth. It tastes good. You fit in now, with your big caviar.

            #"No thanks. I'm not comfortable with this."
                *goto event_1_reject

    #"No thanks. I'm not getting drawn into your games."
        *label event_1_reject
        *set chloe_subplot_status "rejected"

        Chloe's gaze falls to the ground. You see an almost imperceptible pinkness appear on her cheeks, but it fades. She looks at you again, and her shoulders sag.

        "No big deal. My methods can be off-putting. You're being sensible, playing it safe. Expected something like this to happen. Was a long shot anyway."

        She tries to smile, though it comes out as more of a grimace. A slow exhale. Then she crosses her arms, sits up straighter, and slowly looks around the rooftop.

        "You'll do fine without me. Good luck ${first_name}. Anyway. This is all on my father's tab, order whatever you want. I... I should go. Later."

        She stands, strides to the exit. The nearest group of bankers pause their conversation and intently study the floor, only resuming their talk when she's completely out of sight.
*return

*label event_2
You step out into Kowloon Station. It's one of the nice ones: brushed metal, glass rails, an atrium with a ceiling so high it faintly echoes. The refrigerated air smells like it's been endlessly recirculated. The atrium still holds a trickle of airport-goers, suitcases clacking on the polished tile, but the expanse of open floor is almost empty. Escalators rise steeply, carrying you out of the station and into Elements.

You emerge at the "Water Zone". You know how this works: the mall has five zones, one for each element, and you're supposed to remember the order. You don't want to, so you approach the touchscreen directory and tap the International Commerce Centre button, and a glowing path shows the way to the Metal Zone. They say the ICC is there because it's made of metal.

A procession of escalators, each one identical to the last. Your path cuts through Prada, Louis Vuitton, Zara. And Citysuper, for some reason. Eventually, the mall spits you out into the office lobby on level 9.

Not much activity this Saturday, the lift lobby staffed by a lone receptionist at the concierge desk past the electronic turnstiles. He's patting his cheeks, barely aware of his surroundings. You give him your name, and he prints a visitor badge, hands you the lanyard, and directs you to the far bank of lifts. 

Out again at the 86th floor. The corridor's LED strip lights glow white and the carpet mutes your footsteps. A metallic grinding sound intrudes from the ceiling vents, followed by a puff of cold air that raises goosebumps on your forearms. A plain, frosted-glass door with an angled steel handle. A nameplate: "Studio 3". You push the solid door, slowly, and the latch clicks open, bright golden light flooding into the corridor.

*page_break
The dense grey rubber yields with a soft groan as you step on it. You scan the room: white drywall with grey metal panels, a narrow steel bench against a wall, Chloe's sports bag and navy Asics sneakers tucked neatly underneath. You breathe in the faint smells of sweat and disinfectant, more Pilates than boxing.

On the far side, floor-to-ceiling windows span the entire width, a thin metal grid as support. The windows lead to a view of Victoria Harbour and Hong Kong Island below, skyline still shining, but whole towers already dark, ones that once glowed until midnight.
*if (eric_subplot_scene > 1)
    It feels different from Eastside. Both of them are professional, but this place is all about function.

Chloe's standing by the window, left arm extended above her head, leaning into a side stretch. She's wearing a black sports bra and athletic shorts, no logos or decorations. Hair clipped back, barefoot, hand wraps and gloves beside her on the floor.

"Good timing." She looks at you and flashes you a grin. After a moment, she steps over to the wall and presses a button. The skyline vanishes as the windows turn frosted white.

*page_break
"Okay, warm up, and then let's do it. We'll start with contact sparring. Don't go soft on me."

Chloe skips rope and jogs on the spot. She sets the rope aside as you finish your warm-up stretches, but then stares at the far wall, looking at nothing in particular.
*if highest_trait = "analysis"
    No small talk, a disciplined warm-up, turning the windows opaque to eliminate distractions.
*elseif highest_trait = "composure"
    The room feels airless with the city shut out. You breathe evenly, grounding yourself.
*elseif highest_trait = "empathy"
    The city's gone, behind frosted glass. No distractions, everything shut out.
*else
    *bug Invalid highest_trait

"We'll start with a jab drill. Step in. I'll check and teep you back. Start slow." She retrieves a stopwatch from her bag and sets it for three minutes.

You put on your gloves and settle into your ready stance. Chloe stands opposite you and nods, her arms extended in front of her in a long guard. The timer's ticking.

You start light, singles and doubles, probing her guard. Jabs meet gloves and forearms. Nothing gets through. Her eyes follow your every movement.

She swats one away, lands a gentle push-kick to your chest, steps off to the side as you give ground. A brief smile, then her guard snaps back up.

You move forward again, double jab blocked, a satisfying thud against her outstretched palm. The next one parried, another light teep. 

A jab gets through, lightly tapping her forehead. A grin, sharp and toothy. She backsteps, teeps, centres herself. The stopwatch beeps, already counting down the next minute.

Chloe strides over to the bench, stays standing, and takes a quick mouthful of water. You fumble through your gym bag and grab your own bottle. Chloe breathes lightly, fires off instructions. "Next. Short combos. Two or three punches, your choice. I'll block and kick back. Full power. No head-hunting."

*temp pc_sparring_power 0
*choice
    #Go light. Keep it technical.
        *set pc_sparring_power 0
        The timer signals the start of the next round, and you go straight to it. Jab, body jab, cross, your leather absorbed by her guard. She fires back with a low roundhouse to your thigh, a clean tap.

        Jab, hook. Another roundhouse.

        Jab cross hook. Textbook combos, controlled impacts.

        After the next basic combo, Chloe narrows her eyes. The roundhouse lands stronger this time, an audible [i]thwack[/i] against your upper thigh.

        You give her another controlled combination, jab jab cross. Her shin finds your lead leg again, stinging lightly. You close out the round with a clean jab cross, your breathing still steady.

    #Match her power.
        *set pc_sparring_power 1
        *set chloe_friendship +1
        The timer signals the start of the next round, and you go straight to it. Jab to forehead, cross to chest, hook to the glove line. She absorbs them on her guard, fires back with a low roundhouse to your thigh, a clean tap.

        Jab, jab, cross to the chest. Roundhouse.

        Jab, cross, body hook. Solid punches.

        More short combinations, some of your punches slipping through as you vary your angles. A hook lands on her ribs, a check jab to her forehead, Chloe rolling with the impacts. After your next sequence, she looks you in the eye, nods, satisfied. Her return roundhouses come with force, matching your power, slightly numbing your thigh. You close out the round with another string of punches, solid but controlled, your breath fast but steady.

    #Go hard, see how she handles it.
        *set pc_sparring_power 2
        *set chloe_friendship +2
        The timer signals the start of the next round, and you go straight to it. If she wants full power, you'll give her that. A light jab to the forehead, then your cross pistons forward, crashing against her guard. The impact staggers her briefly, but she manages to tag your lead leg with a quick roundhouse.

        Jab jab cross. Roundhouse. Then you unleash with a hook, cross, hook to the body. Full force.

        Chloe shells up, guard high, no time for her counter kick. She looks at you, eyes wide, and can't suppress a broad smile. She bounces on her feet, breathes out sharply through pursed lips, and signals for you to continue.

        More combinations. A hook lands on her ribs, staggering her. She barely registers it, firing back with a roundhouse that lands with a [i]thwack[/i] on your thigh. You close out the round with another heavy combination, breathing hard through your nose.

The timer signals the end of the round, and both of you head to the bench.
*if pc_sparring_power = 0
    Her breathing remains steady
*elseif pc_sparring_power = 1
    Her chest heaves
*elseif pc_sparring_power = 2
    She takes laboured breaths, sweat running down her face,
as she dictates the next drill. "High volume. Nonstop flurries. I'll block, counter once. Full power, don't hold back, this is the last round."

She's calling for a pad-work barrage, except this time it's her body taking the shots. You can already see the bruises. A moment ago, she smiled when your punches connected, took them without blinking.

*choice
    #Work her body with strong, controlled shots. If she won't show restraint, you will.
        *set chloe_friendship +1
        You lay in as soon as the timer beeps. Jab cross, jab cross, jab cross, exhaling sharply on the first. More jabs, more crosses, now hooks, uppercuts to the chest.

        Chloe deflects most of them, absorbing shots on her guard, slipping jabs to her head, parrying body shots. But some of them find their mark. Gloves smack on flesh, unbalancing her. Body shots force air from her lungs. Flurries on her guard push her back. Occasional roundhouses from her land on your thighs and ribs, light taps that are counters in name only.

        A smile, one where the lines crinkle at the corners of her eyes. "Good," she huffs out, as she settles into her guard again.

        More strikes dig into her ribs, chest, sternum. Her guard rises slower after each flurry. Your shoulders start to burn, gloves becoming heavy.
    #Unload with full power.
        *set pc_sparring_power +3
        You lay in as soon as the timer beeps. Full power. Jab cross, jab cross, jab cross, exhaling sharply on the first. More jabs, more crosses, now hooks, uppercuts to the body.

        Chloe deflects most of them, absorbing shots on her guard, slipping jabs to her head, parrying body shots. Occasional roundhouses from her land on your thighs and ribs, light taps that are counters in name only. More of your punches find their mark. Gloves crack on flesh, staggering her. Body shots force sharp exhales. Flurries on her guard send her stumbling back. She smiles, cheeks tight and flushed. 

        A cross crashes into her upper chest with a heavy, muffled thud. Her eyes snap shut and her mouth opens wide, then the next moment her composure returns. "Good shot," she says, dragging her guard back up.

        More strikes bypass her defences, digging into her ribs, chest, sternum. Her guard rises slower after each flurry. Your shoulders start to burn, gloves becoming heavy.

*comment pc_sparring_power from 0 to 5
*page_break
The timer rings out. You take a deep breath, the cool, filtered air hitting your lungs, then both of you shuffle over to the bench. The metal feels cold against your thighs.
*if pc_sparring_power <= 1
    Chloe wipes her forehead with her towel, and three breaths later her rhythm is normal again.
*elseif pc_sparring_power <= 3
    Chloe wipes her face with her towel, her breathing becoming steady, as she runs a hand over her ribs.
*else
    Chloe wipes her face with her towel, her breathing still sharp and uneven. She presses her hand on her chest, eyes closing when she finds the bruise.

A minute later, she stands up, strides to the centre of the room, and motions you over. "That's it for physical. Now let's see your mental game."

Once you're beside her, she speaks with the detachment of someone delivering a report. "Everyone flinches. Everyone gives something away. I want to show you where it happens."

She steps forward and bars her arm across your chest. Her foot catches your ankle as she drives you down. You crash onto the rubber mat, Chloe grinning down at you, eyes fierce.

*if chloe_trauma = 0
    You tense up as you recall the fight at The Cauldron. But this isn't the same. It can't be.

    *page_break
    Chloe hasn't moved. She's still standing at your side, peering down at you. The spike of adrenaline's faded completely. She's studying you.
    
    She clicks her tongue and says, "You knew it wasn't real. But for a moment there, your body didn't."

    She offers a hand. You take it, and she hauls you up.

*elseif chloe_trauma = 1
    Your body tenses up as your mind replays her attack on you at The Cauldron. Panic flares briefly. She wouldn't.

    *page_break
    Chloe hasn't moved. She's still standing at your side, peering down at you. The immediate danger gone, you replay what happened: the jolt hit before you could think. Your body acted first, brain lagging behind.

    She rubs her chin, and then says, "You knew I wasn't going to do anything, but your body didn't."

    She offers a hand. You take it, and she hauls you up.

*elseif chloe_trauma = 2
    You freeze, muscles rigid. You remember her standing on you. You remember all your futile attempts to escape.

    *page_break
    Chloe hasn't moved. She's crouched at your side, eyebrows drawn together, gaze soft, but jaw stiff. Her mouth opens slightly, as she searches for words.

    She touches a hand to the side of your shoulder, and you gradually come back. "That bad, huh."

    Chloe clears her throat. Pauses. "You really thought I would."

    She slides both hands under your shoulders and drags you up to a sitting position. Then she stands up before you do.

*else
    *bug Invalid chloe_trauma
*page_break
Sitting side-by-side on the metal bench, you feel your breathing slow and your heartbeat settle.

She turns to you. "Watch my eyes. The corners." The skin there tightens by a millimetre. "See that? That's contempt, but pretending to be boredom. Easy to miss. Now look at my mouth." Her lips press together, not quite thin. "Anger? No, that's fear. No white in the lips."

Her voice is low, intense, the restless energy in her body wholly directed into the lesson. The instructions blur together, but the general idea stays.

Chloe's half-smiling, her shoulders relaxed. "Dad's always been good at reading people. I got that part. I can use it against them. And then?"

She catches herself and stops talking. She stands up, strides over to the window. The evening skyline appears again, a few more lights winked out.

Chloe stays still, looking at the city below. You join her at the window.

"Whatever," she says, flicking her hand. "Enough of that. You've been fighting for a while. Who can you still not figure out?"

*temp character_read_choice ""
*choice
    #Eric "Blazefist" Jiang.
        *set character_read_choice "Eric"
        *if eric_subplot_scene > 2
            "Eric, huh? He's like an open book. Remember at Eastside? I just said a few words, and he looked ready to ignite the entire gym."

            You remember that time. You were training with Eric. Chloe barged in through the front door and provoked him with a few cheap shots. Eric started out steady and controlled, but in less than a minute the fire was leaking through.

            "Chloe, what was that for, anyway? Why did you provoke him like that?"

            *if (eric_subplot_scene >= 6)
                "I wanted to see how he'd react." She chugs some water, sloshing it around before swallowing. "And I mean, he'll be fine. Look how well he did at the Pearl River Cup."
            *else
                "I wanted to see how he'd react." She chugs some water, sloshing it around before swallowing. "And I mean, he'll be fine. He'll own the Pearl River Cup, as long as he doesn't choke."

        *else
            "Eric, huh? He's like an open book. He wears everything on his sleeve."

            She chugs some water, sloshing it around before swallowing. "He tries so hard to stay calm, but he can't do it. You can see the exact moment when he slips. His eyes give him away before he even knows it himself."

            You towel off, aware of the cooling sweat on your skin. Chloe adds, "Just let him do his thing and he'll knock himself out."

    #Katie "Pressure Point" Reynolds.
        *set character_read_choice "Katie"
        "Katie? Weird ones are usually dangerous. But there's a rhythm to what she does. Easy once you know what to look for."

        She explains more. "Watch where she's looking. She's looking at your arm, not your face."

        She lets out a short laugh. "I guess it's hard when you're screaming because your arm feels broken. But once you understand that, you stop being her lab rat."

        *if katie_subplot_scene > 1
            You remember Katie's exam table, her eyes bright as she scribbled furiously.
        *else
            You remember how Katie grinned, the casual chatter as she pressed her fingers into your elbow. 

        She chugs some water, sloshing it around before swallowing. "Whatever. Point is, don't get distracted by the smile. The smile's for you, but her hands telegraph her intentions. Watch her hands."

    #Danny "The Dragon" Chan.
        *set character_read_choice "Danny"
        "Ugh, Danny. Can't stand that guy. Still, you have to respect it."

        "What do you mean?"

        "If he was a computer program he'd be the smallest program ever. Step one, step two, next step, loop. Loop, loop, loop. People like that, they don't even see you. You're just part of the scenery."

        She chugs some water, sloshing it around before swallowing. "Still, though. I kind of admire that, in a way. I couldn't do that."

        You both sit there, staring at nothing in particular.

[i]A Boxing Insight appears. Understanding.[/i]

*page_break
The quiet returns. Beyond the window, the evening lights fade. You pack your things, shoulder your bag, and look over at her. She's zipping up her bag, then running a hand over her ribs. Hunched over her equipment, head bowed.

But then she jerks upright. Looks straight at you, unblinking. "We could go get a drink."

She looks away. "Forget it."

Chloe marches out, the door left half-open.
*set chloe_friendship +1
*return

*label event_3
*temp shirt "T-shirt"
*if current_season = "winter"
    *set shirt "long sleeved T-shirt"
"You don't have to dress up, ${first_name}."

Chloe texted you the message an hour ago, so you're in jeans and a ${shirt} today. You feel slightly out of place in late afternoon Central, surrounded by men in starched collars and women in heels and blazers, everyone more attractive than in the rest of the city. 

It's only a short walk to Cheung Kong Center from Central station. A Rolls-Royce ghosts past you, curving parallel to the tall metal railing. Chloe's waiting in the marble-floored lobby. A muted pencil skirt and blouse, black pumps, hair in a towel-dried bob, same as any other woman streaming past. She greets you with a measured hello.

Chloe signs you in at the turnstiles and taps her security pass to the reader. The lift zips straight up in less than a minute, depositing you in front of a pair of floor-to-ceiling glass doors. "Wong Investment Holding Company" is etched in steel on the dark wood panel behind the reception counter.

You pass the reception area together. Behind the partition, you see a place like any other Hong Kong office, maybe two dozen people around, scattered in cubicles. Small private rooms and meeting areas line the walls. Chloe leads you to the far corner, where there's a spacious executive office. Through the tinted glass, you see a mahogany desk with a computer monitor on it, a spacious leather sofa, and a glass-topped coffee table.

"Here's Roland. He's expecting us." Chloe opens the door and you both step inside.

*page_break
You scan the rest of the room: a display cabinet with initial public offering plaques, a large framed family photo on the far wall, and a man in the desk chair, gelled black hair in a classic side part, facing the window.

Chloe smiles broadly, her eyes crinkling, as she hurries over to him. He swivels in his chair. Roland has a lean physique, his arms filling out the sleeves of his crisp white dress shirt. He looks to be in his late twenties, although faint creases show on his forehead.

"Hey boss!" She embraces him, wraps her arms around him from behind the chair, squeezes him tight.

"Hey warrior princess," Roland grins as he turns to face her and ruffles her hair.

*choice
    #Stay where you are, waiting for Chloe to take the lead.
        *set chloe_friendship +1
        You move your gaze over to Chloe, meeting her eyes, then you give a quick shrug of your eyebrows. Her chin dips.

    #Meet Roland's eyes briefly, then look away.
        You look directly at Roland, and he meets your eyes almost accidentally.

        You both look away at the same time.

Chloe straightens Roland's tie with a quick tug, as he relaxes into his chair. Then she introduces you: "${first_name}, this is my brother Roland. He manages part of the family business. Roland, this is ${first_name}. @{gender_num She's|He's|They're} my friend from the fighting scene."

Roland turns to you, his face blank. Then he snaps out of his reverie and sits up straight, the corners of his lips curving into a small smile. "Nice to meet you, ${first_name}. Please, no need for formalities. Let's relax over there. A drink?"

All three of you sink into the sofa, Roland on the short arm, you and Chloe on the longer side. The sofa's comfortable, at least.

"Chloe's told me a bit about her... intense hobbies. Unconventional, even. And you? What do you gain from it?" His piercing eyes are fixed upon you, waiting.

*choice
    #"It's hard to explain. Keeps me busy."
    #"I get to improve myself and meet new people."
        *set chloe_friendship +1

"Mmm... I see." Roland hasn't broken eye contact with you. It feels like a performance review.

"Chloe's mentioned you a few times, you know that?" Chloe leans over and swats him on the shoulder, causing him to let out a short laugh.

"So what do you do when you're not fighting for fun?"

"Office work. Market research and analysis," you reply.

Roland nods politely, his expression neutral, but Chloe cuts in: "Not everything's about work, Roland."

"Mm-hmm."

*choice
    #Notice how Roland's watching you.
        *gosub_scene utils increase_analysis
        Roland's leaning back into the seat cushion, but his eyes miss nothing. You wonder if he's like this all the time.

    #Wait and observe the situation first.
        *gosub_scene utils increase_composure
        This is a lot to process all at once. But you're not being pressured at the moment. There's space to wait.

    #See what you can infer from the conversation so far.
        *gosub_scene utils increase_empathy
        Roland said that Chloe's mentioned you a few times. He didn't have to say that.

        Is he hinting that you're important to her?

Roland sits up straight, and you find yourself doing the same. "You should be careful, ${first_name}. Chloe tends to push people hard."

Out of the corner of your eye, you see Chloe lean forward. "Roland..."

The siblings lock eyes, not a word being exchanged. You catch things: the corner of Chloe's mouth tightening for a fraction of a second, Roland blinking a bit slowly. But you can't piece them together without speaking their language.

A moment later, they both sink back into their seats. Roland sighs. "She doesn't know how much people can take. Just be careful."

"That's not true. People are tough."

Roland starts to say something, then stops and turns to you. "Anyway, ${first_name}, was nice to meet. I have to... see the Guangzhou team."

His cheek twitches slightly. Chloe scans his face, her mouth forming into a thin line.

"Roland, you're pushing yourself too hard. You don't need to..."

"Catch up later, ${first_name}." He's on his feet.

"Roland —"

But he strides past, and is out the door before she can finish.

*choice
    #Take Roland's warning seriously.
        Roland made the effort to warn you about Chloe, on your first meeting.

        Chloe's looking at the open doorway, mouth open in a slight frown. You notice that her arms are relaxed at her sides, hands unclenched.

    #Trust that people can take a lot.
        Chloe beamed and gave Roland a hug when she saw him. But at the end, he couldn't escape the room fast enough.

        Now she's standing still, looking at the open doorway, mouth open in a slight frown. You notice that her arms are relaxed at her sides, hands unclenched.

    #Wonder if both of them could be right.
        Roland paused before each answer, weighing every word. But Chloe kept cutting in, on instinct.

        Now she's looking at the open doorway, mouth open in a slight frown. You notice that her arms are relaxed at her sides, hands unclenched.

"I... guess it's time to go. Thanks for coming. I'll go down with you." She leads the way, past the cubicles, past the reception area. As the glass doors slide shut, Chloe lets out a long breath.

You're down on the ground floor and past the turnstiles and out into the lobby, height and brushed metal overhead, bodies streaming past. Near the edge of the lobby, the foot traffic thins out. Chloe faces you, inside your personal space, her arms by her sides. Her right hand is turned to you, palm out. A stocky man in a grey suit cuts close by, barking into his phone.

*choice
    #Thank her and say goodbye.
        You thank Chloe for introducing you to Roland, and wave goodbye.

        "I..."

        She trails off. Then: "See you again soon, ${first_name}. Thanks for coming."

        Her fingers pinch the back of her other hand, the skin turning white. You head for the MTR.

        *return
    #Ask her to accompany you to the MTR.
        *set chloe_friendship +1
        You ask Chloe to walk with you to the MTR. Your hands stay at your sides. She waits a moment more.

        Then her hand drops back. She says okay, and walks alongside you. She smooths out her blouse, then keeps her eyes forward.

        The walk back to the MTR station feels twice as long. You wait together at the crossing as the red figure stands frozen, the pedestrian chime counting down the seconds. Marks & Spencer, in beige metal and sheet glass, falls behind you, and next is HSBC, its red-and-white logo hard to ignore. The silence lasts until you reach the MTR entrance.

    #Ask her to accompany you to the MTR. Offer your hand.
        *set chloe_friendship +1
        *set chloe_romance +1
        "Let's go", you say, offering your hand.

        She takes your hand in hers, no hesitation. Her grip is steady, her palm warm. She squeezes your hand once, then loosens to a casual grasp.

        The walk back to the MTR station feels twice as long. You wait together at the crossing as the red figure stands frozen, the pedestrian chime counting down the seconds. Marks & Spencer, in beige metal and sheet glass, falls behind you, and next is HSBC, its red-and-white logo hard to ignore. People stream past, but Chloe doesn't let go of your hand. The silence lasts until you reach the MTR entrance.

At the top of the stairs, where the asphalt meets the tiled flooring, Chloe stops and faces you. "Roland liked you. Unfortunate..."

She keeps looking at you. Passersby keep moving around you, indistinct, a blur. She's waiting for your response, but you don't say anything.

*page_break
That night, you finally think of something you could have said.

*return

*comment Season is either "autumn" (October, November), or "winter" (December).
*label event_4
"We never go out on the boat together any more. You just use it to entertain now."

Roland smiles at Chloe. "Oh? I didn't know you still liked the banana boat."

"Meh. ${first_name}, do you like that stuff? Or are you more of a speedboat person?"

The three of you are in the lobby lounge of the Aberdeen Marina Club, all wearing dark blue polos and khakis, your polo a bit too dark. You're on a low sofa facing them, a coffee table between you, a drawstring bag of swimwear at your ankle. Near the lift, a staircase spirals up, and to your left is the marina, boats in rows behind the breakwater. Your eyes follow the sunlight as it streams in through the floor-to-ceiling windows, dancing and reflecting off the glass.

Wait, was Chloe saying something? Something about fruit or a boat?

*fake_choice
    #"I like the outdoors."
        "I like the outdoors."

        "Wow, we've got a real adventurer here! The outdoors!" Chloe says.

        She turns to Roland, whose faint smile hasn't changed.

    #"I like boats."
        "I like boats."

        "Boats. That's lucky, since we're about to go on one," Chloe says.

        She stays looking at you, in case there's more where that came from.

    #"I like fruit."
        "I like fruit."

        "Uh... that's good. I think the boat has some pomelos and mangoes," Chloe says. "I..."

        She stops and looks down at the thick carpet. Whatever she wanted to say, it's gone.

A tanned man in a white polo enters and stoops to Roland's ear. "Boat's ready, Mr Wong."

Roland thanks him, and the three of you follow him through the glass doors, down a ramp, and onto the pontoon.

"It's a bit rough out there today," the man says.

Roland glances up at the cloudless sky, then back at him.

"Monsoon surge last night, Mr Wong. Better to go to Deep Water Bay."

Chloe throws her head back and groans. As you reach the end of the pontoon, the marina ferry comes alongside. You board, and it crosses to the outer pontoon, where you alight.

*page_break
A few more steps and everyone stops. The boat is white paint and steel and wood in narrow strips. It looks to be three levels high, most of it enclosed behind brown-tinted glass. You see thick ropes coiled around a metal knob, a metal plank up on the roof, and a heap of flabby yellow plastic under a net. You resolve to become more nautical.

A walkway with railings extends from an opening in the railing and bridges the water to the pontoon. Roland goes across, then Chloe, and you follow. "Whenever you're ready," Roland says. Chloe has her forearms on the rail, gazing at the residential towers.

The engines rumble, and the floor shakes. Thick diesel fumes. The marina and the buildings slide away.

As the boat picks up speed, the spray soaks your polo cold against your back. Roland goes in and slides the door shut. Chloe leans on the railings and says, "It's nice out here!"

The boat drops with a thump and the water comes over the rail onto Chloe's face. She spits over the side and brushes her hair back. "But inside is good too."

She holds the door. You duck inside, into still, warm air.

*page_break
You leave your shoes outside the door. The carpet swallows your feet, dry and warm, as your polo loosens off your back. The door slides shut, and the engines drop to a hum. It's a single room about the size of a badminton court. Just inside are two sofas meeting in the corner around a low table, with a glass bowl on it holding dragonfruit, pomelos, pears, and mangoes. Past that, a drinks bar, an oval dining table, and a staircase spiralling up and down.

Aside from the engine hum, there's only the brush of feet on carpet and the clink of a glass. Roland's at the bar, dropping ice cubes into a tumbler, then pouring Scotch over them. A crew member appears. "Something to drink?"

Chloe replies, "Soda water, please."

*temp drink_choice ""
*fake_choice
    #"The same, please."
        *set drink_choice "soda water"
        "The same, please."

        The crew member turns and goes. You sit on one sofa, Chloe on the other, both at the corner. He returns with a silver tray in one hand and places two leather coasters onto the low table, then two tall glasses on them, both two-thirds full with fizzing water, two ice cubes each.
    #"Coke, please."
        *set drink_choice "coke"
        "Coke, please."

        The crew member turns and goes. You sit on one sofa, Chloe on the other, both at the corner. He returns with a silver tray in one hand and places two leather coasters onto the low table, then two tall glasses on them, both two-thirds full, one with fizzing water and the other with cola, two ice cubes each.

    #"Orange juice, please."
        *set drink_choice "orange juice"
        "Orange juice, please."

        The crew member turns and goes. You sit on one sofa, Chloe on the other, both at the corner. He returns with a silver tray in one hand and places two leather coasters onto the low table, then two tall glasses on them, both two-thirds full, one with fizzing water and the other with orange juice, two ice cubes each.

Roland comes over and takes the far end of Chloe's sofa and swirls his Scotch. He stares into the tumbler and smiles as the ice cubes go around, tinkling against the glass.

Chloe crosses one leg over the other, knee pointing at you. "${first_name}, you look like you're on a company trip. No, worse. You look like you're on a company trip and they're filming it for the website."

*choice
    #"Yeah, that's where I should be. Next to the 'Working hard or hardly working' banner."
        *set chloe_friendship +2
        "Yeah, that's where I should be. Next to the 'Working hard or hardly working' banner."

        Chloe's laugh cuts through the engine hum. "Oh, we know a thing or two about working hard, right, Roland?"

        Roland just swirls his Scotch, the faint smile still on his face.

    #"No way, I'd cover my face with a pomelo."
        *set chloe_friendship +1
        "No way, I'd cover my face with a pomelo."

        Chloe claps. "Join our team! Get your photo taken with a pomelo over your face!"

        Roland grunts a small laugh.

The engines cut out. A heavy clunk and the rattle of a long chain, then the boat sways gently. A crew member comes over. "Lunch is ready."

The three of you cross to the dining table, already set with large white porcelain dishes on white linen, silver forks, spoons, knives. In the middle is the spread: Caesar salad, roasted chicken drumsticks, steamed scallops in the shell with vermicelli, pork loin in gravy, Yeung Chow fried rice, roast beef.

"Let's eat." Roland has already lifted a scallop onto his plate and is turning it over in the soy sauce with his fork. Chloe scoops a helping of Caesar salad with fork and spoon, carries it towards your plate, then, halfway, sets it on her own plate instead.

"Tuck in, ${first_name}! Just get whatever you like. The scallops and the beef are great." She flashes you a smile.

Roland glances over, says nothing, then looks down and attacks his scallop.

*temp lunch_choice ""
*choice
    #Help yourself to a scallop and some roast beef.
        *set chloe_friendship +1
        *set lunch_choice "scallop"
        You pick up the fan-shaped shell of the scallop with your fingers and bring it to your plate. An enormous, plump, white scallop, framed by a ruffled skirt and a bulging orange roe, the shell half-full of soy sauce, a thin film of glistening oil across it, translucent vermicelli coiled around it all. The steam coming off it is soy and garlic and clean marine sweetness. You want to eat it right away, but instead you fork an inch-wide cube of roast beef onto your plate, turn it so the pink side faces up, and spoon a dab of mustard onto it. The smell of the ensemble is a violent mix of umami, salt, and a sharpness that stings the nostrils.

        You eat the roe first, a single slow chew, and it bursts between your teeth. Then the scallop itself, cut in half, two bites, chewy and springy and juicy, then the vermicelli — you resist gulping a spoonful of soy sauce along with it — and then the beef, tough to chew. But it's very beef-tasting.

        "Wow, you were right. This is really good."

        "Yeah. Only the best for you, ${first_name}!"

        You still can't read her face. How does she do that?

    #Turn to Chloe and offer her a cube of roast beef.
        *set chloe_friendship +1
        *set chloe_romance +1
        *set lunch_choice "beef"
        You lift an inch-wide cube of roast beef off the platter and hold it there with your fork, halfway to Chloe. A drop of jus falls onto the tablecloth, then another.

        "Chloe, would you like one?"

        Her eyes go to the beef, then to you, then down. "Oh, sure... thanks..."

        You set it down on her plate, pink side up, and spoon a dab of mustard on top. She takes her time with it. You take one for yourself, too, and the mustard stings your nose before you get it into your mouth. It's tough to chew. But it's very beef-tasting.

        "It tastes good, Chloe."

        "Glad you like it."

        You still can't read her face. How does she do that?

    #Scoop some fried rice onto your plate.
        *set lunch_choice "rice"
        You take the oversized serving spoon and heap a couple of scoops onto your plate. A few grains of rice spill onto the tablecloth. You pinch them up in your napkin and set it aside.

        The rice glistens, with egg strands, baby peas, [i]char siu[/i] bits, scallions, and shrimp. Steam comes off it, carrying scorched [i]wok hei[/i], sweet and smoky. You eat some. The flavour is nothing special. But the texture is: no grease, no clumps, every grain of rice loose and light, like warm water washing through your mouth.

        "This is great."

        "Glad you like it, ${first_name}!"

        Chloe's looking at you with that inscrutable face again. How does she do that?

For a quarter-hour you all eat in silence, the boat rocking under you, only cutlery clinking on porcelain. No one feels the need to talk. The scallops are gone, most of the other dishes down to a piece or two. Roland excuses himself to go to the bathroom.

Chloe watches Roland go. She sinks into her chair, both arms on the armrests.

"He's really good at his work, you know."

You say nothing. After a moment, she turns and waves a hand at the table, at the bar, at the windows.

"Do you like being here, with me?"

*choice
    #"Yes, I like being here."
        *set chloe_friendship +1
        "Yes, I like being here."

        "Good."

        The corners of her mouth lift up, then she catches the smile before it spreads. She sighs, although her body barely moves. "He doesn't mind at all. He likes it."

    #"I like being here. I like spending time with you."
        *set chloe_romance +1
        *set chloe_friendship +1
        "I like being here. I like spending time with you."

        "Good."

        She leans in, and the corners of her mouth lift up. Then she sighs, although her body barely moves. "He doesn't mind at all. He likes it."

    #"I like boating."
        "I like boating."

        "Good."

        Then she sighs, although her body barely moves. "He doesn't mind at all. He likes it."

Roland shuffles across the carpet and drops into his chair. Chloe straightens and plants her elbows on the table. A crew member brings out a plate of E-fu noodles in brown sauce, with mushroom slivers and yellow chives folded in. "That's all for lunch. Red bean soup for dessert whenever you'd like it."

Roland nods and lifts a clump of noodles to his plate. His mouth full, he asks Chloe, "So what do you want to do after lunch? I might go kayaking. Or take a nap."

Chloe shrugs. "Haven't thought about it yet. Speedboat maybe?"

Roland's phone buzzes against the table. He glances at it and frowns. "Give me a moment. It's K.W."

You only catch Roland's half: "We can't. Construction costs won't come down." "And the fit-out?" "Don't bid."

Roland shoves the phone into his trouser pocket and looks down at the noodles. "They do these really well. Kind of chewy, like QQ? I think that's what they call it."

Chloe sets her fork down and sits back. She folds her hands in her lap and stares at her plate.

*fake_choice
    #Make small talk with Roland.
        "I think QQ is for those tapioca balls in Taiwanese milk tea. But you're right, these noodles are nice and chewy."

        Roland's fork hovers, and a strand of noodle falls back onto his plate. Then he nods. "That sounds right."

    #Check in with Chloe.
        You turn to Chloe. "You okay, Chloe?"

        "Oh... huh? I'm fine. Nice noodles."

        Roland joins in. "Yeah, they're my favourite."

This is going nowhere. You try another angle: "So what about you, Roland? What do you like doing?"

Roland finishes his mouthful before answering. "Not much, really. Sometimes I see friends on Sundays. I mostly live at the office."

"What's that like?"

"Oh, you know, the usual. My dad runs the thing, but there's a lot to learn. Keeps me busy."

Chloe looks up from her plate. She isn't smiling. "Mostly live at the office? You have an entire ecosystem there."

Roland shrugs. "Hey, it's interesting. You get to see how everything works."

"Interesting."

*fake_choice
    #Watch Chloe.
        Chloe's hands are flat on the table. Her eyes are fixed on Roland.

        He sits back. "Eventually Dad's going to retire. Who else is it going to be?"
    #Watch Roland.
        Roland sets his fork down. His eyes are half-lidded.

        After a moment, he sits back. "Eventually Dad's going to retire. Who else is it going to be?"
    #Stay out of it.
        Family business. You replay the lunch instead.
        *if (lunch_choice = "scallop")
            Those scallops were really good.
        *elseif (lunch_choice = "beef")
            That beef was really good.
        *elseif (lunch_choice = "rice")
            The fried rice was really good.
        *else
            *bug Invalid lunch_choice

        Roland sits back. "Eventually Dad's going to retire. Who else is it going to be?"

"Yeah, and you'll do eighty-hour weeks, just like Dad."

"It comes with the territory. There's a cost to everything, Chloe."

"You don't have to do this. There are people who can run it."

"I know. But I want to."

Chloe opens her mouth. Nothing comes out.

A crew member appears, beaming, a tureen of red bean soup held in both hands. "Miss Wong's favourite!"

His eyes go to Chloe, then Roland. He sets the tureen down with a muffled [i]thunk[/i] and withdraws.

*page_break
You eat with small mouthfuls, the soup sweet and silky, the red bean husks chewy, a hint of bitterness from the dried orange peel. Water laps at the boat's outer edge. The crew in the boat kitchen have gone quiet. Roland works systematically through his bowl, nudging the two lotus seeds aside with his spoon. Chloe eats more slowly, her gaze fixed on a loose thread in the tablecloth.

Roland finishes first, then you, then Chloe. The tureen is still half full, but no one reaches for a second helping. Roland stands. "I'll take the kayak. See you in a bit."

He heads down the staircase. You and Chloe stay at the table. Roland comes back up in a wetsuit and strides out, sliding the glass door shut behind him.

Chloe turns from the door to you. "Speedboat? Or up top, to the deckchairs?"

*temp activity_choice ""
*choice
    #Take the speedboat.
        *set activity_choice "speedboat"
        "Let's go on the speedboat. Some fresh air would be nice."

        "Good idea, ${first_name}. No need to change. Let's go."

        She turns to the bar. "Ah Wing, could you get the speedboat ready?"

        You step out and put your shoes on. Roland is already well out, the kayak just a dark sliver. Behind you, an engine putters, and a small white boat comes out and stops beside the wooden ledge. The speedboat's about as big as a minibus and has two seats in the front and a U-shaped bench at the back. An engine hangs off the back of the boat, and a metal paddle is at each side of it.

        *if (chloe_romance >= 1)
            At the ledge, the speedboat rises and falls. Chloe takes your hand. She steps in as the boat rises and takes you across with her. She sits in the driver's seat, with you in the other one. Only then does she let go.
        *else
            At the ledge, the speedboat rises and falls. Chloe steps in as the boat rises and holds out her hand. You take it and cross, and she sits in the driver's seat while you take the other one.
        Firm pleather, cool through your khakis. Glare comes off the water, and you squint.

        Chloe puts a hand on the gearstick and the engine burbles. She puts her sunglasses on, then looks over and sees you squinting. She takes off the sunglasses and tosses them into the drinks holder.

        "Ready, ${first_name}?"

        You nod. She nods at the crew member on the ledge, and the rope comes off. She pushes the gearstick forward, and the boat pulls away from the ledge. She turns the steering wheel and the boat leans into a gentle curve, out towards the mouth of the bay, the opposite way from Roland.

        Once clear of other boats, she pushes the gearstick all the way forward. The front of the boat climbs, then smacks down flat, and again. Wind in your eyes. You open your mouth and the wind fills it, cold on your teeth, down your throat. Chloe's bob is coming apart.

        Every so often, there's a big wave. She doesn't slow much, taking them square on. The boat drops out from under you. Nothing else here, just the motor and petrol and salt. Chloe glances over, then turns back to the water.

        *page_break
        Chloe eases the stick back and the boat settles into the water. The engine drops to almost nothing. Her hair is everywhere.

        She looks straight ahead.

        "He wants to. What can I even do?"

        She's still holding the wheel.

    #Go up to the deckchairs.
        *set activity_choice "deck"
        "Let's hang out on the boat. It's a nice day."

        "Good idea, ${first_name}." Chloe raises a palm at you. She slides the door open, wind blowing in, and a few seconds later she's back.

        "Bit too cold for swimsuits. Don't bother changing, we'll just go up to the sun deck."

        *if (chloe_romance >= 1)
            She takes your hand and goes up the stairs ahead of you.
        *else
            She goes up the stairs ahead of you.
        Upstairs is a single room again, with two wide chairs side by side, a low table in front of them, a leather dice cup on it, and two decks of cards still wrapped in cellophane. Another drinks bar, the wine glasses hanging upside down. Next to it, a TV cabinet with a small LCD screen on top.

        Chloe slides the door open and the cold comes in. Outside, the deck is warm under your bare feet. Four loungers in a row, a plastic side table between the middle two, folded white towels piled on it. Chloe shakes out two towels and lays them on the loungers on either side of it. She lies back on one, arms at her sides, and you take the other.

        The sky is empty except for a black kite, beating its wings. Below, water splashes against the side of the boat. Up, pause, down. Up, pause, down. You sink into the lounger. You turn your head. Chloe's eyes are closed.

        *page_break
        You open your eyes. The kite is gone, and your mouth is dry. Did you fall asleep?

        Chloe has swung her legs over the side of her lounger, facing you, her elbows on her knees. She's watching you.

        "Everyone falls asleep on this boat. I got you an iced lemon tea."

        Someone's cleared the pile of towels. In its place are two tumblers of dark brown tea, three thick circles of lemon in each, and contraband plastic straws.

        You press the lemon slices with the straw, then drink. A lemon seed gets stuck in the straw, but you suck harder and it comes through. You chew on the seed, the bitterness lost in the sugar.

        Chloe drinks, then swings her legs back up onto the lounger and lies down.

        "He wants to. What can I even do?"

        She's holding the tumbler on her stomach. That must feel cold.

*choice
    #"Keep saying it. You're the only one he might listen to."
        *set chloe_acceptance -3
        "Keep saying it. You're the only one he might listen to."

        "Thank you. I was starting to think it was just me." The corners of her mouth lift.

        *if (activity_choice = "speedboat")
            Her eyes go to a sailboat out near an island. It leans over as a gust grabs the sail, then rights itself, and she watches it sail away.
        *elseif (activity_choice = "deck")
            She turns the tumbler on her stomach. A quarter-turn clockwise, another, then four the other way. The wet ring on her polo spreads. Clockwise again.
        *else
            *bug Invalid activity_choice
        "I just need to say it the right way. Let's see. I could book him a body check. He'll go if it's on his calendar. Or I could get him out more. He's only taken one call today."

        She stops. "But I've done all that. None of it's worked. We need a new angle."

    #"It's Roland's choice. You can't change people who don't want to change."
        *set chloe_acceptance +2
        "It's Roland's choice. You can't change people who don't want to change."

        *if (activity_choice = "speedboat")
            Her hands come off the wheel and open, palms up.
        *elseif (activity_choice = "deck")
            Her hands fall from the tumbler. It starts to tip, and she steadies it with a hand.
        *else
            *bug Invalid activity_choice

        "Can't change people? Of course you can."

        She's turned all the way towards you now, looking past your shoulder. "People change all the time. You find the right angle, say the right thing, and one day it's their own idea. Close enough, anyway."

        You keep your voice low. "Will he listen, though?"

        Chloe looks at you, her eyes bright, holding your gaze until you look away.
        *if (activity_choice = "speedboat")
            Then she turns back to the water.
        *elseif (activity_choice = "deck")
            Then her head goes back against the lounger, and she looks at the sky.
        *else
            *bug Invalid activity_choice

        "I'm not sure."

    #"Why does it matter so much to you?"
        "Why does it matter so much to you?"

        "Because he's my brother?"

        She rubs her chin. "Because he's stupid."

        You say nothing.
        *if (activity_choice = "speedboat")
            Her shoulders drop. Her eyes stay on the water.
        *elseif (activity_choice = "deck")
            She brings a forearm up over her eyes.
        *else
            *bug Invalid activity_choice
        
        "I'll lose him. It was hard enough getting him out here today."

*page_break
*if (activity_choice = "speedboat")
    She turns the wheel and the boat comes around. She barely pushes the gearstick, and you ride the waves one at a time. You squint into the water, the glare bright in the low sun. The speedboat comes in against the wooden ledge. A crew member ropes the speedboat to a knob, and Chloe steps off, then you follow, leaving your shoes outside the door.

    "Let's go up. More comfortable there."

    *if (chloe_romance >= 1)
        She takes your hand and goes up the stairs ahead of you.
    *else
        She goes up the stairs ahead of you.
    It's a single room again, with two wide chairs side by side, a low table in front of them, a leather dice cup on it, and two decks of cards still wrapped in cellophane. Another drinks bar, the wine glasses hanging upside down. Next to it, a TV cabinet with a small LCD screen on top.

*elseif (activity_choice = "deck")
    The sky's empty. The water sparkles in the low sun. After a while, she sits up, drinks the rest of her tea, and sets the tumbler down.

    "Let's go inside. It'll get cold soon."

    She slides the door open and warm air comes out at you.
*else
    *bug Invalid activity_choice
You sit in one of the wide chairs. Chloe crouches at the TV cabinet and hauls out a tangle of wires and plastic. A Super Famicom, its cables running up to the back of the screen.

"Want to play something, ${first_name}?"

She rifles through the cartridges: [i]Super Mario World[/i], [i]Street Fighter II[/i], [i]Super Bomberman[/i]. She shoves [i]Super Bomberman[/i] into the slot and brings two controllers over.
*if (chloe_romance >= 2)
    She sits down in the same chair, her thigh against yours. A tight fit. She hands you a controller.
*else
    She sits down in the chair next to yours, close enough that your shoulders almost touch. She hands you a controller.

*choice
    #Lean into Chloe.
        *set chloe_romance +1
        You lean into Chloe, your shoulder against hers.

        She keeps her eyes on the screen, breezing through the menus. Battle Game, two computer opponents. She settles into you.

        "Ready?"

        Your thumbs rest on the buttons. "Ready."

    #Lean towards the screen.
        You lean forward, thumbs resting on the buttons. Chloe does the same, breezing through the menus. Battle Game, two computer opponents.

        "Ready?"

        "Ready."

*set chloe_friendship +1
*return

*label event_5
Rain since noon. Your socks are wet. The 58 minibus winds down the coast, wipers scraping the windscreen, and you step off at Cyberport and run the few metres into the Arcade. Inside, the air doesn't move, and the escalators are stopped, waiting for someone to ride them. You shake the water out of your hair and stop at the glass, checking your reflection. Good enough. You look through the glass into the downpour: low buildings of metal and glass, strips of lawn, the towers of Residence Bel-Air backstopping it all.

You cross through to Le Méridien, where the air conditioning chills your neck, jazz music somewhere behind it. Chloe is on the round sofa that wraps around the lobby pillar, palms on her thighs, small handbag beside her. Tonight, she's wearing a cream short-sleeved knit top, loose indigo trousers and black flats.

"${first_name}! Glad you could make it." Her voice is flat, pleasant.
*if (chloe_romance >= 2)
    She hugs you, a hand on your back, pulling you in. Then she takes your hand and leads you through the Latitude 22 lounge into Umami.
*elseif (chloe_romance = 1)
    She takes your hand and leads you through the Latitude 22 lounge into Umami.
*else
    She leads you through the Latitude 22 lounge into Umami.

The manager at the reception stand greets Chloe by name and walks the two of you through the dining area to the private room at the back. A sushi counter at one end, the glass case laid out with cuts of fish in white, orange, red, even silver. Opposite, floor-to-ceiling glass, and behind it the garden, lit from below, clipped hedges and pebbles and a small koi pond. The room could seat eight, but it's set for two.

"The set menu is usually pretty good here. You can choose the mains, if you'd like."

Appetisers of sakura shrimp seaweed salad, deep-fried baby horse mackerel, radish in spicy soy sauce, and dried cod chips; two mains out of three; miso soup and rice; dessert. The choices are ginger pork shogayaki, teppanyaki salmon in butter sake sauce, and teppanyaki ox tongue cubes with fried garlic.

Chloe is still reading. Her menu must be more interesting than yours.

*temp pork false
*temp salmon false
*temp oxtongue false
*choice
    #Order the pork and the salmon.
        *set pork true
        *set salmon true
    #Order the pork and the ox tongue.
        *set pork true
        *set oxtongue true
    #Order the salmon and the ox tongue.
        *set salmon true
        *set oxtongue true
    #Let Chloe choose what to order.
        *set salmon true
        *set oxtongue true
Chloe raises a hand. The manager arrives, and she tells him the order. He scoops up the menus and leaves. Someone sets down two tumblers of water.

Chloe looks at you, at your mouth rather than your eyes. "How was your day?"

"Um. Good? Another average Friday at work. How about you?"

"Good. Average Friday for me too."

More small talk, and then the food arrives. A small bowl of sakura shrimp seaweed salad each, and the mackerel, radish, and dried cod chips in the middle.

"Bon appétit!" She eats her salad. You eat yours — it's too salty. The mackerel is crisp and comes apart into white flakes and steam, and the cod chips crunch between your teeth.

The waiter clears the bowls. Chloe watches him leave.

*page_break
"${first_name}, I've been thinking."

You take a drink of water, then set the tumbler down.

"When we fought... after the first round..."

Chloe's hands are flat on the table, her nails gone white. She's looking down at them. "I'm sorry for standing on you."

She looks up, finds you looking back, and looks past you to the sushi counter. "I mean, there wasn't any damage —"

*if (chloe_trauma >= 1)
    Her hands go to her lap. "No, I have my own stuff going on, but that's not an excuse. I frightened you."
*else
    Her hands go to her lap. "No, I have my own stuff going on, but that's not an excuse."

*if highest_trait = "analysis"
    She apologised for what she did. She didn't give a reason.
*elseif highest_trait = "composure"
    You don't answer. She doesn't fill the silence.
*elseif highest_trait = "empathy"
    Right now, she's not reading your face.
*else
    *bug Invalid highest_trait

*choice
    #"Thank you. I believe you."
        *set chloe_apology "accept"
        *set chloe_friendship +2
        "Thank you. I believe you."

        Chloe meets your eyes. Then she glances at your mouth, your hands, and back to your eyes.

        "Thank you, ${first_name}."

        Neither of you says anything. She drinks her water. Behind her, rain runs off the hedges, and the pebbles shine.

        Chloe tucks her hair behind her ear and sits back. "Let's get the mains."
        
    #"I forgive you. But don't ever test me again."
        *set chloe_apology "boundaries"
        *set chloe_friendship +2
        "I forgive you. But don't ever test me again."

        Chloe meets your eyes. Then she glances at your mouth, your hands, and back to your eyes.

        "Thank you, ${first_name}. I won't."

        Neither of you says anything. She closes her hand around her tumbler and watches the water settle. Behind her, rain runs off the hedges, and the pebbles shine.

        She nods. "It's your call, not mine."

        She tucks her hair behind her ear. "Shall we have the mains?"

    #"I'm not ready to forgive you for that."
        *set chloe_apology "reject"
        "I'm not ready to forgive you for that."

        Chloe meets your eyes. Then she glances at your mouth, your hands, and back to your eyes. She starts to say something, but doesn't.

        "I understand. You don't owe me forgiveness."

        Neither of you says anything. She closes her hand around her tumbler and watches the water settle. Behind her, rain runs off the hedges, and the pebbles shine.

        She straightens. "We should get the mains."

*page_break
*comment First main
*if (pork)
    *if (salmon)
        A waiter brings in the mains: glossy pork slices and two thick salmon fillets in a pale gold sauce. Steam rises from both, and butter and char reach you from the salmon.

    *elseif (oxtongue)
        A waiter brings in the mains: seared cubes of ox tongue on crisp golden garlic chips, and glossy pork slices. Steam rises from both, and ginger and soy reach you from the pork.
    *else
        *bug Invalid food choice
    Rice and miso soup follow, the soup in lacquered bowls.

    You eat. A slice of pork, a mouthful of rice. Sweet and salty, and the burn of ginger. The pork gives under your teeth.

*elseif (salmon)
    *if (oxtongue)
        A waiter brings in the mains: two thick salmon fillets in a pale gold sauce and seared cubes of ox tongue on crisp golden garlic chips. Steam rises from both, and butter and char reach you from the salmon.
    *else
        *bug Invalid food choice
    Rice and miso soup follow, the soup in lacquered bowls.

    You eat. A cube of ox tongue, a mouthful of rice. Salt and char, and the garlic crunches.
*else
    *bug Invalid food choice

*if (chloe_apology = "accept")

    "Wow, this is good."

    Chloe's mouth is full. She swallows fast. "Isn't it?"

*elseif (chloe_apology = "boundaries")

    "This is good."

    Chloe's mouth is full. She swallows fast. "Isn't it?"
*elseif (chloe_apology = "reject")
    Chloe eats without looking up.
*else
    *bug Invalid chloe_apology

*comment Second main
*if (pork)
    *if (salmon)
        You press your chopsticks through the salmon fillet, and the skin snaps. Translucent pink at the centre. A mouthful of rice with it. Butter and sake, and the salmon melts.

    *elseif (oxtongue)
        A cube of ox tongue, a mouthful of rice. Salt and char, and the garlic crunches.

    *else
        *bug Invalid food choice

*elseif (salmon)
    *if (oxtongue)
        You press your chopsticks through the salmon fillet, and the skin snaps. Translucent pink at the centre. A mouthful of rice with it. Butter and sake, and the salmon melts.

    *else
        *bug Invalid food choice
*else
    *bug Invalid food choice

*if (chloe_apology = "accept")
    "This one is great too."

    "I know!" She talks through the food.

    You finish the rice, then the miso soup.
*elseif (chloe_apology = "boundaries")
    "This is good too."

    Chloe waits until she's swallowed. "Yeah, I like this one even more."

    You finish the rice. The miso soup's lukewarm now, but you still drink it.
*elseif (chloe_apology = "reject")
    Chloe looks up from her plate. "Tastes pretty good."

    "Yeah."

    You finish the rice. The miso soup's lukewarm now, but you still drink it.
*else
    *bug Invalid chloe_apology

The waiter clears the plates and bowls.
*if (chloe_apology = "accept")
    Chloe leans her elbows on the table and asks you things. Where you grew up. What your parents do. What you'd usually be doing tonight.
*elseif (chloe_apology = "boundaries")
    Chloe asks you things. How long your commute is. How your training's going. What you'd usually be doing tonight.
*elseif (chloe_apology = "reject")
    Chloe looks past you to the sushi counter. You watch the garden.
*else
    *bug Invalid chloe_apology

The waiter sets down two glasses of matcha jelly, a film of dark syrup on top. The matcha is strong and barely sweet.

"My car's outside," Chloe says. "We can drive you back, if you'd like."

Your socks are still damp. You say yes.

*page_break
A black BMW waits in the driveway, engine idling. The driver's door opens, and a stocky man steps out, puts up an umbrella, and opens the rear door. Chloe gets in and slides across to the far side. You get in and pull the door after you. It doesn't budge.
*if highest_trait = "analysis"
    Way too heavy.
*elseif highest_trait = "composure"
    You put your hands in your lap.
*elseif highest_trait = "empathy"
    Chloe starts to turn towards you, then doesn't.
*else
    *bug Invalid highest_trait
The driver closes it and gets back in behind the wheel.

You tell Chloe the address, and she passes it to the driver. The car pulls out onto the road.

Through the tinted glass, the sea is black against the charcoal sky. Streetlights come and go. Rain on the roof, wipers, tyres on wet road. No radio.

*if (chloe_apology = "reject")
    Chloe looks from her window to you. "I hope you liked the dinner tonight."

    "Yes, I liked it."

    She turns back to the window. Streetlights come and go. "I'd like to see you again."

    "Yeah. I think so."

    The car enters the tunnel and the rain cuts out. Just the rumble now, low, echoing off the walls. No one says anything. Out the other side, the rain has eased to a drizzle.

    Mong Kok. The car slows to a crawl in the narrow streets and stops across from your building on the double yellow lines, hazard lights blinking. The driver comes round to your side and pulls the door open. You step out, and your socks squish in your shoes.

    "Goodnight, ${first_name}."

    "Goodnight, Chloe."

    Chloe leans across the seat and heaves the door shut with both hands. The car pulls away and disappears around the corner.

    *return

*elseif (chloe_romance >= 2)
    *if (chloe_apology = "accept")
        Chloe looks from her window to you. "I hope you liked the dinner tonight. It's a bit out of the way, I know. There's a nice lawn down by the water. I was hoping we could take a walk there after dinner, but the weather's no good."

        "I liked it. I'd enjoy walking with you."

        She crosses her legs. "There's something else I wanted to ask. I didn't know if it would be okay to bring it up..."

        She glances at the driver. The driver's eyes are on the road.

        She turns her head. "${first_name}. Would you want to be with me?"

    *elseif (chloe_apology = "boundaries")
        Chloe looks from her window to you. "I hope you liked the dinner tonight. It's a bit out of the way, and nobody's ever there. But that's why I like it."

        "I liked it. Thanks for asking me."

        She crosses her legs. "I asked you here to apologise. But there's something else I wanted to ask, too. I didn't know if it would be okay to bring it up..."

        She glances at the driver. The driver's eyes are on the road. She nods at nothing. "I think it's okay to ask."

        She turns her head. "${first_name}. Would you want to be with me?"

    *else
        *bug Invalid chloe_apology

    *choice
        #"Yes, I would." [i](Be her partner.)[/i]
            *set chloe_friendship +1
            *set chloe_partner true
            "Yes, I would."

            Chloe turns her whole body towards you. A streetlight sweeps across her face and is gone.

            She breathes out. Her hands come up and stop halfway between you.

            "${first_name}."

            Her hand comes down on the back of yours. You turn your hand over and take it. Her palm is damp and hot.

            The car enters the tunnel and the rain cuts out. Just the rumble now, low, echoing off the walls. You both face forward. Every so often, her hand tightens, then eases.

            Out the other side, and the rain has eased off. Chloe turns to you and grins. "I think this could be good."

            "I think so too."

            Mong Kok. The car slows to a crawl in the narrow streets and stops across from your building on the double yellow lines, hazard lights blinking. The driver comes round to your side and pulls the door open.

            You let go of her hand. You step out, and your socks squish in your shoes.

            "Goodnight, Chloe."

            "Goodnight, ${first_name}."

            She stays facing you until the car disappears around the corner.

        #Kiss her. [i](Be her partner.)[/i]
            *set chloe_friendship +2
            *set chloe_partner true
            You turn in your seat and lean across the gap. Chloe goes still. Then she turns her face to yours.

            You close the distance and your noses bump. Her hand's on your back, pulling you in, and her mouth opens against yours. She does the rest. Her fingers close on your shirt.

            She lets go and sits back. You sit back too. Her face is blank, her cheeks red.

            She takes your hand in hers. Her palm is damp and hot.

            The car enters the tunnel and the rain cuts out. Just the rumble now, low, echoing off the walls. You both face forward. Every so often, her hand tightens, then eases.

            Out the other side, and the rain has eased off. Chloe turns to you and grins. "I think this could be good."

            "I think so too."

            Mong Kok. The car slows to a crawl in the narrow streets and stops across from your building on the double yellow lines, hazard lights blinking. The driver comes round to your side and pulls the door open.

            You let go of her hand. You step out, and your socks squish in your shoes.

            "Goodnight, Chloe."

            "Goodnight, ${first_name}."

            She stays facing you until the car disappears around the corner.

        #"I'm sorry, Chloe. I don't want that." [i](Stay friends.)[/i]
            "I'm sorry, Chloe. I don't want that."

            Chloe's mouth tightens, then goes flat. She searches your eyes. Then she faces the front.

            "Okay."

            The car enters the tunnel and the rain cuts out. Just the rumble now, low, echoing off the walls.

            Chloe turns her head. "We're still going to see each other?"

            "Yeah. Of course."

            Mong Kok. The car slows to a crawl in the narrow streets and stops across from your building on the double yellow lines, hazard lights blinking. The driver comes round to your side and pulls the door open.

            You step out, and your socks squish in your shoes.

            "Goodnight, ${first_name}. See you soon."

            "See you soon, Chloe."

            Chloe smiles, leans across the seat and heaves the door shut with both hands. The car pulls away and turns the corner.

*else
    *if (chloe_apology = "accept")
        *set chloe_friendship +1
        Chloe looks from her window to you. "I hope you liked the dinner tonight. It's a bit out of the way, I know. There's a nice lawn down by the water. I was hoping we could take a walk there after dinner, but the weather's no good."

        "I liked it. I'd enjoy walking with you."

        The car enters the tunnel and the rain cuts out. Just the rumble now, low, echoing off the walls. No one says anything. Out the other side, the rain has eased to a drizzle.

        Mong Kok. The car slows to a crawl in the narrow streets and stops across from your building on the double yellow lines, hazard lights blinking.

        She turns to face you. "You're a good friend, ${first_name}."

        "You too, Chloe. Thanks for tonight."

        "See you soon, ${first_name}."

        The driver comes round to your side and pulls the door open. You step out, and your socks squish in your shoes.        
        
        Chloe smiles, leans across the seat and heaves the door shut with both hands. The car pulls away and turns the corner.

    *elseif (chloe_apology = "boundaries")
        *set chloe_friendship +1
        Chloe looks from her window to you. "I hope you liked the dinner tonight. It's a bit out of the way, and nobody's ever there. But that's why I like it."

        "I liked it. Thanks for asking me."

        The car enters the tunnel and the rain cuts out. Just the rumble now, low, echoing off the walls. No one says anything. Out the other side, the rain has eased to a drizzle.

        Mong Kok. The car slows to a crawl in the narrow streets and stops across from your building on the double yellow lines, hazard lights blinking.

        She turns to face you. "You're a good friend, ${first_name}."

        "You too, Chloe. Thanks for tonight."

        "See you soon, ${first_name}."

        The driver comes round to your side and pulls the door open. You step out, and your socks squish in your shoes.        
   
        Chloe smiles, leans across the seat and heaves the door shut with both hands. The car pulls away and turns the corner.

    *else
        *bug Invalid chloe_apology

*return

*label event_6
Lan Kwai Fong on a Sunday morning: stools upside down in darkened bars, a sun-bleached poster by a lift entrance — 15 SHOTS $600 — and office towers, a single light on somewhere above. Two men walking down the middle of the road.

You and Chloe walk down D'Aguilar Street towards Roland's office. He's meeting you both for lunch.
*if (chloe_partner)
    Chloe's got your hand, half a step ahead. She points at Ebeneezer's. Once, her friend ordered the chicken instead of the lamb.

    "And?"

    She smacks your shoulder and laughs.

    Then you're downstairs from Roland's office. You kiss her, and she smiles at you. The two of you wait in the lift lobby.

*else
    You point at the pigeons picking through the rubbish outside the 7-Eleven. Big morning for them. Chloe agrees, then points at Ebeneezer's. Once, her friend ordered the chicken instead of the lamb.

    "And?"

    She claps you on the shoulder and laughs.

    Then you're downstairs from Roland's office. The two of you wait in the lobby, just one lift running.

No Roland. Chloe clicks her tongue. "Let's just go up. He'll be on the phone."

Chloe taps her pass and signs you in. You take the lift up together.

*page_break
No one's at the reception counter. You follow Chloe past the cubicles, all dark, to the corner office. The door's open and Roland's typing. He waves. Chloe waves back and drops onto the sofa. You sit next to her.

*if highest_trait = "analysis"
    Dozens of dark workstations, a single lighted office. Many things are decided at the top.
*elseif highest_trait = "composure"
    No need to fill the silence. You wait for Roland.
*elseif highest_trait = "empathy"
    Everyone else's desks are empty, and Roland is here, alone.
*else
    *bug Invalid trait
He clicks, types, picks up the desk phone, hangs up, types more. Chloe takes out her phone. 12:10. "Should have left ten minutes ago."

Roland holds up his palm. "Give me five more minutes."

His mobile rattles against the desk. He answers it, then stops talking and listens. Less than half a minute. "Sorry, I can't get out before one o'clock. You two start without me. I'll come by after."

Chloe puts her phone away. "It's Sunday, Roland."

"Dad said the bid has to go in tomorrow. I told him I'd handle it."

"When was the last time you had a day off?"

The typing stops. "On the boat, I guess?"

"That was weeks ago."

*fake_choice
    #"We can get a table first."
        "We can get a table first."

        Chloe's quiet for a moment. "We could. Or we could have lunch together like normal people."

    #"You could probably use a lunch break."
        "You could probably use a lunch break."

        Chloe keeps her eyes on Roland. "${first_name}'s right."

    #Stay out of it.
        You keep quiet. Under the desk, the computer hums, dust caked over the fan grille.


Roland looks up from the screen. "Busy season. Everything before Christmas. You know that."

Chloe stands and plants herself in front of his desk. "Come on, have lunch first!"

"It's urgent."

Chloe comes around the desk and reaches for the mouse. Then her hand pulls back. She returns to the front of the desk and turns to you instead. She folds her arms.

*choice
    #Notice that her hand stopped.
        *gosub_scene utils increase_composure
        She could have shut the computer down, but she decided not to.

    #Consider what she's feeling.
        *gosub_scene utils increase_empathy
        Lunch isn't the point. She's frightened.

    #Observe the pattern.
        *gosub_scene utils increase_analysis
        Roland chooses the work, Chloe pushes back. Same as on the boat.

"You're an idiot, Roland. You're choosing this."

"I am."

Chloe's arms drop to her sides. Her shoulders go up, down. She tries to say something, but the words don't come.

Tears run down her face.

She turns to face Roland. She's talking just to him now. "You're killing yourself. I can't watch you do this."

Roland stands and comes around the desk. Chloe puts her arms around him and puts her forehead on his collar. Roland puts a hand between her shoulder blades. The other one rests on her hair. You hear Chloe breathing, not much else. The computer monitor dims.

The mobile rattles against the desk again. He looks at it, but that's all. It stops. Chloe lets go.

"One moment." He picks up the phone and goes out into the cubicles. Chloe wipes her cheek with the back of her hand. She stays looking at the empty chair.

*choice
    #"He's heard you."
        *set chloe_acceptance +6
        "He's heard you."

    #"Don't give up on him."
        *set chloe_acceptance -6
        "Don't give up on him."

Chloe turns round and looks at you. She keeps looking. She doesn't say anything. She crosses to the sofa and sits down next to you.

Roland comes back in. "I'll be as quick as I can. Sorry about this."

Neither of you answers.

You both stay on the sofa. The typing starts again.

*page_break Later.
Wednesday evening.

You and Chloe are both leaning back in your chairs. Paradise Dynasty, second floor of Grand Plaza. Chloe doesn't stick out in her plain black T-shirt, beige cropped trousers, and flats. You're in your office clothes. Your hands rest on your stomach, empty steamer stacks between you, the vinegar in the saucers gone thin and cloudy with dumpling broth, ginger slivers and a dark patch soaking into the cloth by Chloe's saucer. They do a good eight-flavour [i]xiao long bao[/i] here, but the cheese one was a mistake.

She puffs out her cheeks and blows out a long breath. "Whew. That was a lot. I don't know if I can even stand up!"

*if (chloe_partner)
    Then she stands up instantly and motions you to leave. "Can I see your flat?"

    "It's small."

    "So...?"

    Down the escalators and out onto Nathan Road. Two streets and you're at your building. Waiting for the lift, she takes your hand in both of hers. She's half a step behind you.

    You try to remember what state you left it in, then turn the key. Chloe stops just inside the door. Fold-up bed, pull-up bar, gloves on the desk. She kicks off her flats and puts an arm around your waist.

    "I like it here."

    *fake_choice
        #"It's enough for me."
            "It's enough for me."

            Chloe nods at the pull-up bar. "All the necessities. Don't need that much."

            She leans closer.

        #"I like having you here."
            "I like having you here."

            "Yeah?"

            "Yeah."

            She pulls you in. "Good."

    Then she lets go. "I could use a drink. You?"

    She crosses to the fridge, crouches, opens it. A carton of eggs and three apples. She closes it and fills two tumblers from the jug on the counter. She comes back, a tumbler in each hand.

    "There's only one chair, though?"

    "Yeah, I don't get visitors much."

    She puts both tumblers in your hands and turns to the fold-up bed. "We'll just have to make one, then!"

    You nod and she hauls it down with both hands. You give her a tumbler and sit down beside her. The frame creaks. You both drink.

    She finishes hers, takes yours out of your hand, and puts them both in the sink. On the way back she stops at your calendar, flips to July, reads your notes, and flips it forward to ${current_month}.

    "A chaotic performer! Why, thank you!"

    "My scouting's pretty good, huh?"

    She laughs. She sits down again, closer, her thigh against yours. She kisses you once and sits back.

    "I want to have sex with you. Right now. Do you?"

    *choice
        #"Yes, I do."
            "Yes, I do."

            She hooks an arm behind your shoulder and kisses you. She puts a palm on your chest and pushes. You land on your back and she's all over you, kissing you harder, mouth pressing against yours.

            Your hands go behind her head, into her hair. She breaks the kiss, breathing hard, and grins. She takes both of your wrists and holds them down on the mattress above your head. She keeps you there and watches you.
            
            *if (chloe_trauma = 0)
                You give one wrist a pull. Her palm follows it down, keeping it there.

                You pull again, and she lets go. Her grin widens.

            *elseif (chloe_trauma = 1)
                You give one wrist a pull. She holds it there, for a moment. You pull again and it comes free.

                You smile, and her grin widens.

            *elseif (chloe_trauma = 2)
                You give one wrist a pull. She lets go the moment you move.

                She stays where she is, hands open above your head. You put your hand back where it was. Her hand covers your wrist again, barely touching. She grins.

            *else
                *bug Invalid chloe_trauma

            "You liked that."

            Her cheeks go red. She glances at the pull-up bar and laughs, once. "Shut up."

            She sits up, weight on your hips, and places her hands flat on your chest. She takes a breath. "Fine. I like being in control."

            "Oh, like when you stood on me?"

            *temp pc_response ""
            *temp stood_on_you false
            *if (chloe_trauma = 0)
                She stops grinning and leans down over you. Whatever she's looking for, she finds it. The grin's back, and she straightens up, hands on hips.

                "I'd do it again."
                *set pc_response "I bet you would."

            *elseif (chloe_trauma = 1)
                She stops grinning and leans down over you. Whatever she's looking for, she finds it. The grin's back, and she straightens up, hands on hips.

                "I did like it."
                *set pc_response "I bet you did."

            *elseif (chloe_trauma = 2)
                She stops grinning. She leans down over you and doesn't say anything. Whatever she's looking for, she finds it.

                "I did like it." Then nothing for a moment.

                "But I wouldn't do it again."

                She waits.
                *set pc_response "Probably for the best."

            *else
                *bug Invalid chloe_trauma

            *choice
                #${pc_response}
                    *if (chloe_trauma = 0)
                        You put your hands behind your head. ${pc_response}

                        Chloe rests a palm on your chest. "You don't know what you're missing."

                        "I'll survive."

                        You pull her back down.

                    *elseif (chloe_trauma = 1)
                        You put your hands behind your head. ${pc_response}

                        Chloe rests a palm on your chest. "Limited-time offer, you know."

                        "I'll survive."

                        You pull her back down.

                    *elseif (chloe_trauma = 2)
                        You breathe in, all the way. ${pc_response}

                        Chloe lowers herself onto you. "Yeah. Probably."

                    *else
                        *bug Invalid chloe_trauma

                #"Go on, then." Lie on the floor.
                    *set stood_on_you true
                    *if (chloe_trauma = 0)
                        "Go on, then." You pat her thigh and she rises. You get down on the floor beside the bed, flat on your back.

                        Chloe stays on the bed, on her knees, arms straight, hands on the edge of the mattress. "Are you serious?"

                        "Serious."

                        She swings around to sit on the edge of the mattress. She places one foot on your chest, the other on your stomach, and leans forward off the mattress. Your chest rises under her. She's not grinning any more; her eyes are on you.

                    *elseif (chloe_trauma = 1)
                        "Go on, then." You pat her thigh and she rises. You get down on the floor beside the bed, flat on your back.

                        Chloe stays on the bed, on her knees, arms straight, hands on the edge of the mattress. "You actually want me to?"

                        "I do."

                        She swings around to sit on the edge of the mattress. She places one foot on your chest, the other on your stomach, and lets some weight down. Your chest rises under her. She's not grinning any more; her eyes are on you.

                    *elseif (chloe_trauma = 2)
                        "Go on, then." You pat her thigh and she rises. You get down on the floor beside the bed, flat on your back.

                        Chloe stays on the bed, on her knees, arms straight, hands on the edge of the mattress. "${first_name}."

                        "You said you wouldn't. I'm asking you to."

                        She comes down onto her forearms, her face above yours. "Are you sure?"

                        "Yes."

                        She straightens and swings around to sit on the edge of the mattress. She rests one foot on your chest, the other on your stomach. Her eyes are on you.
                    *else
                        *bug Invalid chloe_trauma

                    Bare soles, warm through your shirt. "Tense your core."

                    You brace. She presses down once, testing. Then her weight comes off the mattress. She holds still, arms at her sides.

                    You breathe in, all the way. Easy. Her weight goes down, through you, into the floor. You give her a thumbs-up.

                    She stops watching your face, and her breathing settles. She sways from foot to foot. The foot on your chest moves down, both feet on your stomach now, together. Your stomach holds.

                    You watch her. You lose track of how long she's up there.

                    Too soon, she sits back on the mattress and lifts her feet off you.

                    "Wow. Fuck. Get back up here."

                    You shake out your shirt and clamber up.

            She kisses you, and keeps kissing you, barely stopping to breathe, then her mouth moves to your neck, and her hands go wherever they like. Your shirt goes first. She takes her T-shirt off herself, flinging it behind her, and it lands on your desk. She guides your hands round to the clasp at her back and lets go.

            Off go the trousers, the underwear, all of it. She's on top again, all her weight on you, hair in your face. The frame creaks, and creaks, and creaks.

            She takes both of your hands and holds them down on the mattress above your head, fingers interlaced. You squeeze back.

            *page_break
            You're face down on the mattress, cheek on the pillow. Your neck complains. You don't move. Chloe sits by your head, thumbs making circles behind your ears.

            "${first_name}, you're good."

            "In bed?"

            "Good in general. Wait, I didn't mean it that way. You're good in bed too."

            "Glad we cleared that up."

            She laughs and pinches your earlobe. Her hands move down to your shoulder blades. Your shoulders loosen.

            Her voice drops. "How was that? Too much?"

            *if (stood_on_you)
                "No. I could've taken more."

                "Next time, then."
            *else
                "No. You're fine."

            She collects the clothes off the floor. Yours land in a pile next to your head, and she starts dressing. You push yourself up, sit, then dress.

            She leans into your shoulder. "I'm an angel, you know."

            "I know."

            Someone downstairs thumps the ceiling three times, then nothing. You take her hand.

        #"No, I don't."
            "No, I don't."

            "Aww, okay." She scratches the back of your head and kisses your cheek. She rests her head on your shoulder.

            "So what do you actually do here besides sleep?"

            "Mostly just eat."

            "Wow. Living the dream."

            You talk for a long time, about work, training, the circuit.

            Chloe checks her phone. "My driver will be here soon."

            She stays just a while longer.

*else
    Then she stands up instantly and motions you to leave. "Have you been to the new dessert place on Fa Yuen Street? We have to go! And I need to buy new sunglasses. Tell me which pair is the least stupid-looking."

    "It's night now."

    "Yeah, but what if I trip? Without sunglasses on, I'd have no excuse."

    Down the escalators and out onto Nathan Road, the crowd closing around you. You turn left, cross Sai Yeung Choi Street, and point along it. There used to be buskers the entire way. Chloe looks up the street and doesn't say anything.

    "Here we go." Chloe stops in front of an unmarked set of stairs. Up the stairs to a brushed chrome door, which Chloe pushes open. Wooden cabinets line the walls, glass-topped cases down the middle. A young man in a blazer greets you both and goes to stand behind the counter. Mostly regular frames, the sunglasses maybe a third of it.

    The frames are thick or thin, round or square, plastic or metal. Past that, you can't tell them apart. Chloe points at one, thin metal, square corners. The assistant takes them out and hands them to her. She puts them on and turns to you. "Well?"

    *temp first_sunglasses_ok true
    *choice
        #"Fashionable. Classic."
            "Fashionable. Classic."

            She grins. "I have good fashion sense, huh?"

            "Why did you have to ask me, then?"

        #"Kind of boring, honestly."
            *set first_sunglasses_ok false
            "Kind of boring, honestly."

            She narrows her eyes. "Okay, you pick one then!"

            "Hey, you're the one who needs anti-trip sunglasses."

        #"Nice. Chloe Wong, CPA."
            *set first_sunglasses_ok false
            "Nice. Chloe Wong, CPA."
            
            She looks up and away from you, like she hasn't heard. "Wow! Was anyone saying anything? Looks like no."

    She hands the glasses back and goes down the line of cabinets. At the last cabinet, she spots a pair of thick round frames, each lens the size of her palm. She points, grinning, and the assistant lifts them out.

    "${first_name}! This one's for you!"

    "I would never wear something so stupid, Chloe. But you, on the other hand..."
    
    "What? What about me?"

    "Nothing. I'll try them on if you do." You take them from her and put them on. She laughs. You take them off and put them on her. She gives a thumbs-up and you take a photo.

    "Very good," you say. "You look like a sea turtle."

    She blows a raspberry at you.
    *if (first_sunglasses_ok)
        "I'll take the first one. No prescription."
    *else
        She does another lap of the cabinets and comes back with two pairs. Thin frames, one metal and round, one plastic and square. You point at the metal pair. "I'll take that one. No prescription."

    *page_break
    Out onto the street again. "Hey, I have time for a quick dessert, then I have to go. I've got work tomorrow, unlike some spoiled princesses I know."

    Chloe folds her arms and lifts her chin. "Wow! I can't catch a break, can I? Fine, let's make it quick."

    Two streets over, through Ladies' Market, and you're sitting down at the dessert place. Only two other tables are taken: a mum and her daughter with a coconut each, and two girls in school uniforms.

    You order the lychee longan shaved ice. Chloe orders the double-boiled egg white with coconut milk, snow swallow and taro balls in young coconut. Both arrive fast, hers lukewarm.

    Chloe eats quickly, then scrapes the coconut flesh from the shell with the back of her spoon. You start with the ice shavings, crunchy and syrupy. Then a longan, then a lychee, then a longan and lychee together. Finally both with a spoonful of ice. Really going wild.

    The food's gone. The two schoolgirls leave. You both stay seated.

*return
