*save_checkpoint ch0
*set checkpoint0 true
*label start_of_chapter0
*image header.png
*set stats_screen "start"

Three months ago, you started training at a Mong Kok boxing gym tucked above a [i]char siu[/i] eatery. Now you're leaving work early to punch accountants in warehouses and empty rooftop bars.

Yesterday, you traded blows inside the half-abandoned Kwun Tong Ferry Pier. The crowd cheered for fighters whose names they didn't know. You won a glutinous rice chicken in a thin plastic bag, and a lukewarm Vita lemon tea carton, its plastic straw missing.

No money, no glory, just another night getting hit. But some fighters do things that shouldn't be possible. Some say a man threw a fireball. It missed.

You're not here to save the world. Just here to see what happens when you keep showing up.

*check_achievements
*choice
    #Start the game.
        *goto start_game
    *selectable_if (choice_achieved_game_completed) #View the bonus content.
        *goto bonus_content_menu
    #Read a brief guide to boxing terminology.
        *goto boxing_terminology
    #View the content advisory.
        This game contains depictions of fighting and physical injury, pain, restricted breathing, alcohol use, gambling, sexual content, and strong language. Player discretion is advised.

        *page_break
        *goto start_of_chapter0

*label start_game
A half-open [i]ding uk[/i] rooftop, the rusted metal floor fan doing nothing against the stale air. A volunteer at a white plastic folding table, empty [i]poon choi[/i] basins stacked nearby. "The form's in English, but I don't read English. Just write something."

*choice
    #Claire Lau. (she/her)
        *set gender "Female"
        *set first_name "Claire"
        *set last_name "Lau"
    #A different name. (she/her)
        *set gender "Female"
        *gosub choose_name
    #Steve Parker. (he/him)
        *set gender "Male"
        *set first_name "Steve"
        *set last_name "Parker"
    #A different name. (he/him)
        *set gender "Male"
        *gosub choose_name
    #Leslie Fong. (they/them)
        *set gender "Nonbinary"
        *set first_name "Leslie"
        *set last_name "Fong"
    #A different name. (they/them)
        *set gender "Nonbinary"
        *gosub choose_name
*gosub set_pronouns
*finish

*label choose_name
*temp name_collision false
*label choose_name_input
*set name_collision false
What name will you declare to this underground world?

My first name is:
*input_text first_name

My surname is:
*input_text last_name
*if (("$!!{first_name}" = "ERIC") and ("$!!{last_name}" = "JIANG"))
    *set name_collision true
*elseif (("$!!{first_name}" = "KATIE") and ("$!!{last_name}" = "REYNOLDS"))
    *set name_collision true
*elseif (("$!!{first_name}" = "DANNY") and ("$!!{last_name}" = "CHAN"))
    *set name_collision true
*elseif (("$!!{first_name}" = "CHLOE") and ("$!!{last_name}" = "WONG"))
    *set name_collision true

*if (name_collision)
    The volunteer coughs. "Just so you know, there's another fighter already called ${first_name} ${last_name}. Is that okay?"

    *choice
        #Go with this name.
            *return
        #Choose another name.
            *goto choose_name_input
*return

*label set_pronouns
*if gender = "Female"
    *set gender_num 1
    *set he "she"
    *set him "her"
    *set his "her"
*elseif gender = "Male"
    *set gender_num 2
    *set he "he"
    *set him "him"
    *set his "his"
*elseif gender = "Nonbinary"
    *set gender_num 3
    *set he "they"
    *set him "them"
    *set his "their"
*else
    *bug Invalid gender
*return

*label bonus_content_menu
*set character_stories_completed 0
*if (choice_achieved_eric)
    *set character_stories_completed +1
*if (choice_achieved_katie)
    *set character_stories_completed +1
*if (choice_achieved_danny)
    *set character_stories_completed +1
*if (choice_achieved_chloe)
    *set character_stories_completed +1
*choice
    #View a glossary of Cantonese and technical terms used in the game.
        *gosub_scene bonus_content glossary
    *if (fight_vision)
        #Turn off Fight-Vision. [i](Currently on.)[/i]
            *set fight_vision false
            Fight-Vision is now disabled.
    *else
        #Turn on Fight-Vision. [i](Currently off.)[/i]
            *set fight_vision true
            Fight-Vision is now enabled. During fights, you'll see which stats each option tests. Fight-Vision can be turned on or off at any time through the Show Stats screen.
    *if (character_stories_completed >= 1)
        #Flashback: Your boxing journey begins.
            *gosub_scene bonus_content boxing_journey_begins
    *else
        *selectable_if (false) #Flashback: Your boxing journey begins. [i](Complete one character story to unlock.)[/i]
    *if (character_stories_completed >= 1)
        #Flashback: Your unofficial fight at the Kwun Tong ferry pier.
            *gosub_scene bonus_content unofficial_fight
    *else
        *selectable_if (false) #Flashback: Your unofficial fight at the Kwun Tong ferry pier. [i](Complete one character story to unlock.)[/i]
    *if (character_stories_completed >= 2)
        #Bonus fight: The Final Boss.
            *gosub_scene bonus_content alternate_ending
    *else
        *selectable_if (false) #Bonus fight: The Final Boss. [i](Complete two character stories to unlock.)[/i]
    #Return to the start menu.
        *goto start_of_chapter0
*goto bonus_content_menu

*label boxing_terminology
[b]Basic boxing terminology[/b]

You don't need any boxing knowledge to play [i]Below the Skyline[/i], but this guide explains some common boxing terminology.

Jab — A quick straight punch with the lead hand.

Cross — A straight punch with the rear hand. Stronger than a jab.

Hook — A punch that comes in from the side. The arm is bent at the elbow.

Uppercut — An upward punch thrown at close range.

Combo — Several punches thrown in sequence. Also called a combination.

Flurry — A rapid series of punches. Intended to keep an opponent on the defensive.

Guard — The positioning of the arms and gloves to protect the head and body.

Block — Absorbing an incoming strike with the hands, arms, or gloves.

Parry — Deflecting an incoming strike, usually with a glove.

Slip — Moving the head just outside the path of a punch.

Roll — Lowering the head and body to evade a punch. Often used to move under a hook. Bobbing and weaving are related terms: bobbing is moving the head vertically, while weaving is moving it side-to-side in a curved path.

Counter — An attack made in response to an opponent's attack, exploiting the opening created by it.

Clinch — Holding an opponent at close range to restrict their attacks.

*page_break
*goto start_of_chapter0