*save_checkpoint ch5
*set checkpoint5 true
*set fight_opponent_name "None"
*set current_month "August"
Chapter 5: The Hungry Ghost Festival

[b]A note on character stories[/b]

By now, you know several people in the fighting circuit. You won't have time to follow all of these connections fully. [b]You can see at most two character stories through to the end in a single playthrough.[/b]

*page_break
*set epithet "CPT hours completer"
Thursday, 1 August 2024

The photocopier whirs as you make more copies of the latest pitch book. Your boss, Janet (jan-NET, she corrected you once), approaches and asks you to join her for a quick meeting in her office. Seeing your blank expression, she nods repeatedly, then goes back to her room.

Has she noticed that you've been coasting this year, ever since your new hobby? There's nothing to be done either way. You need to get this over with, so you drop the pitch books on someone's desk, take a deep breath, and knock on her door.

"${first_name}, have a seat! First of all, I want to thank you for your hard work and how you're always so proactive about..." She glances down at a notepad on her desk. "...about completing your CPT hours on time."

You're pretty sure you don't even need CPT hours, but she clears her throat and powers through. "I've noticed your enthusiasm. I can tell you're hungry to climb the ladder and make something of yourself. Unfortunately, the economy's rough and we just don't have the budget for promotions right now. I'm sure you understand. But keep up the good work. It's people like you who make this company run."

*fake_choice
    #A few years ago, this would have bothered you.
        A few years ago, this would have bothered you. You used to care about climbing the career ladder. Now, not so much.

    #You could use a bit more money, but it's not a big deal.
        The promotion doesn't mean much to you, but you could always use a bit more money. Who couldn't?

    #You care about doing the work well, but not about moving up.
        It's important that you do things well, as much for yourself as for the company. But you don't care about moving up.

"Thanks, Janet. I get what you mean. Some things can't be helped. Thanks for letting me know."

Back at your desk, your mind refuses to think about the conversation at all. You place your fingers on the keyboard, but no letters appear on the screen. You shift in your chair and take a deep breath.

A dull pain flares in your ribs. Last week's fight. Chloe started out chaotic and undisciplined, but dropped the act the moment you saw through it. Does that still count as chaos, then?

*if chloe_trauma = 0
    And you still remember her standing on you after the first round ended. Unpleasant. But if she was playing dirty, it was a strange way of going about it.
*elseif chloe_trauma = 1
    You can't forget her standing on you. Terrifying in the moment, although there was no lasting damage. A strange way to behave in an underground fight, with no obvious benefit.
*elseif chloe_trauma = 2
    You can't forget her standing on you. How you didn't know if she would stop, or when.
*else
    *bug Invalid chloe_trauma

The arrow keys no longer work. You press the up arrow a few more times, still nothing. Then you press Scroll Lock. Problem solved.

*page_break
Saturday, 3 August 2024
*gosub_scene utils show_stats

You still haven't received this month's fight card. Usually your promoter tells you at the start of the month. You message her.

"No fight this month. Bad luck. Ghosts."

Of course. August is the Hungry Ghost Festival, when the gates of the underworld open. It would be foolhardy to fight. Not only would venues be contaminated by wandering spirits, but fighting would also invite misfortune.

You head to [i]MK[/i], wondering how you'll fill the time.

*gosub_scene utils tick_character_cooldowns
*gosub_scene utils character_unvisited_check
*gosub_scene utils fortnight_choice
*gosub_scene utils show_stats
*gosub_scene utils character_visit_options
*gosub_scene utils character_visit_choice
Sunday, 11 August 2024
*gosub_scene utils update_highest_friendship

The 104 wheezes as it comes to a stop outside Statue Square. Thousands of women relax under HSBC's canopy, cardboard mats spread out, chattering happily and munching on palabok, kare-kare, nasi bungkus and gado-gado. There's a plump Filipino in wraparound sunglasses and a black silk shirt, strutting on a small raised stage.

You stroll past the fountain onto the elevated walkway, more women and their makeshift mats lining both sides of the footbridge, and take the slow escalator to the ground level, where burly men are wrapping far too much packing tape around a bulging [i]balikbayan[/i] box, the cardboard straining to contain toothpaste, luncheon meat, tiny baby shoes. No businessmen in sharp suits striding through, no office ladies shopping for snacks in side alleys, no tourists.

Jollibee beckons, the scent of fried chicken already apparent from a block away. You order your Chickenjoy set and find a high table and stool on one side. The air is filled with Tagalog and laughter.

*if highest_friendship = "Eric"
    The crispy skin crunches in your mouth as you think about Eric. How he would be at Eastside every day, training until the air conditioning was switched off, body still moving in the silence.
    *if eric_subplot_scene > 3
        How he hesitated before knocking on Master Cheng's door, then bowed deep. The tight jaw and the grimace when he pushed back on Master Cheng's advice.
    *if eric_subplot_scene > 4
        And more, how Eric keeps asking you to accompany him, the way his smile reaches his eyes when you arrive, and how he takes a deep breath before the words tumble out quietly.
    You wonder if he's found his rhythm yet, or if his fists still burn him.

*elseif highest_friendship = "Katie"
    The crispy skin crunches in your mouth as you think about Katie. You remember her cheerful commentary during your fight, even as she set your elbow on fire.
    *if katie_subplot_scene > 1
        Her eyes, wide and bright, taking in the smallest twitches of your body, as she pressed your nerves in her lab.
    *if katie_subplot_scene > 3
        That time she unexpectedly asked you for help, and you ended up having lunch, listening to her as she tried to land every word just right.
    *if katie_subplot_scene > 4
        You remember when her research was rejected: slumped over, eyes red, voice wavering. How you helped with a small suggestion, and she sat up, straighter, closer.
    You wonder what it's like to be her, surrounded by lab equipment and research notes, her monologues disappearing into concrete walls.

*elseif highest_friendship = "Danny"
    The crispy skin crunches in your mouth as you think about Danny. The thousand-strong crowd, a sea of yellow, roaring and hushing as one.
    *if ((danny_subplot_scene > 1) and (danny_investigated))
        How some unknown urge made you decide to look for him. The disinfectant smell and the crackling PA at the community centre, and the empty function room, wax on the floor worn away.
    *if (danny_subplot_scene > 2)
        That led to a morning stroll through Kowloon Park, observing tai chi practitioners. Sitting on a cold stone bench, watching men and women wince as they walk barefoot on pebbles.
    You wonder what it's like. Whether it would wear you down.
    *if (danny_subplot_scene > 2)
        You wonder why you keep seeking him out.
    *elseif (danny_investigated)
        You wonder why you went looking for him.

*elseif highest_friendship = "Chloe"
    The crispy skin crunches in your mouth as you think about Chloe. Wild, stumbling haymakers that didn't leave any openings. Then her weight on you, your breath no longer yours to control.
    *if chloe_subplot_scene > 1
        The rooftop lounge with the zen pebbles surrounding hollow-eyed bankers, where the fighter was gone and the socialite appeared, the tuxedoed waiters anticipating her requests before she voiced them.
    *if chloe_subplot_scene > 2
        And at the exercise studio, where Hong Kong itself was sealed out, nothing but the sterile room and the beeping timer, her training, and her desperation. Reading other people as if they were case studies, every weakness catalogued.
    You wonder what it would be like to live like that, slipping into roles as easily as changing outfits.

*else
    *bug Invalid highest_friendship

Your thoughts drift. There's something you admire in these people. Almost envy.

*fake_choice
    *if (eric_subplot_scene >= 2) #Admire that Eric still works on his fundamentals despite his gift.
        You admire how Eric still works on his fundamentals despite his gift, and that he spends his time helping others.

        It would be easy to lean too heavily on the fire. But he's aware of that.

    #Admire that Katie can care so completely about her research.
        You admire how completely Katie can care about her research. You couldn't do that.

        Maybe it could take over her life. But there are worse fates.

    #Admire that Danny doesn't seem to need anyone's approval.
        You admire how Danny doesn't seem to need anyone's approval. He just keeps doing what he's decided to do.

        Maybe that's inflexible. Unreasonable. But all progress depends on the unreasonable man, as someone said. Maybe it was Albert Einstein.

    #Admire that Chloe treats other people's expectations as optional.
        You admire how Chloe doesn't seem bound by other people's expectations. She does what she wants, whether people approve or not.

        Maybe she takes it too far. But still, the idea's good.

*page_break
Friday, 16 August 2024
*gosub_scene utils show_stats

At [i]MK[/i] today, there are only three people stretching and running laps, their footsteps pattering in the empty space. Even the heat isn't as oppressive, the ceiling fans finally coping. It's the humidity, the Hungry Ghost month, everything combining to push people away.

Coach Lam gives you the same exercise twice in a row and forgets to reset the timer in between. He keeps counting the reps wrong.

Your fists move. The bag takes your punches without enthusiasm. Still. Have to push through.

*gosub_scene utils tick_character_cooldowns
*gosub_scene utils character_unvisited_check
*gosub_scene utils fortnight_choice
*gosub_scene utils show_stats
*gosub_scene utils character_visit_options
*gosub_scene utils character_visit_choice
Friday, 30 August 2024
*gosub_scene utils show_stats

*if (boxing_insights_unspent > 0)
    *gosub_scene upgrades spend_insight_choices

*gosub afterhours_scene
*finish End of Chapter 5.


*label afterhours_scene
*temp companion ""
Normally you'd be finishing up your preparations for the fight card, but now there's only dead air, empty gyms, emptier streets. Even the undercover policemen avert their eyes.

Hungry Ghost month. People walk with their shoulders drawn in, weaving around the incense, the wax-splattered oranges, the suckling pig heads. A double-decker brakes hard, metal squealing against metal, an Alphard barging into its lane. You flinch before you realise.

The city itself smells different. Burnt offerings in the air, a faint sourness in the smog. A bubble tea shop with a few dozen drinks on the countertop, plastic seals sagging, pearls bloated, no one to claim them. Red marker on a yellow Post-it note that's stamped onto a glass shopfront, fluttering under the sodium streetlight.

In the distance, a basketball thuds onto concrete, each bounce dull and heavy. It might be easier if you had someone with you, against all this.

*comment char_friendship max amounts: Eric 15, Katie 13, Danny 7, Chloe 8
*temp people_available_to_ask_out 4
*if ((eric_subplot_scene < 2) or (eric_subplot_status != "available"))
    *set people_available_to_ask_out -1
*if ((katie_subplot_scene < 2) or (katie_subplot_status != "available"))
    *set people_available_to_ask_out -1
*if ((danny_subplot_scene < 3) or (danny_subplot_status != "available"))
    *set people_available_to_ask_out -1
*if ((chloe_subplot_scene < 2) or (chloe_subplot_status != "available"))
    *set people_available_to_ask_out -1
*label invite_companion
*choice
    *disable_reuse *selectable_if ((eric_subplot_scene >= 2) and (eric_subplot_status = "available")) #Ask Eric if he's free for a walk tomorrow night.
        *if (eric_friendship >= 7)
            *set companion "Eric"
            Eric's text comes back promptly. "A walk? Tomorrow? I have training..."

            You answer with an acknowledgement of how important training is to him. Then another message arrives. "I almost never skip training.
            *if (eric_romance >= 1)
                But I will, for you. Just this once."
            *else
                But I'll make an exception for you. One time only."
        *else
            *set people_available_to_ask_out -1
            Eric's text comes back promptly. "Hey ${first_name}, can't make it tomorrow. Tournament prep. Maybe next time."

            Maybe someone else will be free, but if not, a solo walk might be what you need anyway.
            *goto invite_companion
    *disable_reuse *selectable_if ((katie_subplot_scene >= 2) and (katie_subplot_status = "available")) #Ask Katie if she's free for a walk tomorrow night.
        *if (katie_friendship >= 6)
            *set companion "Katie"
            Katie's response arrives almost instantly, a real-time cascade of messages.
            *if (katie_romance >= 1)
                "Really? You asked me?" A short pause, the [i]Katie is typing...[/i] notification pulsing.

                "Yes, absolutely! I'd love to! Oh. Sorry for rambling, I wasn't expecting this. See you tomorrow!"
            *else
                "Really? A walk? That sounds great! I could use a break. I've been glued to my chair all day!"
        *else
            *set people_available_to_ask_out -1
            Katie's response arrives right away. "I'm sorry, ${first_name}, I can't make it tomorrow. Lab session booked in."

            She's buried in her work. Not a surprise.
            *goto invite_companion
    *disable_reuse *selectable_if ((danny_subplot_scene >= 3) and (danny_subplot_status = "available")) #Ask Danny if he's free for a walk tomorrow night.
        *if (danny_friendship >= 4)
            *set companion "Danny"
            Danny sends back a brief Cantonese voice clip. "A walk would be good tomorrow."

            That's surprising.
        *else
            *set people_available_to_ask_out -1
            Danny sends back a brief message. "Sorry. Can't tomorrow."

            No room for spontaneity.
            *goto invite_companion
    *disable_reuse *selectable_if ((chloe_subplot_scene >= 2) and (chloe_subplot_status = "available")) #Ask Chloe if she's free for a walk tomorrow night.
        *if (chloe_friendship >= 3)
            *set companion "Chloe"
            "You can't be serious. A walk? On the pavement?"

            You confirm that this is your intention.

            "God, that's insane. Fine, let's do it. Can't wait to see what I'm missing."
        *else
            *set people_available_to_ask_out -1
            "Charity dinner tomorrow. Ask me earlier next time."

            Of course her schedule's full.
            *goto invite_companion
    #Go for a walk by yourself.
        *if (people_available_to_ask_out > 0)
            Are you sure you want to walk alone?

            *choice
                #Yes.
                    *set companion "None"
                    Better to walk alone. Just you and the restless streets.
                #No. [i](Reconsider.)[/i]
                    *goto invite_companion
        *else
            *set companion "None"
            Better to walk alone. Just you and the restless streets.

*page_break
Saturday, 31 August 2024

The lighting at the MTR entrance is out, the shadows pooling in the stairwell. You take the bus instead, staying on the lower deck, leaning against a steel pole as cold blasts of air drag the sweat from your shirt, and a few minutes later you step out at Ferry Street into the choking evening air.

You round the corner, circling some metal fencing, to Kansu Street outside the Jade Hawker Bazaar. Its tiny entrance is lacquered in red and gold, black lettering announcing greetings in half a dozen languages: Bem-vindo, Swaagat, Benvenuti. It's shut for the night.
 
*if (companion = "Eric")
    Eric's waiting there at the entrance, hair combed back more neatly than usual. His gi is nowhere to be seen today; instead, he's wearing a red polo shirt tucked into black jeans, with a leather belt a notch too loose. His leather shoes gleam, too shiny for his casual attire. He looks straight at you, a wide grin forming before he reins it back, and 
    *if (eric_romance >= 1)
        embraces you in a tight, warm hug.
    *else
        claps you on the shoulder, his hand firm yet gentle.

    "${first_name}! Looking forward to this."
*elseif (companion = "Katie")
    Katie's standing at the entrance, sporting a plain pastel top tucked into black jeans, a slim belt, and spotless white sneakers, laces tied into neat bunny ears. She smooths her shirt, then gives you a warm smile, eyes crinkling, and
    *if (katie_romance >= 1)  
        embraces you in a slightly awkward hug, her body not quite touching you.
    *else  
        lifts a hand, pausing for a beat before waving.  

    "${first_name}! I wasn't sure if this was casual or, like... never mind. I'm happy you asked!"
*elseif (companion = "Danny")
    Danny's already at the entrance, dressed in a loose black T-shirt, faded khaki chinos, and sneakers that look like they've been through a marathon. Slung over one shoulder is a threadbare cloth bag with a bottle of water inside. He gives you a short nod, adjusts the strap on his shoulder, and falls in beside you.

    "${first_name}. Walking's good. Clears the head."
*elseif (companion = "Chloe")
    Chloe's already there, leaning against the wall. Her black cropped top hangs loose above black drawstring trousers and scuffed white sneakers. Her eyes are sharp in the streetlights, lines too clean. A small silver stud sparkles in the light as she turns her head, then it's gone.

    "${first_name}, this better not be boring," she says, walking alongside you. A hint of peach drifts from her direction.
*elseif (companion = "None")
    You pause a moment, then keep walking.
*else
    *bug Invalid companion

*if companion != "None"
    Together, you set off towards the main road.
You pass a half-built highway flyover, its plastic barricades spilled onto the pavement, almost melting in the heat. A vacant retail store, its metal shutters plastered with Midland and Centaline [i]For Rent[/i] signs, each new layer pasted over the others. You walk over a patch of pavement bricks, the joints all sealed. A herbal tea and turtle jelly shop, one of the old ones, with the giant metal urn, not the bright red plastic chain stores where they put too much honey in. The bitter smell of medicinal roots drifts out.

*if (companion = "Eric")
    Eric observes, "It's interesting that they serve turtle jelly like a dessert here. Back in Shunde it was more like a medicine thing." He looks over at you, eyes gauging your interest.

    *choice
        #Ask about Shunde.
            *set eric_friendship +1
            "Shunde? We have way better dessert, that's for sure. I've lived in Hong Kong for years but I still go back for the food."

            You ask him what he thinks of his hometown, whether he likes it here in Hong Kong.

            "Hong Kong has a lot more restaurants. But in Shunde they cook with more care. They make the dace stuffing for the peppers by hand, pounding it for hours." He slows, then stops walking, looking down at the pavement.

            "My mum made the best stuffed peppers. I kept hogging them, so one time she left the seeds in one of the peppers. I took a huge bite and my throat was on fire. I thought I would literally die, and she's laughing, patting me on the shoulder. I was seven then."

            You try not to laugh, picturing a young Eric gasping for air. He nods and starts walking again, a brief smile bubbling to the surface. 
        #Ask about turtle jelly.
            "Nah, turtle jelly isn't really my thing. Kind of feels like a kiddie food. But what about you? Do you like it? Or do you like herbal tea more?"

            You mention five-flower tea, kudzu root tea.

            "Yeah, I like the kudzu too. It's more like soup, right? You add some salt to it. Always good to have some soup with meals." He smiles to himself, gaze becoming distant.
*elseif (companion = "Katie")
    "Do you like turtle jelly, ${first_name}? I tried both kinds. I actually liked the bitter one more. Made me shiver and almost seize up, you know? So fun!"

    She glances at you and bites her lower lip. "Uh. It's fine to like that, right?"

    *choice
        #Tell her your thoughts on turtle jelly.
            "People say it's healthy," you say. "That's enough for me. At least it's better than something like 24-herb tea."

            Katie nods. "Yeah, exactly."

            You continue walking together. She fidgets with her belt, then her eyes pause on a scam alert roadside banner, a frown flickering across her face, before moving on.
        #Tell her you admire her attitude.
            *set katie_friendship +1
            "I don't think many people enjoy eating it," you say. "But you turned it into an adventure. That's pretty cool."

            Katie breaks into a broad smile. "Wow... thanks, ${first_name}. I... no one says this kind of thing to me, usually..."

            *if (katie_romance >= 1)
                She blurts out, "Do you want to... eat some?" You're already past the shop. You open your mouth, and a soft "uhh" escapes. A faint blush appears on her cheeks as she looks straight ahead. Her hand twitches at her side, close to yours.
*elseif (companion = "Danny")
    Danny notices your gaze lingering on the turtle jelly. "They're not supposed to use turtle shell in it now. I prefer the 24-herb tea."

    *choice
        #Ask why he likes 24-herb tea.
            "24-herb tea is very bitter. But if you accept it, the bitterness loses meaning."

            His gaze fixes on an elderly couple on the pavement opposite, arguing loudly. They're taking turns complaining, but they're walking in sync, bodies easy with each other. 
            
            "Drink it every day, and you don't even taste it any more."

            You wonder what else might fade the same way.
        #Question whether it's more about habit than medicinal benefit.
            *set danny_friendship +1
            "Does the tea really help you? Or is it just a habit by now?"
            
            "Habit is medicine."

            You stare at him. It sounds like nonsense. But you understand it in your gut.

            Danny sees the change in your expression and nods. He permits himself the briefest smile.

            You notice you stopped walking a while ago. You move forward again, but the pavement beneath you feels just a bit heavier.
*elseif (companion = "Chloe")
    Chloe boots a stray rock aside. "You're serious, aren't you? We're just going to walk like this." She smirks, one eyebrow arched, as she continues alongside you.

    *choice
        #Tell her that boredom clears the mind.
            Chloe clutches her head with both hands and lets out a groan.

            "What are you doing, Chloe?"

            She lets go. "Your great wisdom gave me a headache."

            She flicks your forehead with her index finger. It stings, just for a moment. "Must be clear inside there now, huh?"

            *if highest_trait = "composure"
                You rub your forehead but don't answer. She laughs, satisfied, and continues walking.
            *else
                You swat her hand away. She laughs hard.
        #Say that your biggest joy in life is walking on pavement and achieving nothing.
            *set chloe_friendship +1
            Chloe stops walking, rooted in place, and looks at you, eyes wide open, mouth hanging open. She stares for another second. Then a smile dances across her lips.

            "The scary thing is, you could have been serious."

            She runs a hand through her hair. "This walking... it's... not bad, actually."

            She grimaces, then bumps your shoulder with hers, unbalancing you for a moment. She flashes you a cheeky grin, and lightly pulls you along by the elbow.
*elseif (companion = "None")
    You consider stopping for a herbal tea, but decide against it. Better to keep things moving. The pavement feels wider without anyone beside you.
*else
    *bug Invalid companion

*page_break
A few minutes later, you arrive at a major intersection, where the foot traffic thickens. As you're waiting at the pedestrian light, a passing red double-decker blasts you with exhaust, the fumes mixing with the smell of heated metal. A half-burnt hell banknote flutters across your path, the short edge crisped into black ash as it brushes across your shin.

The Gascoigne Road flyover looms above the traffic, its concrete pillars pressing down on the street below. A truck roars by overhead, rusted steel rods clanking as they grind against themselves. You turn right onto Nathan Road, grimy vehicles inching forwards on all six lanes. A van darts forward; a horn screeches as the bus slams on the brakes.
*if highest_trait = "analysis"
    The traffic's jammed up, but the pavement is half-empty. The imbalance is obvious.
*elseif highest_trait = "composure"
    The stop-start traffic hits you in waves, testing your balance.
*elseif highest_trait = "empathy"
    Engines rumble, but the pavement is half-empty, like the city's pulse is missing.
*else
    *bug Invalid highest_trait

Across the street, the Eaton HK hotel squats, its big billboard showing a series of arthouse Pride snapshots. No one spares it a glance. Then behind it, a love hotel, a discreet crescent moon logo above the entrance. You pass a roadside newsstand, with triad pulp comics, soft-core magazines sealed in black plastic, horse racing tip sheets. Hard to imagine it will last the year.

*if (companion = "Eric")
    Eric notices the love hotel and flashes you a half-smile. "I like it. Clean, simple. A room with a purpose. There's no private space in this city."
    *choice
        #Say that might be true, but it feels a bit transactional.
            He frowns. "Transactional? Maybe. Doesn't mean it's not real."

            A small silence, then he shrugs. "You're right. But people don't have the luxury of space."

            He looks straight ahead, his jaw working silently, as you continue walking.
        #Agree that it's a practical option borne of necessity.
            *set eric_friendship +1
            "Yeah. An entire family sharing a hundred square feet. People don't have a choice."

            He waves a hand at an old apartment block, dozens of storeys high. "That's just life here. We get used to anything."
            
            He rubs his chin with one hand as he stares up at the apartment block. Then a smile.

            "Some people look down on it, but it's giving people a door they can close."
*elseif (companion = "Katie")
    Katie's gaze lingers on the newsstand. "I've never actually seen anyone buy anything from these news vendors. Wonder how they make any money."
    *choice
        #Say that you're seeing less and less of them around.
            *set katie_friendship +1
            Katie smiles and nods energetically in agreement. "Yeah! Feels like most of them just disappeared."

            She steals a glance at the vendor, who's slouched in his flimsy fold-out chair, and looks at you. Lowers her voice. "Feels kind of sad, right? Like you look away for a while, and when you look back, part of the city's gone."

            She runs her eyes slowly over the newsstand, and her smile fades. For the moment, there's no one else on this stretch of the pavement.
            *if (katie_romance >= 1)
                She grabs your forearm lightly, palm not quite touching, and hesitantly pulls you along with her.
        #Suggest that not everyone wants to read everything on their phone.
            Katie looks up, her eyebrows drawing together. "True... having actual paper you can flip through, it does feel different."

            She looks over the newspaper stall again, running her eyes over the offerings. "When I read while eating, I'm always scared of spilling my drink on my phone. That's one advantage of paper."

            She beams, but then her face falls as her words sink in. "Although, um... that wouldn't be good for a magazine either..."

            She trails off and looks down at the ground.
            *if (katie_romance >= 1)
                Then she brushes your elbow with her hand, hesitating, before gently pulling you along with her.
*elseif (companion = "Danny")
    Danny's gaze lingers on the newsstand vendor. He shrugs and says, "Probably been doing it for years now. Look at how his arm is wrapped around the cash tray, like a reflex."
    *choice
        #Suggest that maybe he just doesn't know how to do anything else.
            Danny's jaw tightens before it relaxes again. He nods.

            "Yeah. Do something long enough, and stopping isn't a choice."

            His hand rests briefly against his chest. He exchanges a few words with the vendor and buys a stick of Doublemint gum.
            
            He offers you one as you walk onwards.
        #Observe that the vendor looks like he'll continue even if no one buys anything.
            *set danny_friendship +1
            Danny nods. "Can't let something like having no customers affect you."

            You're about to say something, and he continues. "That's how the [i]dai pai dongs[/i] died out. You can't insist on everything making sense."

            He exchanges a few words with the vendor and buys a stick of Doublemint gum. He offers you one as you walk onwards.
*elseif (companion = "Chloe")
    Chloe points at the moon logo. "I'd take the moon hotel over the fancy one any day. Eaton forces you to pretend to be romantic."
    *choice
        #Say that you'd take the moon hotel too. Being direct has its advantages.
            *set chloe_friendship +1
            Her eyes gleam, sharp as glass. "Direct, huh? Dangerous. I like it."

            Chloe moves in, close enough that you feel the warmth from her arm. "Makes me wonder if you'd actually follow through." She holds eye contact with you, just inches away.

            You realise you've been taking shallow breaths, and draw in a deep one. She moves back a step. "Anyway. Moon hotel. No contest."

            She slides her hands into her pockets and keeps walking.
        #Counter that Eaton has its place. Some people like the game.
            *set chloe_friendship +1
            She scoffs, but turns to look at you. "You like that stuff? Pretending together?"

            "It's just another kind of dance."

            Chloe shrugs. "Huh. Sounds like work to me. I see what you mean, though."

            She stares straight ahead, not speaking, rubbing her thumb across her fingertips.
        #Say that both hotels serve their purpose. No need to compare.
            She snorts. "Boring! You dragged me out here, and now this!"

            A short silence, then a laugh. "Whatever. I guess sometimes I'd be in the mood for Eaton. When I feel like getting hurt."

            She keeps walking and doesn't push the issue.
*elseif (companion = "None")
    You scan the newspaper headlines. Nothing worth printing.
*else
    *bug Invalid companion

*page_break
You continue along Nathan Road, a rapid-fire chime accompanying the green pedestrian light. A smell like damp cardboard wafts out of a cul-de-sac. Large, warm droplets from air-conditioning units high above plop onto the pavement and splash onto your shoes. You look up at the [i]tong lau[/i] with their protruding balconies, and sidestep the worst of the splatter zone.

Another pedestrian crossing, then you stroll past a plaster wall, empty but for the ghost of a pawn shop sign, the scar left behind where the lettering was removed. Just above head height, reflexology and foot massage billboards in simplified Chinese. On the street, sandwich boards in faded, coated plastic. Through a break in the phalanx of buildings above, you glimpse a bare metal frame, several storeys high, where the neon signs used to hang.

Ahead, clothes shops and property agencies and a burger joint. A vacant shopfront with an overflowing jumble of [i]For Rent[/i] signs, Centaline and Midland and more you don't recognise, enthusiastically pasted over each other, contoured like a three-dimensional map. You take a deep breath, tasting the humidity. A man approaches, hawking loudly, then sees you and redirects his spit to the gutter. 

*page_break
A bright orange rubbish bin stands near the railing, the shallow metal bowl on top full of cigarette butts, some still glowing amber. Black-and-white road signs announce Ning Po Street, Nanking Street. A sign advertises karaoke, backlit by an array of white fluorescents, the right half gone dark. Pink and blue neons beckon you into a "health centre", the blinking arrow pointing up a dark, narrow staircase. From a mahjong parlour comes the sharp crack of a tile slammed on wood.

An old woman blocks most of the pavement, an iron rod in her hand. She's stoking the flames in a metal barrel alongside offerings of poached chicken and barbecued pork in oily polystyrene boxes. The makeshift furnace blazes, spitting out ash and embers and choking black smoke that overpowers the minibus exhaust at the kerbside.

*if (companion = "Eric")
    Eric nods his head towards the furnace. "Can you see that? It's an entire mansion, with windows and cars and all, made out of paper. Burnt in a minute."

    He lowers his eyes, a faint frown on his face. He swallows his words and stares at the old woman and the flames.

    *choice
        #Remark that the house shows an incredible level of detail.
            You remark on the see-through windows and the tiny imitation security cameras. They make the house seem so real, it almost feels wrong to burn.

            Eric makes a soft "mmm" sound. "Yeah. It's not just something they print out. Someone needs to fold it up. I wonder what they feel when they make it, knowing it will be tossed into a fire."

            He continues staring at the flames. You stay with him. Then he turns to the narrow gap between the concrete wall and the woman, who's stoking the flames again.
        #Admit that you don't know much about this tradition.
            *set eric_friendship +1
            You confess that you've seen these furnaces around this time of year, but you've never thought about what they represent.

            Eric brightens, turning his head to face you. "Yeah, it's an interesting story. Around this time, the barrier between earth and hell weakens. So the hungry ghosts can come and visit. They call it hungry, but I think it's more like, restless, or something like that."

            He clears his throat. "Anyway, that's why people don't fight. But it also means you can give them things more easily. So this woman is sending gifts to someone she knew."

            He gazes at the furnace for a bit more. Then, satisfied, he turns towards the narrow gap between the concrete wall and the woman.
    *if (eric_romance >= 1) 
        You squeeze past, Eric guiding you forward with a steady hand on your back.
    *else
        You squeeze past. Eric gives you space, then slips in behind you.
*elseif (companion = "Katie")
    "Wow... is that a [i]paper house[/i]?"

    Katie's eyes widen. "A stack of banknotes too. So many zeros... wouldn't that, I don't know, mess up the economy on the other side?"

    You see her eyes narrow as she listens to her own words; then a slight frown crosses her face. She looks at you, head tilted.

    *choice
        #Consider her question thoughtfully and build on it.
            *set katie_friendship +1
            "That's fascinating to think about. If they have banknotes, that means they spend money in hell. But what would they buy?"

            Katie beams and nods enthusiastically. "Clothes? Food? Air conditioners! Wait, no, this underworld isn't hot. It's different, right?"

            "I saw [i]Journey to the West[/i] on TV a while ago. I think they have a lot of different things. Like one of them is that your bed is made of iron."

            She bursts into laughter. "That sounds terrible! You'd get a sore back when you woke up! Maybe your pillow is iron too!"

            The old woman stops tending the fire and looks over, one eye narrowed. Katie mumbles a "sorry", still grinning, and gestures towards the narrow gap between the concrete wall and the woman.
        #Suggest that it's more about showing care.
            "I think it's not really about the economy there. It's more for the living than the dead. People feel good, express their care for others."

            Katie nods. "Yeah, you're right. It's... practical. From what I can tell, people like to find meaning in rituals." Her voice trails off near the end.

            She looks from the furnace to the woman. She becomes quieter as she studies the woman's heavy, repetitive movements. Then, clasping her arms in front of her, Katie inclines her head respectfully. She glances at you, then indicates the gap between the concrete wall and the old woman.
    *if (katie_romance >= 1)
        As you squeeze past, Katie follows, close enough that you don't need to look back to feel her presence.
    *else
        You squeeze past, and Katie follows, her sneakers padding softly on the pavement.
*elseif (companion = "Danny")
    Danny stands a few metres away from the old woman, giving her space.

    "Not many young ones carry on the traditions now."

    He's quiet, just watching the smoke curl up.

    *choice
        #Watch quietly with Danny.
            You watch the metal furnace, flames flickering above the rim. The old woman heaves a miniature paper house in, an intricately detailed one, with see-through windows and tiny imitation security cameras. It sinks slowly, edges blackening and crumpling, a cloud of white-grey flakes floating onto the road. The woman says nothing, just prods the remains of the house with her metal rod.
            
            Your gaze turns to Danny. His eyes are fixed on the rod in her hands, tracking its every movement, staring at the way she clasps it tightly, the veins visible on her wrinkled skin. You can't tell what he sees in it.

            Danny still hasn't said anything, but you realise his body has turned subtly towards the gap between the concrete wall and the old woman. Time to move.
        #Ask what it means to him.
            *set danny_friendship +1
            "What does this mean to you?"

            "It's not about the ghosts. It's about making sure we don't forget."
            
            The old woman fans out a stack of hell banknotes and drops them into the fire, handfuls at a time. Her hand shakes slightly when she stops. 

            Danny says something to the woman, who replies "yes" without turning to look. He nods, then extends a hand towards the gap between the concrete wall and the old woman.
        #Admit that you don't know much about this tradition.
            *set danny_friendship +1
            You confess that you've seen these furnaces around this time of year, but you've never thought about what they represent.

            "The paper houses turn into real houses on the other side." Danny gazes at the woman. "But really... it's for us. A reminder."

            You want to ask what kind of reminder he means, but he's transfixed by the flames.
            
            The old woman gently lowers a paper PlayStation into the fire. It crackles as it burns, too loud for something made out of paper. You don't think about who it might be for.

            Danny turns his gaze away. He moves to a gap between the concrete wall and the old woman, and signals with his eyes for you to come along.
    You squeeze past, and Danny follows, casting a last glance at the fire before he catches up.
*elseif (companion = "Chloe")
    Chloe grins, the twitching kind you've seen before. You take a deep breath.

    "Imagine being stuck in hell and a big bowl of paper noodles pops up on your table. What would you do?"

    You picture it. Joss paper, run through a shredder. Unappetising.

    *choice
        #Say you'd be excited about the taste of paper noodles.
            *set chloe_friendship +1
            "That would be interesting. Imagine biting down on that!"

            Chloe bursts into laughter. "Yes! Everyone watching you out of the corner of their eyes, and you have to pretend to enjoy choking it down!"

            *if (chloe_romance >= 1)
                She steps in close, slurping some invisible noodles right in front of your face, then clutching her throat with her hand before pulling back. A few passers-by glance over at her.

                Still grinning, she points at the gap between the concrete wall and the woman. You squeeze past; Chloe's hands land on your shoulders, steering you forward.
            *else
                She mimes gagging, doubled over, then flashes you a wild grin, teeth showing, before straightening up. A few passers-by glance over at her.

                She strides forward confidently and motions at the gap between the concrete wall and the woman. You squeeze past, Chloe catching up to you, still grinning.
        #Say you never liked noodles to begin with.
            "Was never a big fan of noodles to begin with, unfortunately."

            She rolls her eyes in slow motion, like her entire head's being pulled up by an invisible string. "Wow, no imagination at all," she says, shaking her head.

            But then her attention is drawn to the old woman, who's just lowered a paper PlayStation into the fire. She straightens up, feet together, and her expression becomes unreadable.

            Then she brightens and waves you forward. You squeeze through the gap between the concrete wall and the woman, and Chloe trails behind, snickering about how some people are basically robots.

*elseif (companion = "None")
    The paper house disintegrates into ash. The smoke sticks to your clothes as you keep moving.
*else
    *bug Invalid companion

*page_break
You're a block away from Jordan MTR now. The traffic is louder, but there's also the chatter of overlapping Cantonese and Putonghua conversations, music blaring from phone accessory shops. You pass a metal cart, a plastic cut-out window showing the [i]tong cung beng[/i] inside, honeycomb-like sugar cylinders dusted with coconut flakes and wrapped in a thin pancake. The vendor lifts the lid and chips at the honeycomb with a metal spatula. [i]Tink, tink, tink[/i]. A warm, nutty smell hits you. Don't see those much any more.

A pair of shoppers overtake you, wheeling Rimowas. The man is sweating in chinos, dress shirt and blazer; the woman sports a pink Juicy Couture tracksuit and oversized sunglasses to shield her from the dim light. She plants a quick, quiet peck on his cheek. He leans in, still looking forward, and they continue walking.
*if highest_trait = "analysis"
    The clothes suggest they're mainland tourists. Not many of those still come.
*elseif highest_trait = "composure"
    The kiss is just a gesture. Something that keeps them going.
*elseif highest_trait = "empathy"
    The way he received the kiss. An easy familiarity, people who have been together for decades. How that would feel: comfortable or stifling?
*else
    *bug Invalid highest_trait

You can't tell if it was habit or intimacy. Either way, it was something fragile.

As you wait at the pedestrian light, you're bombarded by a cacophony of honking. A plug of taxis has blocked the intersection, and a truck driver is stabbing his finger at them and mouthing a stream of obscenities behind his rolled-up window. More cars and more taxis join in the honking, a medley of long, continuous screeches and rapid jabs of noise.

The light turns green, and you cross and approach the mouth of the MTR station. A pair of policemen straddle the entrance, clad in light-blue shirts and dark-blue cargo trousers. They scan the foot traffic, eyes sharp, hunting for anyone wearing the wrong clothes. No one looks up.

*if (companion = "Eric")
    Eric casts a glance at the policemen, scanning their posture more than their faces. "Discipline isn't holding your breath. Their energy is stagnant."

    *choice
        #Agree with Eric's observation.
            "All of that energy, pent up for so long without release. Can't be good."
        #Reply that they might not be concerned about their energy.
            "Maybe they don't even care about energy. They're just doing what the uniform demands."

    Eric doesn't reply, preferring to move past as soon as possible.
*elseif (companion = "Katie")
    Katie gives the policemen a wide berth as you pass, but then turns to you. "I always wonder what their training is like. Do they get lessons on how to make everyone uncomfortable?"

    *choice
        #Agree and brainstorm what they might be learning.
            "There's probably a whole course on it. Intro to staring people down."

            Katie's cheeks dimple as she smiles, 
        #Offer a more systematic explanation.
            "Maybe it just happens, when you put on the uniform."

            One side of Katie's mouth moves down in a grimace,
    then she pulls you along by the
    *if (katie_romance >= 1)
        wrist.
    *else
        shoulder.
    "Let's keep moving."
*elseif (companion = "Danny")
    Danny doesn't look at the policemen. After you pass them, he keeps looking forward. "Every day they stand there. They carry it home."

    *choice
        #Acknowledge the burden they bear.
            "That kind of weight is light at first, but it accumulates."
        #Suggest they've learnt to leave it behind.
            "Maybe they don't. Take off the uniform, leave it behind."

    Danny exhales softly and keeps walking, his pace unchanged.
*elseif (companion = "Chloe")
    Chloe ignores the policemen, but after you pass, she remarks, "Money gets you everything in this city. Except immunity from those brutes."

    *choice
        #Agree that power defeats money.
            "All the money in the world won't protect you from raw power."
        #Say it isn't that simple.
            "They're not untouchable either. We're just not the ones who can touch them."

    Chloe smirks, but her eyes are hard. "Anyway. Come on."
*elseif (companion = "None")
    Doesn't feel like the police are here to catch anyone. They're here to keep everyone small.
*else
    *bug Invalid companion

You pass a Luk Fook, its sign still standing where the street used to shine. Your eyes sweep across the display window. Diamond specks framed in gold and platinum. A necklace showcasing a fat pig in solid gold, with half a dozen dangling gold piglets. The pig's smiling.

A man in a grey T-shirt and shorts walks past you, pausing regularly to drill a Muay Thai block, knee rising, elbow dropping.
*if (companion = "Chloe")
    You catch Chloe's face twisting, her lips curled, eyebrows drawn together.
*elseif (companion = "Eric")
    You catch Eric squinting at him, his mouth opening then closing.
*else
    You catch the smell of salt and sweat as he passes.
The crowd thickens at Austin Road, so you slip back onto Tak Shing Street, where the pavement breathes again. A 7-Eleven's there, next to an overly orange Mannings pharmacy. Two teens shuffle out, each holding a carton of malt Vitasoy and an opened bag of [i]Ethnicans[/i] potato chips, the smell of onion and garlic trailing behind them.

*if (companion = "None")
    You duck inside
*else
    You nod at ${companion} and duck inside
the 7-Eleven, the electronic door chime sharp and grating. You squeeze sideways between stacked shelves. You head for the hot food counter and order some takeaway [i]siu mai[/i]. The attendant ladles a dozen of them into a flimsy plastic tray, each with pasty yellow skin wrapped around a lump of grey fish paste. He tosses a handful of thin bamboo skewers on top and hands it to you.

*page_break
Carrying the food in one hand, you walk down Tak Shing Street. It's just off the main road, but a few steps in, it's quiet. An unmanned currency booth on your left, the frozen exchange rates ghosted into the display. A Japanese restaurant with a polystyrene box of dead mackerel left at the entrance. Property agencies, signs shouting "HUGE DISCOUNT, EMIGRATION SALE". The prices are still seven figures.

At the end, Cox's Road children's playground. Crumb rubber flooring, a slide barely a metre high, a swing with rust on the chains. No children. Around it, clusters of metal chairs, the steel a cold shock even in the summer heat. A few elderly residents are seated, reading newspapers, waving small hand fans, listening to stock tips on the radio.

*if (companion = "Eric")
    You rest your arm on the armrest, then lift it away from the film of dried syrup. Eric's still.

    "They built this place for movement. But no one moves."

    *choice
        #"Not every place has to serve its intended function. It's fine if they find new purposes."
            "Not every place has to serve its intended function. It's fine if they find new purposes."

            Eric gazes at the swing and the tiny rocking horse next to it. One of the screws is missing from the base, so the rocking horse is tilted at an angle. "Maybe. Kind of like the cycle of life. But it does mean that the park's failed at its original purpose."

            He keeps looking at the rocking horse. It sways whenever a wind blows.
        #"Movement leaves echoes, even if no one's here now."
            *set eric_friendship +1
            "Movement leaves echoes, even if no one's here now."

            Eric watches the swing twist in the wind, never completely still. "Echoes. Yeah. They're like a faint copy of the real thing. You can hear them, but you can't build on them."

            He keeps watching the swing, but his eyes are somewhere else entirely.
        #"The stillness doesn't bother me. I'm here, beside you."
            *set eric_friendship +1
            *set eric_romance +1
            "The stillness doesn't bother me. I'm here, beside you."

            His eyes close as he breaks into a smile, though he catches himself.

            "Thank you, ${first_name}. That's enough for me."

            You've seen him blaze in the ring. This is something else entirely.

    *if (eric_romance >= 1)
        In a far row of seats, an old woman stands, mumbles something to her friends, then drifts away. Eric leans back slightly, spine still straight, and skewers a [i]siu mai[/i], lifting it to you. As you take it from him, there's barely any space between your hands.

        *choice
            #Take the skewer naturally, brushing your hand across his.
                *set eric_romance +1
                He smiles, and there's the faintest flush across his cheeks. You eat the [i]siu mai[/i], not even noticing the rubbery taste, and then let your hand settle on the armrest between you.

                Eric places his hand on yours. The warmth is steady, contained. He keeps his gaze straight ahead, but the silence feels shared.

                The swing creaks once in the breeze, then goes still.
            #Take the skewer carefully, avoiding contact.
                *set eric_romance -1
                He nods, then leans back slightly, spine still straight. His face stays neutral. You eat the [i]siu mai[/i]. It's rubbery and bland.

                Eric eats one too. He makes a face. "This barely counts as food."

                The swing creaks once in the breeze. Eric watches the swing, then closes his eyes. The silence holds.
    *else
        In a far row of seats, an old woman stands, mumbles something to her friends, then drifts away. Eric leans back slightly, spine still straight, and skewers a [i]siu mai[/i]. He takes a bite. "This barely counts as food."

        Unconvinced, you pop one in your mouth. It's rubbery and bland, the skin sticking to your teeth. You finish the rest of the [i]siu mai[/i].

        Eric watches the swing a moment longer, then closes his eyes. His breath moves with the breeze, but his back is rigid against the seat. You find yourself sitting straighter too.

*elseif (companion = "Katie")
    You rest your arm on the armrest, then lift it away from the film of dried syrup. You shift slightly on the metal seat. Katie fidgets, then reaches for the tray. She spears a [i]siu mai[/i] and pops it into her mouth without looking at it. A grimace, then she forces a swallow. "That's... not how it's supposed to taste."

    Looking around, her eyes land on a row of metal chairs. "These chairs are warm, but your skin insists that they're cold. Nerves are so subjective."

    *choice
        #"That's just physics. Metal is more conductive, so it pulls heat away more quickly."
            *set katie_friendship +1
            "That's just physics. Metal is more conductive, so it pulls heat away more quickly."

            She snaps her fingers. "Oh yeah! Thermal conductivity. I knew that. But still, what matters is how we perceive it, right?"

            The correction lands like a gift. She's leaning back, shoulders loose, hands moving as she talks.
        #"Makes sense to me. Our bodies only tell us what we need to know."
            *set katie_friendship +1
            "Makes sense to me. Our bodies only tell us what we need to know."

            Katie nods vigorously. "Exactly! We only notice a tiny fraction of the stimuli we get. Our brains edit everything."

        #"Cold or not, I just want to be next to you."
            *set katie_friendship +2
            *set katie_romance +1
            "Cold or not, I just want to be next to you."

            Her face reddens instantly, impossible to miss. She presses her palms against her cheeks, then drops them. You let the moment breathe. It's a while before she speaks again.

            "That... makes me very happy. Thanks."

            As her face slowly returns to its regular complexion, she looks down at your [i]siu mai[/i] tray.

    *if (katie_romance >= 2)
        Then, Katie sits up straight. She blurts out, "Do you... like me? Like, not just for the research?"

        She digs her fingers into her thighs as her legs bounce. "No, no! I didn't mean..."

        Staring intently at the [i]siu mai[/i], she shoves one into her mouth. "These are... um, high in amino acids. Very functional," she mumbles through the mouthful. You think she just swallowed the entire thing without chewing.

        *choice
            #"I like you."
                *set katie_friendship +1
                *set katie_romance +1
                Katie swallows hard, then faces you and starts to lean in. Then her brain catches up. Her eyes widen as she freezes, breath still, halfway to you.

                She's completely stuck, so you gently lean in to meet her. Katie closes her eyes, a bit too hard.

                A quick kiss on her lips.

                Katie doesn't dare to look, trembling as she holds the moment, a smile melting onto her face.

                You ease her back, and she sinks into the seat with a contented sigh.

                The swing creaks in the faint breeze.

            #"Relax, Katie. We're just eating [i]siu mai[/i]."
                Katie blinks rapidly. "Right. Siu mai."

                She nods fast, like she's rebooting her brain. Tries to stab at another [i]siu mai[/i], but her hands are shaking and she misses.

                She finally spears one and holds it up in triumph, but her smile wobbles.

                "Motor control: restored!" she announces. The bright smile reappears.

                You can't help but laugh. Her shoulders loosen, and she lets out a quiet breath.

                The swing creaks in the faint breeze.
    *elseif (katie_romance = 1)
        She pops another one in her mouth, then says, "They're still terrible. But... somehow better with you here."

        The delivery needs work, but the meaning comes through.

        *choice
            #"Yeah. Everything's better with you."
                *set katie_friendship +1
                *set katie_romance +1
                Katie freezes, her hands halfway to another [i]siu mai[/i]. Then a smile forms on her face, slow and automatic.

                "That's..." she starts to say, then laughs softly. "That's... nice to hear."

                She lets out a breath and then looks down at the [i]siu mai[/i] like it's fascinating again. A moment passes, then she adds quietly, "Thanks."

                You put your arm around her shoulder. She leans into you. The fit isn't perfect, all angles and elbows, but it's comfortable.

                The swing creaks in the faint breeze. She's warm against your side.
            #"Wow, I'm being compared to bad dim sum here."
                *set katie_friendship +1
                Katie laughs out loud, then nearly chokes on her food. You pat her back and she manages a quick recovery. "You made me laugh while I was eating! That's dangerous."

                She wipes her mouth, but can't wipe the grin from her face. "Bad dim sum, but good company. Conclusion: favourable outcome."
                
                She nudges the [i]siu mai[/i] plate towards you. "Now it's your turn to suffer."

                Her laugh sounds lighter now. The swing creaks in the faint breeze.
    *else
        *set katie_friendship +1
        She pops another [i]siu mai[/i] into her mouth, winces, then laughs. "I don't know why I keep doing this. Each piece is going to be just as bad, right?"

        You laugh and take one too. Pasty and rubbery, just like she said.

        "At least I'm eating them with you. That's not so bad."

        "Yeah, it's not so bad."

        You lean back, watching the swing creak in the faint breeze.
*elseif (companion = "Danny")
    You rest your arm on the armrest, then lift it away from the film of dried syrup. You shift slightly on the metal seat.

    Danny says nothing, eyes fixed on the empty swing as it sways in the breeze. You eat a [i]siu mai[/i], rubbery and bland, the skin sticking to your teeth. The silence lasts until Danny finally speaks.

    "The children left. The elderly remain."

    *choice
        #"Yeah. Only the elderly have time to sit here."
            *set danny_friendship +1
            "Yeah. Only the elderly have time to sit here."

            Danny nods. "Time is more of a burden for them."

            You watch an old man, hunched forward on his seat, peel an orange with his bare hands. The peel tears from the pulp with an invisible mist that stains his fingers. One peel detaches, then another.

            It's like time works differently for him, its passage marked only by the orange.
        #"The kids probably show up during the daytime."
            "The kids probably show up during the daytime."

            "Maybe. Each hour belongs to someone different."

            You watch an old man, hunched forward on his seat, peel an orange with his bare hands. The peel tears from the pulp with an invisible mist that stains his fingers. One peel detaches, then another.

            The orange belongs to this hour. When it's gone, so is his time.

    Danny's noticed your gaze on the man, and he watches him too. He says, "After he's peeled the orange, he will eat it."

    You nod.

    The slightest hint of citrus drifts over. A group of teenagers cut across the playground, absorbed in their phones. The man pulls off orange slices one by one, eats them methodically. It's a sour one.

    There's nothing more to say. The swing sways in the faint breeze.
*elseif (companion = "Chloe")
    You rest your arm on the armrest, then lift it away from the film of dried syrup. You shift slightly on the metal seat. Chloe sprawls back in her chair, legs spread wide. She grabs a [i]siu mai[/i] from your tray with her fingers and pops it into her mouth. She grimaces at you, then swallows.

    *if (chloe_romance >= 1)
        "A playground with no kids. Such a romantic date. You're really spoiling me."
    *else
        "A playground with no kids. So romantic. You're really spoiling me."

    *choice
        #"Gourmet siu mai, scenic playground view. What more could anyone ask for?"
            *set chloe_friendship +1
            "Gourmet siu mai, scenic playground view. What more could anyone ask for?"

            Chloe laughs, shaking her head. Her eyes flicker over your face, reading it.

            "If this is your idea of a date, I'm both impressed and concerned."

            You study the [i]siu mai[/i] tray with interest instead of answering.
        #"Don't blame me. You're the one stealing my food."
            "Don't blame me. You're the one stealing my food."

            "You snooze, you lose!" She pulls a mock-childish face.

            You watch her pretend to enjoy the [i]siu mai[/i]. Then she grins and swipes another one. "I'm doing you a favour here. You know how bad these things taste?"
            
            Stealing is wrong. Especially from someone who's already sharing.
        #"Call it whatever you want. I just wanted to spend the night with you."
            "Call it whatever you want. I just wanted to spend the night with you."
            *set chloe_friendship +1
            *set chloe_romance +1

            Chloe's grin disappears. She stares at you. "You actually mean that, don't you...?"

            The playground slide becomes very interesting to her. "Careful. I don't..."

            "Feels good, though." She's looking at you again.

            You're expecting a joke, an eye roll, a grin snapping back into place. But she just sits there, her shoulders tight.

            "Ugh. Listen to me. Gross." She says this even as she moves closer, her shoulder touching yours.

    *if (chloe_romance >= 1)
        Chloe becomes still, then picks up another [i]siu mai[/i] with her fingers, brings it halfway to her mouth, and pauses. She raises her eyebrows, a slow smile spreading on her face, and she offers it to you.

        *choice
            #Lean forward and open your mouth.
                *set chloe_romance +1
                *set chloe_friendship +1
                You lean forward and open your mouth.

                She leaves you hanging for a moment, then slides the [i]siu mai[/i] in. As she pulls away, she slowly brushes your lower lip with her fingers.

                Chloe just watches you, her fingers resting on her lips. You chew slowly, not even tasting it, stretching out each second.

                She doesn't look away, nor can you read her expression. 
                
                A radio crackles with a weather report. Rain tomorrow.
            #Take it from her hand.
                *set chloe_friendship +1
                You hold the [i]siu mai[/i], fingers touching hers, waiting for her to let go.
                
                She doesn't. Her fingers stay where they are, light but deliberate.
                
                Then she releases. A slight smile, impossible to read. She watches you chew. You don't really taste it.

                You pick another one from the plastic tray and lift it towards her.

                A radio crackles with a weather report. Rain tomorrow.
    *else
        Chloe points at the plastic tray while leaning away so much she's over the far armrest. "Hey, you bought it. You have to suffer too."

        You pop a [i]siu mai[/i] in your mouth. Pasty and rubbery. Her face hadn't lied.

        "Good, good. Shared suffering." She grins, then looks down at her sneakers.

        "Guess that's all it ever is, huh?"

        She starts to laugh, but it dies halfway. She stares at the empty playground. The swing creaks in the faint breeze.
*elseif (companion = "None")
    You find an empty row of chairs and sit down. You eat the [i]siu mai[/i] one by one. They collapse in your mouth. The taste of fish paste.

    It's okay.
*else
    *bug Invalid companion

*return